;
; $VER: Install ReadCDDA V1.0 (17.01.1996)
; This Install-script contains to ReadCDDA V1.0 ©1996 by Michael Siegel
;

(if (= (exists "Env:Language") 1)
	; GetEnv reports "String too long" if the variable doesn't exist! :(
	(set @language (getenv "language"))
)

;**************************************************************************
; English Installation

(set default-lang 1)

(set #bad-kick
	"You must have AmigaOS Release 3.0 or newer to use ReadCDDA."
)

(set #welcome
	(cat
		"\n\n\nWelcome to the ReadCDDA installation.\n\n"
		"   ReadCDDA ©1996  Michael Siegel."
	)
)

(set #install-parts "Please select the parts you wish to install")

(set #item-readcdda "ReadCDDA")

(set #item-readcdda-guide "ReadCDDA.guide")

(set #item-locale "Translations")

(set #where-readcdda
	(cat
		"Please select the Directory you would like to ReadCDDA to \n"
		"be installed?."
	)
)

(set #which-language "Which languages should be installed?")

(set #copy "Copying %s to %s...")

;**************************************************************************
; Deutsche Installation

(if (= @language "deutsch")
	(
		(set default-lang 2)

		(set #bad-kick
			(cat
				"Tut mir Leid!\n"
				"Aber Sie müßen AmigaOS Release 3.0 oder neur haben für ReadCDDA."
			)
		)
		(set #welcome
			(cat
				"\n\n\nWillkommen zu der Installation von ReadCDDA.\n\n"
				"ReadCDDA ©1996  Michael Siegel."
			)
		)

		(set #install-parts "Wählen Sie bitte die Teile, die Sie installieren wollen.")

		(set #item-readcdda "ReadCDDA")

		(set #item-readcdda-guide "ReadCDDA.guide")

		(set #item-locale "Kataloge")

		(set #where-readcdda "Wählen Sie bitte das Directory für ReadCDDA.")

		(set #which-language "Welche Sprachen sollen installiert werden?")

		(set #copy "Kopiere %s nach %s...")
	)
)

;**************************************************************************
; the installaion script

(set @default-dest "")

; Check Kickstart version. Exit if not at least 3.0
(if (< (/ (getversion) 65536) 39)
        (abort #bad-kick)
)

(message #welcome)

(welcome)

(set install-files
	(askoptions
		(prompt #install-parts)
		(help   @askoptions-help)
		(choices
			#item-readcdda
			#item-readcdda-guide
			#item-locale
		)
		(default 7)
	)
)

(if (IN install-files 0)
	(set readcdda-dest
		(askdir
			(prompt  #where-readcdda)
			(help    @askdir-help)
			(default "Work:")
		)
	)
)

(if (IN install-files 1)
	(set guide-dest readcdda-dest)
)

(set languages 0)

(if (IN install-files 2)
	(set lang
		(askoptions
			(prompt  #which-language)
			(help    @askoptions-help)
			(choices
				"English"
				"Deutsch"
			)
			(default default-lang)
		)
	)
)

; And now do the actual installation

(complete 0)

(if (IN install-files 0)
	(
		(copyfiles
			(prompt (#copy "ReadCDDA" readcdda-dest))
			(source "ReadCDDA")
			(dest   readcdda-dest)
			(help   @copyfiles-help)
			(infos)
			(confirm)
		)
	)
)

(complete 33)

(if (IN install-files 1)
	(
		(copyfiles
			(prompt (#copy "ReadCDDA.guide" guide-dest))
			(source "ReadCDDA.guide")
			(help   @copyfiles-help)
			(dest   guide-dest)
			(infos)
			(confirm)
		)
	)
)

(complete 66)

(if (IN install-files 2)
	(
		(set n 0)

		(while
			(set language
				(select n
					"English"
					"Deutsch"
					""
				)
			)

			(
				(if (AND (IN lang n) (<> 0 n))
					(
						(set catalog
							(tackon "Catalogs"
								(tackon language "readcdda.catalog")
							)
						)
						(set destination (tackon "Locale:Catalogs" language))

						(copylib
							(prompt (#copy catalog destination))
							(source catalog)
							(dest   destination)
						)
					)
				)

				(set n (+ n 1))
			)
		)
	)
)

(complete 100)
(exit)