!DEFAULT OSVERS='D00',YOURWSN='LOCAL',DIRACCT='KERMIT',DEST='*LS'
!JOB NAME=KERMIT,WSN=YOURWSN
!RES MEM=256,TIME=10
!ORES MEM=256
!"
!"  If you have not already done so, read the HC6KERMIT_BLD file and
!"  XEQ HC6KERMIT_INS prior to XEQ/BATCHing this file.
!"
!"  By default, the output created by this job is EDGEMARKed.
!"  However, if you do NOT want it EDGEMARKed, do a DEST=LP substitution on
!"  your BATCH or XEQ command such as:
!"    !BATCH HC6KERMIT_BAT DEST=LP
!"
!   DIR .DIRACCT
!   LET LISTING = 'DEST'
!   LET OS_VERSION='OSVERS'
!   LET IM_BATCH = 0
!   IF $MODE='BATCH' THEN LET IM_BATCH = 1
!   LET TO_OK = $FID_EXIST('TO.:SYS')
!"
!   DEL *HC6KERMIT_PAROU
!"
!   IF TO_OK .AND. IM_BATCH THEN TO A=%$ACCT KERMIT just started.
!"
!   IF OS_VERSION='B03' THEN GOTO ITS_FOR_B03
!"
!   PL6 HC6KERMIT_PL6,HC6KERMIT_UPD_PL6 OVER *HC6KERMIT_PL6OU,DEST (LS,OU,SC,OPTUI)
!   LET PL6STEPCC = STEPCC
!   PARTRGE HC6KERMIT_PAR,HC6KERMIT_UPD_PAR INTO *HC6KERMIT_PAROU,DEST (LS,OU,OPTUI)
!   IF PL6STEPCC + STEPCC > 0 THEN GOTO SHOULD_WE_EDGEMARK
!   LINK ;
      *HC6KERMIT_PL6OU,;
      *HC6KERMIT_PAROU ;
    OVER ;
      KERMIT(IP=100,DP=10,DCB2=F$DEFAULTS)
!   GOTO SHOULD_WE_EDGEMARK
!"
!ITS_FOR_B03:
!   PL6 HC6KERMIT_PL6,HC6KERMIT_UPD_PL6 OVER *HC6KERMIT_PL6OU,DEST (LS,OU,SC,SR(.X,.),OPTUI)
!   LET PL6STEPCC = STEPCC
!   PARTRGE.X HC6KERMIT_PAR,HC6KERMIT_UPD_PAR INTO *HC6KERMIT_PAROU,DEST (LS,OPTUI)
!   IF PL6STEPCC + STEPCC > 0 THEN GOTO SHOULD_WE_EDGEMARK
!   LINK ;
      *HC6KERMIT_PL6OU,;
      *HC6KERMIT_PAROU,;
      XUW$WILDCARD.X ;
    OVER ;
      KERMIT(IP=100,DP=10,DCB2=F$DEFAULTS)
!"
!SHOULD_WE_EDGEMARK:
!   IF LISTING = 'LP' THEN GOTO HERMANIZE
!   LET MONNUM=$SUBSTR($DATE,2,2)
!   LET MONTHS='JanFebMarAprMayJunJulAugSepOctNovDec'
!   LET RIGHT=$SUBSTR(MONTHS,(MONNUM*3)-3,3) || ' ' || $SUBSTR($DATE,4,2)
!   IF $SUBSTR(RIGHT,4,1) ~= '0' THEN GOTO DATE_OK
!   LET RIGHT= $SUBSTR(RIGHT,0,4) || $SUBSTR(RIGHT,5,1)
!DATE_OK:
!   EDGEMARK.X DEST ON LP@YOURWSN (FORM='PERF',L='KERMIT',R='%RIGHT')
!"
!HERMANIZE:
!   HERMAN.X HC6KERMIT_HER OVER HELP:KERMIT:,NO
!"
!ASK_HERMAN_QUESTION:
!   IF $MODE .NE. 'ONLINE' THEN GOTO ALL_DONE
!   LET ANS=$INPUT('Were there warnings in the above HERMAN messages? ')
!   IF $LEN(ANS) = 0 THEN GOTO WAKE_THEM_UP
!   LET ANS= $SUBSTR(ANS,0,1)
!   IF ANS = 'Y'  .OR.  ANS = 'y' THEN GOTO FIX_HERMAN_SOURCE
!   IF ANS = 'N'  .OR.  ANS = 'n' THEN GOTO WAKE_THEM_UP
!   GOTO ASK_HERMAN_QUESTION
!"
!FIX_HERMAN_SOURCE:
!   EDIT
    COPY HC6KERMIT_HER,1,1
    SE0-9999;/*K* '/?/'/?/ /S/*K* /?1//?2/ /
    END
!"
!   HERMAN.X HC6KERMIT_HER OVER HELP:KERMIT:,NO
!"
!WAKE_THEM_UP:
!   IF IM_BATCH THEN GOTO ALL_DONE
!   C ME TO ME(ORG=T)

!"
!ALL_DONE:
!   IF IM_BATCH THEN TO A=%$ACCT KERMIT just finished.
!"
!EOJ: