LOGON TO A LOCAL BBS WITH THIS GEOCOMM SCRIPT

Note: This script comes to us from GWRepDave (thanks!).

For those of you who are using Geocomm to call a local bbs, here's a script file that may make your life easier. You will need to put in the correct phone number, your first and last name, and your password. You may also have to make changes to the line 2400,8,n,1,full. This line sets your buad rate, data bits, paraty, stop bit, and duplex. These settings are most common. However, you may need to change baud rate to 1200, data bits to 7, parity to e, duplex to half, etc. When in doubt, contact the sysop of your local bbs for the correct settings. Finally, you may have to change PORT. It should be 1 if your modem is connected to Com1 and 2 if connected to Com2.
 Lines preceeded by a semi-colon ; are comment lines that explain the script. All other lines should be entered as listed below. 


;SAMPLE.MAC logon file edited by GWRepDave 4/28/91
;
PRINT "      THIS IS A SAMPLE SCRIPT FILE",CR
PRINT "     FOR SIGN-ON TO LOCAL BULLETIN", CR
PRINT "  BOARDS, SUCH AS WILDCAT AND RBBS",CR
PRINT "PORT, COMM, TERM, DIAL, CONNECTED TO,",CR
PRINT " FIRST AND LAST NAME, AND PASSWORD",CR
PRINT "           FIELDS MUST BE EDITED"
PRINT "           FOR YOUR PREFERENCES"
PAUSE
PORT	2
:comm
COMM	2400-8-N-1-FULL
TERM	TTY
; clear the script display
CLEAR
:retry 
PAUSE
PRINT	"DIALING" , CR
DIAL	"555-1111"
MATCH	"BUSY"		GOTO	retry
MATCH	"NO"		GOTO	retry
MATCH	"CONNECT 2400"	GOTO	connect
PROMPT	4800
PRINT	"TIMEOUT ON DIAL",CR
GOTO	done
:connect
PRINT       "Connected to the BBS NAME", CR
PAUSE	

MATCH     "What is your FIRST Name?" GOTO    first
PROMPT	600
PRINT      "TIMEOUT ON FIRST NAME",CR
GOTO	done
:first
PRINT      "Sending FIRST NAME", CR
PAUSE 
SEND       "FIRST NAME",CR


MATCH     "What is your LAST Name?" GOTO    last
PROMPT	600
PRINT	"TIMEOUT ON LAST NAME",CR
GOTO	done
:last
PRINT      "Sending LAST NAME", CR 
PAUSE 
SEND	"LAST NAME",CR


MATCH     "Enter Password (dots will echo)?"GOTO pword
PROMPT    600
PRINT      "TIMEOUT ON PASSWORD",CR
GOTO	done
:pword
PRINT      "Sending password", CR
PAUSE
SEND      "PASSWORD",CR

:done
BELL
PRINT	"   * * *DONE* * *",CR
PRINT        "PLEASE CLICK ON CLOSE",CR
END

:ABORT
PRINT	"HANGING UP",CR
SEND         "+"
MATCH       "OK" GOTO done
MATCH       "NO CARRIER" GOTO done
PROMPT	300
PRINT	"Couldn't disconnect the modem",CR
GOTO	end
; Hangup the connection
:dohup
SEND	"ATH0",CR
MATCH	"OK"	GOTO	hangup
PROMPT	900
PRINT	"TIMEOUT ON hangup",CR
GOTO	end
:hangup
PRINT	"HUNG UP",CR
:end
BELL
END