; $VER: Skeleton Krew HD Install-Script V1.0 (20.1.95) by Roland for ACCESS

(set GameDir "Skeleton Krew")
(set TotalDisks 3)
(set CurrentDisk 0)
(set Percent 20)
(set DiskPercent (/ (- 100 Percent) TotalDisks))
(set keuze 0)

;try to figure out a place where the user usually installs his games
(if (exists "Games:" (noreq) )
    (set @default-dest "Games:")
    (if (exists "SYS:Games" (noreq) )
        (set @default-dest "SYS:Games")
        (if (exists "Work:Games" (noreq) )
            (set @default-dest "Work:Games")
            (set @default-dest "SYS:")
        )
    )
)

;ask the user to select a directory to install the game into
(set default-dest
     (tackon (askdir (prompt "Where would you like " @app-name " installed?\n"
                             "A drawer called " GameDir " will be created.")
                     (help @askdir-help)
                     (default @default-dest)
                     (newpath)
             )
     GameDir
     )
)
(set @default-dest default-dest)
(complete 5)

;create the selected directory and a subdirectory called Data
(makedir @default-dest
         (infos)
)
(complete 10)

;copy all extra files to this directory
(copyfiles (source "Skeleton Krew.6mb")
           (dest @default-dest)
           (newname "Skeleton Krew")
)
(copyfiles (source "Skeleton Krew.6mb.icon")
           (dest @default-dest)
           (newname "Skeleton Krew.info")
)
(complete Percent)

;copy all the disks to the data directory
(until (= CurrentDisk TotalDisks)
       (set CurrentDisk (+ CurrentDisk 1))
       (message "\n\n\n\n\n\nPlease insert " @app-name " Disk "
                CurrentDisk " into DF0:"
       )
       (working "\n\n\n\nConverting disk " CurrentDisk "\n"
       )
       (run (cat "Read DISK " CurrentDisk " TO \"" (tackon @default-dest (cat "SkeletonKrew.D" CurrentDisk) ) "\"" )
       )
       (set Percent (+ Percent DiskPercent))
       (complete Percent)
)
(complete 100)