@echo off
:: Lets Clear the screen and get to work
cls
Echo Welcome to Doe Entertainment (R) (c)1994
Echo Enclosed is Quatra Command(tm) by Doe Entertainment(R)
Echo .
if %1x == x goto help
if %2x == x goto help
Echo This will copy all the Quatra Command(tm)
Echo files to %2\Quatra
Echo .
Echo Press Ctrl Break to abort
Echo or
Echo any other key now ... To continue
pause >nul
:: overwrite and create the Quatra directory on the
:: drive specified by the user.
%1Unzip -d -o %1QCWGAME.ZIP %2\

:: copy the Quatra.ini file if there is a windir enviroment varible
if %windir%x == x goto NOWINDIR

:: There was a environment variable to copy to
copy %2\Quatra\PLAYDOE.INI %windir%
goto HOWTOO

:NOWINDIR
:: if there is no windir environment variable then tell user
:: to copy the file..
echo .
echo You must copy the %2\Quatra\PLAYDOE.INI file
echo to your windows directory.
Echo .
Echo Quatra Command(tm) Now Installed in the %2\Quatra
Echo .
echo Please Run Windows...
goto winrun

:HOWTOO
:: Tell User how to run the program
Echo .
Echo Quatra Command(tm) Now Installed in the %2\Quatra
Echo .

:WinRun
:: Now That they know how, lets put them there
echo .
echo Choose RUN from the File menu
echo and enter %2\Quatra\QUATRA.EXE
echo .
Echo Press any key to continue
%2
CD %2\Quatra
pause>nul
goto END

:help
echo Quatra Installation error
echo game: QUATRA COMMAND(tm)
echo ------------------------------------------------------------------
echo Usage: INSTALL [source:] [destination:]
echo ------------------------------------------------------------------
echo Example:  INSTALL A: C:  -- Will install Quatra from A: to the C: drive
echo -
Echo Press any key to continue
pause >nul

:END
