;*********************************************************************;
; Sciptname..:  PROMOTE1.SHW                                          ;
; Date.......:  1st. Sep. 1992, by RMP DATA.                          ;
; Purpose....:  Promotion for DATASHOW v. 3.0A, as an example script. ;
;*********************************************************************;

; Other files involved:
; sound1.shw                   ; Tight sound loop file
; scroll1.shw                  ; Tight scrool loop file
; promote1.gra, hugo1.gif      ; Graphic files
; entrance.snd, napoleon.snd   ; Music files
; show1.scr - show7.scr        ; Captured screen files

IF HIGRAPH DO JUMPMARK 10      ; check the graphics adapter

CLEARSCREEN
WRITE "I'M SORRY, BUT THIS PRESENTATION ONLY WORK ON VGA SCREENS!"
GOXY 1 2
WAIT "PUSH ANY KEY..."
QUIT

MARK 10

SET GRAPHICS EGA1              ; Make graphics at beginning of this script

SET ESCAPEKEY 27               ; Make sure script can be stopped any time
SET TIMEOUT 10                 ; Set seconds to wait for keyboard (WAITKEY)

VARIABLE CREATE counttimes TYPE NUMBER 1   ; Variable to count number of runs

COLOR ATTRIBUTE 31             ; Set to blue background, white forground
COLOR BACKGROUND 1             ; Set the background to blue
COLOR FOREGROUND 15            ; Set the foreground to white
CLEARSCREEN

SET DELAYFACTOR 5

SET SHADOW 79

GOXY 28 2
WRITE "Welcome to a presentation of"

EFFECT TEXTTYPE 3 6
GOXY 28 3
WRITE "DataShow"
EFFECT TEXTTYPE 0 1

GOXY 10 12
DRAW LINE 60

GOXY 10 20
DRAW LINE 60

GOXY 1 14

SPEAK "W-E-L-L-K-U-M-E"        ; Talk via system speaker

SPEAK "T-OO D-A-TH-A-S-H-U-W"

DEFINE
///////    //////   ///////   //////    ///////  //    //  ///////  //  //  //
//    //  //    //    //     //    //  //        //    //  //   //  //  //  //
//    //  ////////    //     ////////  ////////  ////////  //   //  //  //  //
//    //  //    //    //     //    //        //  //    //  //   //   // // //
///////   //    //    //     //    //  ///////   //    //  ///////    //////
ENDDEFINE

SET DELAYFACTOR 0              ; Set waiting period to zero

MOTION LEFT 0                  ; Move defined area across screen

MOTION RIGHT 79                ; Move defined area partly back on screen

EFFECT TEXTTYPE 1 6
GOXY 30 20
WRITE "V. 3.0A"
EFFECT TEXTTYPE 0 1

SET SHADOW OFF

WAIT 3

SET GRAPHICS OFF

SET CURSOR OFF

SHOWSCREEN "show1.scr" TXT     ; Show screen saved with CAPTURE

MUSIC PROCESS "entrance.snd"

WAIT 1

COLOR BACKGROUND 3             ; Set the background to cyan
CLEARSCREEN

GOXY 1 20
WINDOW 79 4
COLOR BACKGROUND 7
CLEARSCREEN

GOXY 1 1
WINDOW 79 24

COLOR ATTRIBUTE 63             ; Set to cyan background, white forground

GOXY 6 2
DRAW BOX 70 14

SET CURSOR ON

SET DELAYFACTOR 5

GOXY 10 4
WRITE "Together with the resident program CAPTURE, you can create pre-"
GOXY 10 6
WRITE "sentations fast and easy. You CAPTURE screens from programs and"
GOXY 10 8
WRITE "show them from DATASHOW like this screen to be shown here......"

WAIT 2

GETSCREEN                      ; Save the current screen to a buffer
SET CURSOR OFF
SHOWSCREEN "show2.scr" TXT     ; Show screen saved with CAPTURE
WAIT 2
SPEAK "C-A-P-T-U-R-E"
WAIT 1
SPEAK "AE"
SPEAK "S-K-R-EE-EE-N"
WAIT 2
SET CURSOR ON
PUTSCREEN                      ; Retrieve saved screen from the buffer

GOXY 10 10
WRITE "It is a simple task  to create scripts  and have them  shown on"
GOXY 10 12
WRITE "the screen  with encredible  flexibility.  Scripts are ordinary"
GOXY 10 14
WRITE "ASCII files.  Here the easy method to make scripts is shown..."

SPEAK "P-U-S-H"
WAIT 1
SPEAK "A-N-I"
WAIT 1
SPEAK "K-E-I"

GOXY 10 20
WAIT "Push any key"            ; Wait for any key to be pushed or TIMEOUT

SET CURSOR OFF
COLOR ATTRIBUTE 0

SHOWSCREEN "show3.scr" TXT     ; Show screen saved with CAPTURE
WAIT 4

SHOWSCREEN "show4.scr" TXT     ; Show screen saved with CAPTURE
WAIT 4

SHOWSCREEN "show5.scr" TXT     ; Show screen saved with CAPTURE
WAIT 4

EFFECT GLITTER
WAIT 1

SET TEXTSOUND ON

COLOR BACKGROUND 4             ; Set the background to red
CLEARSCREEN
GOXY 10 4
WRITE "You can also write your scripts to a printer!"
WAIT 3

SHOWSCREEN "show6.scr" TXT     ; Show screen saved with CAPTURE
WAIT 2

COLOR BACKGROUND 3             ; Set the background to cyan
GOXY 13 5
WRITE "PROMOTE1.SHW"
WAIT 3

COLOR ATTRIBUTE 63
SET TEXTSOUND OFF
SET DELAYFACTOR 0

CLEARSCREEN
GOXY 10 10
DRAW BOX 32 2
GOXY 11 11
WRITE "You can create single sounds..."

VARIABLE CREATE controlloop TYPE NUMBER 1  ; Variable to control loops

MARK 1                         ; Create a mark that can be jumped to

VARIABLE CREATE soundloop TYPE NUMBER 1    ; Variable to control sound

DO "sound1.shw"                ; Call another (sub) program

VARIABLE RELEASE soundloop     ; Clean up after us, for next time round

EFFECT SCROLL DOWN

IF controlloop 3 DO JUMPMARK 2

VARIABLE INCREASE controlloop 1

JUMPMARK 1

MARK 2                         ; Create a mark that can be jumped to

VARIABLE RELEASE controlloop   ; Clean up after us, for next time round

WAIT 1

GOXY 20 8
WRITE "Or play songs, that you write yourself!"
GOXY 20 9
DRAW LINE 38
MUSIC PROCESS "napoleon.snd"

WAIT 1

COLOR BACKGROUND 2             ; Set the background to green
CLEARSCREEN
GOXY 10 8
WRITE "Besides this you can control a lot of things yourself.  You can"
GOXY 10 10
WRITE "draw your own pictures  or  devellop your own logo in DATASHOW."
GOXY 10 12
WRITE "For this purpose there is a menu for graphic drawing..."
WAIT 6

SHOWSCREEN "show7.scr" TXT     ; Show screen saved with CAPTURE
WAIT 4

SET DELAYFACTOR 5
GOXY 26 12
WINDOW 50 5
CLEARSCREEN
COLOR FOREGROUND 1
GOXY 26 12
COLOR ATTRIBUTE 47             ; Set to green background, white forground
DRAW BOX 50 5
GOXY 3 3
WRITE "By selecting F4 you can draw your own drawings,"
GOXY 3 4
WRITE "and then display them from a script like this.."
WAIT 4
GOXY 1 1
WINDOW 79 24

SET GRAPHICS EGA1

SHOWSCREEN "promote1.gra" GRA
WAIT 4

EFFECT GLITTER

CLEARSCREEN
GOXY 10 10
WRITE "You can also show GRAPHICs created from other programs."
GOXY 10 12
WRITE "Here DataShow display a screen saved in the PCX format -"
GOXY 10 14
WRITE "saved from e.g. the program PaintBrush (TM)."
WAIT 4
SHOWSCREEN "chess.pcx" PCX
WAIT 4

SET GRAPHICS EGA1

CLEARSCREEN
GOXY 10 10
WRITE "AND here DataShow displays a screen saved in the GIF"
GOXY 10 12
WRITE "format; made by CompuServe; with a wealth of files."
WAIT 4
SHOWSCREEN "hugo1.gif" GIF
WAIT 4

SET GRAPHICS EGA1

COLOR BACKGROUND 1
COLOR FOREGROUND 12
CLEARSCREEN

SET DELAYFACTOR 4

GOXY 5 8
WRITE "NEW in DataShow scripts:"
GOXY 5 12
WRITE "Now you can also stay in graphics mode"
GOXY 5 16
WRITE "- and most commands work as in text mode!"
WAIT 3

COLOR BACKGROUND 6
COLOR FOREGROUND 14
CLEARSCREEN
GOXY 10 5
WRITE "Remember to register DataShow. You'll then recieve:"
WAIT 2
SET DELAYFACTOR 0
COLOR FOREGROUND 11
GOXY 12 9
WRITE "- A Runtime version called SHOWRUN for distribution of scripts"
WAIT 3
GOXY 12 11
WRITE "- A Manual that can be printed on a printer for overview"
WAIT 3
GOXY 12 13
WRITE "- A Utility package for making more music files"
WAIT 3
GOXY 12 15
WRITE "- And more music and graphics files"
WAIT 3
COLOR FOREGROUND 14
GOXY 10 19
WRITE "See the READ.ME ascii file for further information!"
WAIT 4

SET GRAPHICS OFF

VARIABLE CREATE COUNTTIMES TYPE NUMBER 1

DO "scroll1.shw"               ; Call another (sub) program

COLOR FOREGROUND 15

SET SHADOW 2

GOXY 1 8
WRITE "This was run number: "
GOXY 25 8
WRITE counttimes
SPEAK counttimes
WAIT 1
SPEAK "T-I-M-E-S"
WAIT 1

GOXY 10 11
WRITE "Now this presentation starts over again, but you can stop it at"
GOXY 10 13
WRITE "any time you wish by pressing the escape key.  Then in DATASHOW"
GOXY 10 15
WRITE "you can try all the marvelous things yourself!   Just type SHOW"
GOXY 10 17
WRITE "at the operating system prompt, and you can try out DataShow."
WAIT 1

GOXY 10 20
WRITE "That's all folks..."

SPEAK "TH-A-T-S AH-L-L F-OH-L-K-S"

SET SHADOW OFF

WAIT 8

SET CURSOR ON

VARIABLE INCREASE counttimes 1

CONTINUE