#! /bin/csh -f
#
# If you don't have seplib, remove "MakeMakesep" before executing this shell!
#
	rm -f Makefile Makesep
	/bin/cat << END1A >! Makefile
#
# Site-specific definitions are confined to makefiles and include files.
#
# The file "machdep" contains all machine dependent parameters for makefiles.
# MakeMake itself is machine independent!
#
END1A
/bin/cat < machdep >> Makefile
	/bin/cat << END1B >> Makefile
#
#
END1B

	set hosttype = `cat hosttype`
	echo $hosttype
	set ALL=()
	foreach dir (*lib)
		echo Doing $dir
		switch ($dir)
			case loclib:
			case genlib:
			case utillib:
				breaksw
			case imaglib:
				set ALL=($ALL ipen)
				breaksw
			case rteklib:
				set ALL=($ALL rpen)
				breaksw
			case spenlib:
				set ALL=($ALL spen)
				breaksw
			case xpenlib:
				set ALL=($ALL xpen)
				breaksw
			default:
				set thispen = `echo $dir | sed -e 's/lib/pen/'`
				set ALL = ($ALL $thispen)
				breaksw
		endsw
	end
	echo "all: $ALL" >> Makefile
	echo "" >> Makefile
	echo "install: all" >> Makefile

	if (-e machdep_restrict) then
	    set machdepres = machdep_restrict
	else
	    set machdepres = /dev/null
	endif

	foreach file ($ALL)
	    if (`grep -c $file $machdepres` > 0) then
		set group = `grep $file $machdepres | sed -e 's/^[^ 	]*[ 	]*//'`
		echo -n '	install -c -s -o $(OWNER) -g '$group' -m 0770 ' >> Makefile
	    else
		echo -n '	install -c -s -o $(OWNER) -g $(GROUP) -m 0775 ' >> Makefile
	    endif

	    echo $file '$(BIN)'$file >> Makefile
	end

	if (-e MakeMakesep) then
		echo "	make -f Makesep install" >> Makefile
	endif

	/bin/cat << 'END2' >> Makefile

.c.o:; cc -c $(CFLAGS) $*.c

$(LOCLIB): loclib/*.c
	cd loclib; make "CFLAGS=${CFLAGS}" loclib.a

$(GENLIB): genlib/*.c
	cd genlib; make "CFLAGS=${CFLAGS}"

$(UTILLIB): utilities/*.c
	cd utilities; make "CFLAGS=${CFLAGS}"

clean:
'END2'
echo "	rm -f *.o $ALL" >> Makefile
if (-e MakeMakesep) then
	echo "	make -f Makesep clean" >> Makefile
endif
echo " " >> Makefile

	foreach dir (*lib)
		switch ($dir)
			case utillib:
			case loclib:
			case genlib:
				breaksw
			default:
				cat $dir/*makef >> Makefile
				breaksw
		endsw
	end

if (-e MakeMakesep) then
	source MakeMakesep
endif
