!; JAPANESE.RUL  25-Oct-89
!; Tables generated by KGEN 30-Apr-91
!
!; Japanese Verb Conjugation
!; Data from Problem Book in Phonology, by Halle & Clements, MIT
!; Press, 1983, p. 127.
!
!; S = alveopalatal sibilant (s-wedge)
!; T = alveolar affricate (ts)
!; & = alveopalatal affricate (c-wedge)
!
;ALPHABET
;  p t k b d g m n s z j h r w y S T & +
;  i e a o u
;NULL 0
;ANY @
;BOUNDARY #
!
SUBSET C p t k b d g m n s z j h r w y S T &
SUBSET V i e a o u
SUBSET M b g m n       ; used in t:d rule
SUBSET B b m           ; used in B:n rule
SUBSET K k g           ; used in K:0 rule
SUBSET X s k g         ; used in 0:i rule
SUBSET A a i           ; used in A:0 rule
SUBSET I i u o         ; used in w:0 rule
SUBSET R r w           ; used in R:t rule

; Consonant defaults
PAIRS p t k b d g m n s z j h r w y +
      p t k b d g m n s z j h r w y 0

; Vowel defaults
PAIRS i e a o u
      i e a o u

; B:n correspondences
PAIRS b m
      n n

; K:0 correspondences
PAIRS k g
      0 0

; A:0 correspondences
PAIRS a i
      0 0

; R:t correspondences
PAIRS r w
      t t

; Voicing, t:d
; LR: sin+ta  yom+ta  yob+ta  tug+0ta
; SR: Sin0da  yon0da  yon0da  Tu00ida

; M = b g m n
; M:@ due to B:n, K:0 rules
RULE t:d <=> M:@ (+:0)(0:i)_

; Nasalization, B:n
; LR: yom+ta  yob+ta
; SR: yon0da  yon0da

; B = b m
; @:d due to t:d rule
RULE B:n <=> _(+:0) @:d

; Palatalization, s:S
; LR: kas+itai  kas+0ta  sin+yoo  sin+ta
; SR: kaS0itai  kaS0ita  Sin00oo  Sin0da

; @:i due to 0:i rule
RULE s:S <=> _(+:0) @:i

; Velar deletion, K:0
; LR: wak+0ta  tug+0ta
; SR: wa00ita  Tu00ida

; K = k g
RULE K:0 <=> _(+:0) 0:i t:@

; Epenthesis, 0:i
; LR: kas+0ta wak+0ta  tug+0ta
; SR: kaS0ita wa00ita  Tu00ida

; X = s k g
RULE 0:i <=> X:@(+:0)_t:@

; Truncation, A:0
; according to Alam 1983 this rule deletes a, i, and e
; LR: ne+anai  ne+itai  mi+anai  mi+itai
; SR: ne00nai  ne00tai  mi00nai  mi00tai

; A = a i
; morpheme boundary is obligatory
RULE A:0 <=> V +:0_

; Affrication 1, t:&
; LR: kat+itai
; SR: ka&0itai
RULE t:& <=> _(+:0)i

; Deletion, r:0
; according to Alam 1983, this rule deletes r, s, and y
; LR: sin+ru  kas+ru  kaw+ru  kat+ru
; SR: Sin00u  kas00u  ka000u  kaT00u

; C:@ due to w:0 rule
RULE r:0 <=> C:@(+:0)_

; Affication 2, t:T
; LR: kat+ru  tug+yoo
; SR: kaT00u  Tug00oo

RULE t:T <=> _(+:0 C:@)u

; w-deletion, w:0
; LR: kaw+itai  kaw+yoo  kaw+ru
; SR: ka00itai  ka000oo  ka000u

RULE w:0 <=> _(+:0)(C:0)I

; y-deletion
; LR: ne+yoo  sin+yoo
; SR: ne0yoo  Sin00oo

RULE y:0 <=> C:@ (+:0)_

; Assimilation, R:t
; LR: kar+ta  kaw+ta
; SR: kat0ta  kat0ta

; R = r w

RULE R:t <=> _(+:0)t
