TEXT

               INCLUDE  '\LIB\GEMDOS.S'
               INCLUDE  '\LIB\XBIOS.S'
               INCLUDE  '\LIB\BIOS.S'
               INCLUDE  '\LIB\ESCCHAR.S'
               XREF EDIT_SECTOR

MAIN           BSR      DRTITLE
               JSR      EDIT_SECTOR
               MOVE.W   #TERM,-(SP)
               TRAP     #GEMDOS

DRTITLE        MOVEM.L  D0-D1/A0-A1,-(SP)
               MOVE.W   #CURSCONF,-(SP)
               MOVE.W   #0,-(SP)
               MOVE.W   #21,-(SP)
               TRAP     #XBIOS
               ADDQ.L   #6,SP
               LEA      BLACK_AND_CLEAR,A0
               BSR      DRTITLE_WRITE_STRING
               MOVE.W   #10,D0
               BSR      DRTITLE_DELAY
               LEA      LINE_1,A0
               JSR      SCROLL
               LEA      LINE_2,A0
               BSR      SCROLL
               MOVE.W   #4,D0
               BSR      DRTITLE_DELAY
               LEA      LINE_3,A0
               BSR      SCROLL
               MOVE.W   #8,D0
               BSR      DRTITLE_DELAY
               LEA      LINE_4,A0
               BSR      SCROLL
               LEA      LINE_5,A0
               BSR      SCROLL
               MOVE.W   #8,D0
               BSR      DRTITLE_DELAY
               LEA      WHITE_AND_CLEAR,A0
               BSR      DRTITLE_WRITE_STRING
               MOVE.W   #CURSCONF,-(SP)
               MOVE.W   #1,-(SP)
               MOVE.W   #21,-(SP)
               TRAP     #XBIOS
               ADDQ.L   #6,SP
               MOVEM.L  (SP)+,D0-D1/A0-A1
               RTS

DRTITLE_WRITE_STRING
               MOVE.L   A0,-(SP)
               MOVE.W   #CONWS,-(SP)
               TRAP     #GEMDOS
               ADDQ.L   #6,SP
               RTS

DRTITLE_DELAY
               MOVEM.L  D1,-(SP)
               MOVE.W   #$6000,D1
DRTITLE_DELAY_1
               NOP
               DBRA     D1,DRTITLE_DELAY_1
               DBRA     D0,DRTITLE_DELAY_1
               MOVEM.L  (SP)+,D1
               RTS

SCROLL         MOVEM.L  D0-D3/A0-A2,-(SP)
               MOVE.B   (A0),CURSOR_BEG_ROW
               MOVE.B   (A0)+,CURSOR_END_ROW
               CLR.W    D3
               MOVE.B   (A0)+,D3
               MOVE.L   A0,STRING_BEG
               ADD.W    D3,A0
               MOVE.L   A0,STRING_END
               LSR.W    #1,D3
               ADD.W    #1,D3
               CLR.W    D2
SCROLL_1       MOVE.L   STRING_BEG,A1
               MOVE.L   STRING_END,A2
               MOVE.B   #71,CURSOR_END_COL
               ADD.B    D2,CURSOR_END_COL
               MOVE.B   #71,CURSOR_BEG_COL
               SUB.B    D2,CURSOR_BEG_COL
               LEA      CURSOR_BEG,A0
               BSR      SCROLL_WRITE_STRING
               CLR.W    D1
SCROLL_2       MOVE.B   (A1)+,D0
               BSR      SCROLL_WRITE_CHARACTER
               ADD.W    #1,D1
               CMP.W    D1,D2
               BGT      SCROLL_2
               CLR.W    D1
SCROLL_3       SUB.B    #1,CURSOR_END_COL
               LEA      CURSOR_END,A0
               BSR      SCROLL_WRITE_STRING
               MOVE.B   -(A2),D0
               BSR      SCROLL_WRITE_CHARACTER
               ADD.W    #1,D1
               CMP.W    D1,D2
               BGT      SCROLL_3
               BSR      SCROLL_DELAY
               ADD.W    #1,D2
               CMP.W    D2,D3
               BGT      SCROLL_1
               MOVEM.L  (SP)+,D0-D3/A0-A2
               RTS

SCROLL_WRITE_STRING
               MOVE.L   A0,-(SP)
               MOVE.W   #CONWS,-(SP)
               TRAP     #GEMDOS
               ADDQ.L   #6,SP
               RTS

SCROLL_WRITE_CHARACTER
               MOVE.W   D0,-(SP)
               MOVE.W   #CONOUT,-(SP)
               TRAP     #GEMDOS
               ADDQ.L   #4,SP
               RTS

SCROLL_DELAY   MOVE.W   #$6000,D0
SCROLL_DELAY_1 NOP
               DBRA     D0,SCROLL_DELAY_1
               RTS

               DATA

CURSOR_END     DC.B     27,'Y'
CURSOR_END_ROW DC.B     32
CURSOR_END_COL DC.B     32
               DC.B     0

CURSOR_BEG     DC.B     27,'Y'
CURSOR_BEG_ROW DC.B     32
CURSOR_BEG_COL DC.B     32
               DC.B     0

STRING_BEG     DS.L     1
STRING_END     DS.L     1

BLACK_AND_CLEAR
               DC.B     ESCAPE,CLEAR_HOME
               DC.B     ESCAPE,SELECT_CHAR_COLOR,WHITE
               DC.B     ESCAPE,SELECT_BKGRND_COLOR,BLACK
               DC.B     ESCAPE,CLEAR_HOME,0

WHITE_AND_CLEAR
               DC.B     ESCAPE,CLEAR_HOME
               DC.B     ESCAPE,SELECT_CHAR_COLOR,BLACK
               DC.B     ESCAPE,SELECT_BKGRND_COLOR,WHITE
               DC.B     ESCAPE,CLEAR_HOME,0

LINE_1         DC.B     36,42,'* * * * *  Doctor Flop E. Disk  * * * * *  '
LINE_2         DC.B     39,14,'Sector Editor  '
LINE_3         DC.B     48,34,'Copyright (C) 1986 by Kirk Stover    '
LINE_4         DC.B     48,34,'                                     '
LINE_5         DC.B     48,34,'The doctor will see you now.......   '

               END