* MultiPlayer
* Copyright (C) 1992 Bryan Ford
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
*
* I (the author of MultiPlayer) can be contacted on the Internet at
* "bryan.ford@m.cc.utah.edu".  See "Player.doc" for other addresses.
*
* Note:  This playroutine was not originally written by me.  In general
* these playroutines are public domain, so I am bringing the versions
* modified for MultiPlayer under the General Public License.  In the
* few cases of already-copyrighted playroutines, the above copyright
* notice applies only to the parts of the file written by me.
*
* $Id: fcoplay.asm,v 4.1 92/06/21 11:13:57 BAF Exp Locker: BAF $
*

        include "player.i"

        xdef    fcostart

        code    text,chip

fcostart:
        plstartret 9$

2$      movem.l d2-d7/a2-a6,-(sp)
        jsr     init_music(pc)
        movem.l (sp)+,d2-d7/a2-a6
        rts

3$      movem.l d2-d7/a2-a6,-(sp)
        jsr     play(pc)
        movem.l (sp)+,d2-d7/a2-a6
        rts

        cnop    0,4
        dc.l    gmod_Hook
9$      gmodnop
        jmp     2$(pc)                  ; StartMusic
        gmodnop                         ; StopMusic
        gmodnop
        gmodnop
        gmodnop
        gmodnop
        gmodnop
        gmodnop
        gmodnop
        gmodnop
        gmodnop
        gmodnop
        gmodnop
        gmodnop
        gmodq   -1                      ; GetFrequency
        jmp     3$(pc)                  ; TimerTick
        lea     name(pc),a0             ; GetMakerName
        move.l  a0,d0
        rts

*********************************************************
**   A debugged amd optimized replay routine for the   **
**         Amiga FUTURE COMPOSER  V1.0 - V1.3          **
*********************************************************

init_music:
        move.w #1,onoff
        bset #1,$bfe001
        lea 100(a0),a1
        move.l a1,seqpoint
        move.l a0,a1
        add.l 8(a0),a1
        move.l a1,patpoint
        move.l a0,a1
        add.l 16(a0),a1
        move.l a1,frqpoint
        move.l a0,a1
        add.l 24(a0),a1
        move.l a1,volpoint
        move.l 4(a0),d0
        divu #13,d0

        lea 40(a0),a1
        lea soundinfo+4(pc),a2
        moveq #10-1,d1
initloop:
        move.w (a1)+,(a2)+
        move.l (a1)+,(a2)+
        addq.w #4,a2
        dbf d1,initloop
        moveq #0,d2
        move.l a0,d1
        add.l 32(a0),d1
        sub.l #waveforms,d1
        lea soundinfo(pc),a0
        move.l d1,(a0)+
        moveq #9-1,d3
initloop1:
        move.w (a0),d2
        add.l d2,d1
        add.l d2,d1
        addq.w #6,a0
        move.l d1,(a0)+
        dbf d3,initloop1

        move.l seqpoint(pc),a0
        moveq #0,d2
        move.b 12(a0),d2                ;get replay speed
        bne.s speedok
        move.b #3,d2                    ;set default speed
speedok:
        move.w d2,respcnt               ;init repspeed counter
        move.w d2,repspd
init2:
        clr.w audtemp
        move.w #$000f,$dff096           ;disable audio dma
        move.w #$0780,$dff09a           ;disable audio irq
        moveq #0,d7
        mulu #13,d0
        moveq #4-1,d6                   ;number of soundchannels-1
        lea v1data(pc),a0               ;point to 1st voice data area
        lea silent(pc),a1
        lea chandata(pc),a2
initloop2:
        move.l a1,10(a0)
        move.l a1,18(a0)
        clr.l 14(a0)
        clr.b 45(a0)
        clr.b 47(a0)
        clr.w 8(a0)
        clr.l 48(a0)
        move.b #$01,23(a0)
        move.b #$01,24(a0)
        clr.b 25(a0)
        clr.l 26(a0)
        clr.w 30(a0)
        moveq #$00,d3
        move.w (a2)+,d1
        move.w (a2)+,d3
        divu #$0003,d3
        moveq #0,d4
        bset d3,d4
        move.w d4,32(a0)
        mulu #$0003,d3
        andi.l #$00ff,d3
        andi.l #$00ff,d1
        addi.l #$dff0a0,d1
        move.l d1,a6
        move.l #$0000,(a6)
        move.w #$0100,4(a6)
        move.w #$0000,6(a6)
        move.w #$0000,8(a6)
        move.l d1,60(a0)
        clr.w 64(a0)
        move.l seqpoint(pc),(a0)
        move.l seqpoint(pc),52(a0)
        add.l d0,52(a0)
        add.l d3,52(a0)
        add.l d7,(a0)
        add.l d3,(a0)
        move.w #$000d,6(a0)
        move.l (a0),a3
        move.b (a3),d1
        andi.l #$00ff,d1
        lsl.w #6,d1
        move.l patpoint(pc),a4
        adda.w d1,a4
        move.l a4,34(a0)
        clr.l 38(a0)
        move.b #$02,42(a0)
        move.b 1(a3),44(a0)
        move.b 2(a3),22(a0)
        clr.b 43(a0)
        clr.b 45(a0)
        clr.w 56(a0)
        lea $4a(a0),a0          ;point to next voice's data area
        dbf d6,initloop2
        rts


play:
        lea audtemp(pc),a5
        tst.w 8(a5)
        bne.s music_on
        rts
music_on:
        subq.w #1,4(a5)                 ;decrease replayspeed counter
        bne.s nonewnote
        move.w 6(a5),4(a5)              ;restore replayspeed counter
        moveq #0,d5
        moveq #6,d6
        lea v1data(pc),a0               ;point to voice1 data area
        bsr.l new_note
        lea v2data(pc),a0               ;point to voice2 data area
        bsr.l new_note
        lea v3data(pc),a0               ;point to voice3 data area
        bsr.l new_note
        lea v4data(pc),a0               ;point to voice4 data area
        bsr.l new_note
nonewnote:
        clr.w (a5)
        lea $dff000,a6
        lea v1data(pc),a0
        bsr.l effects
        move.l d0,$a6(a6)
        lea v2data(pc),a0
        bsr.l effects
        move.l d0,$b6(a6)
        lea v3data(pc),a0
        bsr.l effects
        move.l d0,$c6(a6)
        lea v4data(pc),a0
        bsr.l effects
        move.l d0,$d6(a6)
        lea v1data(pc),a0
        move.l 68+0*74(a0),a1         ;get samplepointer
        adda.w 64+0*74(a0),a1         ;add repeat_start
        move.l 68+1*74(a0),a2
        adda.w 64+1*74(a0),a2
        move.l 68+2*74(a0),a3
        adda.w 64+2*74(a0),a3
        move.l 68+3*74(a0),a4
        adda.w 64+3*74(a0),a4
        move.w 66+0*74(a0),d1         ;get sound lengths
        move.w 66+1*74(a0),d2
        move.w 66+2*74(a0),d3
        move.w 66+3*74(a0),d4
        moveq #2,d0
        moveq #0,d5
        move.w (a5),d7
        ori.w #$8000,d7                 ;set/clr bit = 1
        move.w d7,$dff096               ;enable audio dma
chan1:
        lea v1data+72(pc),a0
        move.w (a0),d7
        beq.s chan2
        subq.w #1,(a0)
        cmp.w d0,d7
        bne.s chan2
        move.w d5,(a0)
        move.l a1,$a0(a6)               ;set soundstart
        move.w d1,$a4(a6)               ;set soundlength
chan2:
        lea v2data+72(pc),a0
        move.w (a0),d7
        beq.s chan3
        subq.w #1,(a0)
        cmp.w d0,d7
        bne.s chan3
        move.w d5,(a0)
        move.l a2,$b0(a6)
        move.w d2,$b4(a6)
chan3:
        lea v3data+72(pc),a0
        move.w (a0),d7
        beq.s chan4
        subq.w #1,(a0)
        cmp.w d0,d7
        bne.s chan4
        move.w d5,(a0)
        move.l a3,$c0(a6)
        move.w d3,$c4(a6)
chan4:
        lea v4data+72(pc),a0
        move.w (a0),d7
        beq.s endplay
        subq.w #1,(a0)
        cmp.w d0,d7
        bne.s endplay
        move.w d5,(a0)
        move.l a4,$d0(a6)
        move.w d4,$d4(a6)
endplay:
        rts

new_note:
        move.l 34(a0),a1
        adda.w 40(a0),a1
        cmp.w #64,40(a0)
        bne.l samepat
        move.w d5,40(a0)
        move.l (a0),a2
        adda.w 6(a0),a2         ;point to next sequence row
        cmpa.l 52(a0),a2        ;is it the end?
        bne.s notend
        move.w d5,6(a0)         ;yes!
        move.l (a0),a2          ;point to first sequence
notend:
        lea spdtemp(pc),a3
        moveq #1,d1
        addq.b #1,(a3)
        cmpi.b #5,(a3)
        bne.s nonewspd
        move.b d1,(a3)
        move.b 12(a2),d1        ;get new replay speed
        beq.s nonewspd
        move.w d1,2(a3)         ;store in counter
        move.w d1,4(a3)
nonewspd:
        move.b (a2)+,d1         ;pattern to play
        move.b (a2)+,44(a0)     ;transpose value
        move.b (a2)+,22(a0)     ;soundtranspose value
        lsl.w d6,d1
        move.l patpoint(pc),a1  ;get pattern pointer
        add.w d1,a1
        move.l a1,34(a0)
        addi.w #$000d,6(a0)
samepat:
        move.b 1(a1),d1         ;get info byte
        move.b (a1)+,d0         ;get note
        bne.s ww1
        andi.w #%11000000,d1
        beq.s noport
        bra.s ww11
ww1:
        move.w d5,56(a0)
ww11:
        move.b d5,47(a0)
        ;move.b (a1),31(a0)

                        ;31(a0) = portamento/instr. info
                                ;bit 7 = portamento on
                                ;bit 6 = portamento off
                                ;bit 5-0 = instrument number
                        ;47(a0) = portamento value
                                ;bit 7-5 = always zero
                                ;bit 4 = up/down
                                ;bit 3-0 = value
t_porton:
        btst #7,d1
        beq.s noport
        move.b 2(a1),47(a0)
noport:
        andi.w #$007f,d0
        beq.l nextnote
        move.b d0,8(a0)
        move.b (a1),d1
        move.b d1,9(a0)
        move.w 32(a0),d3
        or.w d3,(a5)
        move.w d3,$dff096
        andi.w #$003f,d1        ;max 64 instruments
        add.b 22(a0),d1         ;add soundtranspose
        move.l volpoint(pc),a2
        lsl.w d6,d1
        adda.w d1,a2
        move.w d5,16(a0)
        move.b (a2),23(a0)
        move.b (a2)+,24(a0)
        moveq #0,d1
        move.b (a2)+,d1
        move.b (a2)+,27(a0)
        move.b #$40,46(a0)
        move.b (a2),28(a0)
        move.b (a2)+,29(a0)
        move.b (a2)+,30(a0)
        move.l a2,10(a0)
        move.l frqpoint(pc),a2
        lsl.w d6,d1
        adda.w d1,a2
        move.l a2,18(a0)
        move.w d5,50(a0)
        move.b d5,25(a0)
        move.b d5,26(a0)
nextnote:
        addq.w #2,40(a0)
        rts

effects:
        moveq #0,d7
testsustain:
        tst.b 26(a0)            ;is sustain counter = 0
        beq.s sustzero
        subq.b #1,26(a0)        ;if no, decrease counter
        bra.l volufx
sustzero:               ;next part of effect sequence
        move.l 18(a0),a1        ;can be executed now.
        adda.w 50(a0),a1
testeffects:
        cmpi.b #$e1,(a1)        ;e1 = end of freqseq sequence
        beq.l volufx
        move.b (a1),d0
        cmpi.b #$e0,d0          ;e0 = loop to other part of sequence
        bne.s testnewsound
        move.b 1(a1),d1         ;loop to start of sequence + 1(a1)
        andi.w #$003f,d1
        move.w d1,50(a0)
        move.l 18(a0),a1
        adda.w d1,a1
        move.b (a1),d0
testnewsound:
        cmpi.b #$e2,d0          ;e2 = set waveform
        bne.s teste4
        move.w 32(a0),d1
        or.w d1,(a5)
        move.w d1,$dff096
        moveq #0,d0
        move.b 1(a1),d0
        lea soundinfo(pc),a4
        add.w d0,d0
        move.w d0,d1
        lsl.w #2,d1
        add.w d1,d0
        adda.w d0,a4
        move.l 60(a0),a3
        move.l (a4),d1
        add.l #waveforms,d1
        move.l d1,(a3)
        move.l d1,68(a0)
        move.w 4(a4),4(a3)
        move.l 6(a4),64(a0)
        move.w #$0003,72(a0)
        clr.w 16(a0)
        move.b #$01,23(a0)
        addq.w #2,50(a0)
        bra.l transpose
teste4:
        cmpi.b #$e4,d0
        bne.s testpatjmp
        moveq #0,d0
        move.b 1(a1),d0
        lea soundinfo(pc),a4
        add.w d0,d0
        move.w d0,d1
        lsl.w #2,d1
        add.w d1,d0
        adda.w d0,a4
        move.l 60(a0),a3
        move.l (a4),d1
        add.l #waveforms,d1
        move.l d1,(a3)
        move.l d1,68(a0)
        move.w 4(a4),4(a3)
        move.l 6(a4),64(a0)
        move.w #$0003,72(a0)
        addq.w #2,50(a0)
        bra.s transpose
testpatjmp:
        cmpi.b #$e7,d0
        bne.s testnewsustain
        moveq #0,d0
        move.b 1(a1),d0
        lsl.w d6,d0
        move.l frqpoint(pc),a1
        adda.w d0,a1
        move.l a1,18(a0)
        move.w d7,50(a0)
        bra.l testeffects
testnewsustain:
        cmpi.b #$e8,d0          ;e8 = set sustain time
        bne.s testnewvib
        move.b 1(a1),26(a0)
        addq.w #2,50(a0)
        bra.l testsustain
testnewvib:
        cmpi.b #$e3,(a1)+
        bne.s transpose
        addq.w #3,50(a0)
        move.b (a1)+,27(a0)
        move.b (a1),28(a0)
transpose:
        move.l 18(a0),a1
        adda.w 50(a0),a1
        move.b (a1),43(a0)
        addq.w #1,50(a0)

volufx:
        tst.b 25(a0)
        beq.s volsustzero
        subq.b #1,25(a0)
        bra.s calcperiod
volsustzero:
        subq.b #1,23(a0)
        bne.s calcperiod
        move.b 24(a0),23(a0)
volu_cmd:
        move.l 10(a0),a1
        adda.w 16(a0),a1
        move.b (a1),d0
        cmpi.b #$e8,d0
        bne.s testvoluend
        addq.w #2,16(a0)
        move.b 1(a1),25(a0)
        bra.s calcperiod
testvoluend:
        cmpi.b #$e1,d0
        beq.s calcperiod
        cmpi.b #$e0,d0
        bne.s setvolume
        move.b 1(a1),d0
        andi.w #$003f,d0
        subq.b #5,d0
        move.w d0,16(a0)
        bra.s volu_cmd
setvolume:
        move.b (a1),45(a0)
        addq.w #1,16(a0)

calcperiod:
        move.b 43(a0),d0
        bmi.s lockednote
        add.b 8(a0),d0
        add.b 44(a0),d0
lockednote:
        moveq #$7f,d1
        and.l d1,d0
        lea periods(pc),a1
        add.w d0,d0
        move.w d0,d1
        adda.w d0,a1
        move.w (a1),d0

        move.b 46(a0),d7
        tst.b 30(a0)            ;vibrato_delay = zero ?
        beq.s vibrator
        subq.b #1,30(a0)
        bra.s novibrato
vibrator:
        moveq #5,d2
        move.b d1,d5
        move.b 28(a0),d4
        add.b d4,d4
        move.b 29(a0),d1
        tst.b d7
        bpl.s vib1
        btst #0,d7
        bne.s vib4
vib1:
        btst d2,d7
        bne.s vib2
        sub.b 27(a0),d1
        bcc.s vib3
        bset d2,d7
        moveq #0,d1
        bra.s vib3
vib2:
        add.b 27(a0),d1
        cmp.b d4,d1
        bcs.s vib3
        bclr d2,d7
        move.b d4,d1
vib3:
        move.b d1,29(a0)
vib4:
        lsr.b #1,d4
        sub.b d4,d1
        bcc.s vib5
        subi.w #$0100,d1
vib5:
        addi.b #$a0,d5
        bcs.s vib7
vib6:
        add.w d1,d1
        addi.b #$18,d5
        bcc.s vib6
vib7:
        add.w d1,d0
novibrato:
        eori.b #$01,d7
        move.b d7,46(a0)

        ; do the portamento thing
        moveq #0,d1
        move.b 47(a0),d1        ;get portavalue
        beq.s addporta          ;0=no portamento
        cmpi.b #$1f,d1
        bls.s portaup
portadown:
        andi.w #$1f,d1
        neg.w d1
portaup:
        sub.w d1,56(a0)
addporta:
        add.w 56(a0),d0
        cmpi.w #$0070,d0
        bhi.s nn1
        move.w #$0071,d0
nn1:
        cmpi.w #$1ac0,d0
        bls.s nn2
        move.w #$1ac0,d0
nn2:
        swap d0
        move.b 45(a0),d0
        rts



v1data:  ds.b 64     ;voice 1 data area
offset1: ds.b 02     ;is added to start of sound
ssize1:  ds.b 02     ;length of sound
start1:  ds.b 06     ;start of sound

v2data:  ds.b 64     ;voice 2 data area
offset2: ds.b 02
ssize2:  ds.b 02
start2:  ds.b 06

v3data:  ds.b 64     ;voice 3 data area
offset3: ds.b 02
ssize3:  ds.b 02
start3:  ds.b 06

v4data:  ds.b 64     ;voice 4 data area
offset4: ds.b 02
ssize4:  ds.b 02
start4:  ds.b 06

audtemp: dc.w 0         ;dmacon
spdtemp: dc.w 0
respcnt: dc.w 0         ;replay speed counter
repspd:  dc.w 0         ;replay speed counter temp
onoff:   dc.w 0         ;music on/off flag.

chandata: dc.l $00000000,$00100003,$00200006,$00300009
seqpoint: dc.l 0
patpoint: dc.l 0
frqpoint: dc.l 0
volpoint: dc.l 0


even
silent: dc.w $0100,$0000,$0000,$00e1

periods dc.w $06b0,$0650,$05f4,$05a0,$054c,$0500,$04b8,$0474
        dc.w $0434,$03f8,$03c0,$038a,$0358,$0328,$02fa,$02d0
        dc.w $02a6,$0280,$025c,$023a,$021a,$01fc,$01e0,$01c5
        dc.w $01ac,$0194,$017d,$0168,$0153,$0140,$012e,$011d
        dc.w $010d,$00fe,$00f0,$00e2,$00d6,$00ca,$00be,$00b4
        dc.w $00aa,$00a0,$0097,$008f,$0087,$007f,$0078,$0071
        dc.w $0071,$0071,$0071,$0071,$0071,$0071,$0071,$0071
        dc.w $0071,$0071,$0071,$0071,$0d60,$0ca0,$0be8,$0b40
        dc.w $0a98,$0a00,$0970,$08e8,$0868,$07f0,$0780,$0714
        dc.w $1ac0,$1940,$17d0,$1680,$1530,$1400,$12e0,$11d0
        dc.w $10d0,$0fe0,$0f00,$0e28

soundinfo:
;offset.l , sound-length.w , start-offset.w , repeat-length.w

;reserved for samples
        dc.w $0000,$0000,$0000,$0000,$0001
        dc.w $0000,$0000,$0000,$0000,$0001
        dc.w $0000,$0000,$0000,$0000,$0001
        dc.w $0000,$0000,$0000,$0000,$0001
        dc.w $0000,$0000,$0000,$0000,$0001
        dc.w $0000,$0000,$0000,$0000,$0001
        dc.w $0000,$0000,$0000,$0000,$0001
        dc.w $0000,$0000,$0000,$0000,$0001
        dc.w $0000,$0000,$0000,$0000,$0001
        dc.w $0000,$0000,$0000,$0000,$0001
;reserved for synth souns
        dc.w $0000,$0000,$0010,$0000,$0010
        dc.w $0000,$0020,$0010,$0000,$0010
        dc.w $0000,$0040,$0010,$0000,$0010
        dc.w $0000,$0060,$0010,$0000,$0010
        dc.w $0000,$0080,$0010,$0000,$0010
        dc.w $0000,$00a0,$0010,$0000,$0010
        dc.w $0000,$00c0,$0010,$0000,$0010
        dc.w $0000,$00e0,$0010,$0000,$0010
        dc.w $0000,$0100,$0010,$0000,$0010
        dc.w $0000,$0120,$0010,$0000,$0010
        dc.w $0000,$0140,$0010,$0000,$0010
        dc.w $0000,$0160,$0010,$0000,$0010
        dc.w $0000,$0180,$0010,$0000,$0010
        dc.w $0000,$01a0,$0010,$0000,$0010
        dc.w $0000,$01c0,$0010,$0000,$0010
        dc.w $0000,$01e0,$0010,$0000,$0010
        dc.w $0000,$0200,$0010,$0000,$0010
        dc.w $0000,$0220,$0010,$0000,$0010
        dc.w $0000,$0240,$0010,$0000,$0010
        dc.w $0000,$0260,$0010,$0000,$0010
        dc.w $0000,$0280,$0010,$0000,$0010
        dc.w $0000,$02a0,$0010,$0000,$0010
        dc.w $0000,$02c0,$0010,$0000,$0010
        dc.w $0000,$02e0,$0010,$0000,$0010
        dc.w $0000,$0300,$0010,$0000,$0010
        dc.w $0000,$0320,$0010,$0000,$0010
        dc.w $0000,$0340,$0010,$0000,$0010
        dc.w $0000,$0360,$0010,$0000,$0010
        dc.w $0000,$0380,$0010,$0000,$0010
        dc.w $0000,$03a0,$0010,$0000,$0010
        dc.w $0000,$03c0,$0010,$0000,$0010
        dc.w $0000,$03e0,$0010,$0000,$0010
        dc.w $0000,$0400,$0008,$0000,$0008
        dc.w $0000,$0410,$0008,$0000,$0008
        dc.w $0000,$0420,$0008,$0000,$0008
        dc.w $0000,$0430,$0008,$0000,$0008
        dc.w $0000,$0440,$0008,$0000,$0008
        dc.w $0000,$0450,$0008,$0000,$0008
        dc.w $0000,$0460,$0008,$0000,$0008
        dc.w $0000,$0470,$0008,$0000,$0008
        dc.w $0000,$0480,$0010,$0000,$0010
        dc.w $0000,$04a0,$0008,$0000,$0008
        dc.w $0000,$04b0,$0010,$0000,$0010
        dc.w $0000,$04d0,$0010,$0000,$0010
        dc.w $0000,$04f0,$0008,$0000,$0008
        dc.w $0000,$0500,$0008,$0000,$0008
        dc.w $0000,$0510,$0018,$0000,$0018


waveforms:
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $3f37,$2f27,$1f17,$0f07,$ff07,$0f17,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c037,$2f27,$1f17,$0f07,$ff07,$0f17,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$2f27,$1f17,$0f07,$ff07,$0f17,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b027,$1f17,$0f07,$ff07,$0f17,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b0a8,$1f17,$0f07,$ff07,$0f17,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b0a8,$a017,$0f07,$ff07,$0f17,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b0a8,$a098,$0f07,$ff07,$0f17,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b0a8,$a098,$9007,$ff07,$0f17,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b0a8,$a098,$9088,$ff07,$0f17,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b0a8,$a098,$9088,$8007,$0f17,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b0a8,$a098,$9088,$8088,$0f17,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b0a8,$a098,$9088,$8088,$9017,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b0a8,$a098,$9088,$8088,$9098,$1f27,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b0a8,$a098,$9088,$8088,$9098,$a027,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b0a8,$a098,$9088,$8088,$9098,$a0a8,$2f37
        dc.w $c0c0,$d0d8,$e0e8,$f0f8,$00f8,$f0e8,$e0d8,$d0c8
        dc.w $c0b8,$b0a8,$a098,$9088,$8088,$9098,$a0a8,$b037
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $817f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $8181,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $8181,$817f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $8181,$8181,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $8181,$8181,$817f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $8181,$8181,$8181,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $8181,$8181,$8181,$817f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $8181,$8181,$8181,$8181,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $8181,$8181,$8181,$8181,$817f,$7f7f,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $8181,$8181,$8181,$8181,$8181,$7f7f,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $8181,$8181,$8181,$8181,$8181,$817f,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$7f7f,$7f7f
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$8181,$8181
        dc.w $8181,$8181,$8181,$8181,$8181,$8181,$817f,$7f7f
        dc.w $8080,$8080,$8080,$8080,$8080,$8080,$8080,$8080
        dc.w $8080,$8080,$8080,$8080,$8080,$8080,$8080,$7f7f
        dc.w $8080,$8080,$8080,$8080,$8080,$8080,$8080,$8080
        dc.w $8080,$8080,$8080,$8080,$8080,$8080,$8080,$807f
        dc.w $8080,$8080,$8080,$8080,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8080,$8080,$8080,$807f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8080,$8080,$8080,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8080,$8080,$807f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8080,$8080,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8080,$807f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8080,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8080,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f,$7f7f
        dc.w $8080,$9098,$a0a8,$b0b8,$c0c8,$d0d8,$e0e8,$f0f8
        dc.w $0008,$1018,$2028,$3038,$4048,$5058,$6068,$707f
        dc.w $8080,$a0b0,$c0d0,$e0f0,$0010,$2030,$4050,$6070
        dc.w $4545,$797d,$7a77,$7066,$6158,$534d,$2c20,$1812
        dc.w $04db,$d3cd,$c6bc,$b5ae,$a8a3,$9d99,$938e,$8b8a
        dc.w $4545,$797d,$7a77,$7066,$5b4b,$4337,$2c20,$1812
        dc.w $04f8,$e8db,$cfc6,$beb0,$a8a4,$9e9a,$9594,$8d83
        dc.w $0000,$4060,$7f60,$4020,$00e0,$c0a0,$80a0,$c0e0
        dc.w $0000,$4060,$7f60,$4020,$00e0,$c0a0,$80a0,$c0e0
        dc.w $8080,$9098,$a0a8,$b0b8,$c0c8,$d0d8,$e0e8,$f0f8
        dc.w $0008,$1018,$2028,$3038,$4048,$5058,$6068,$707f
        dc.w $8080,$a0b0,$c0d0,$e0f0,$0010,$2030,$4050,$6070

name    dc.b    "Future Composer 1.3",0

        end
