10 CLS: DEFINT A-Z
20 DIM BD(28),DA(12,7,6),DM(12),M$(12)
30 FOR T=1 TO 12: READ DM(T): NEXT
40 FOR T=1 TO 28: READ BD(T-1): NEXT
50 FOR T=1 TO 12: READ M$(T): NEXT
60 INPUT "WHAT YEAR "; Y
70 X=Y-14: IF X<0 THEN 60
80 X= Y - (INT(X/28)*28 +14)
90 IF Y/4 = INT(Y/4) THEN DM(2)=29 ELSE DM(2)=28
100 C2=1:CO=BD(X)-1
110   FOR T=1 TO 12
120 C3=C3+1:CO=CO+1:DA(T,CO,C2)=C3:IF CO=7 THEN CO=0:C2=C2+1
130 IF C3<>DM(T) THEN 120 ELSE C3=0:C2=1
140   NEXT:  PRINT
150   FOR T=1 TO 12 STEP 3
160 LOCATE,10: PRINT M$(T) TAB(37) M$(T+1) TAB(63) M$(T+2): PRINT
180 PRINT "    S  M  T  W  T  F  S" TAB(29) "  S  M  T  W  T  F  S" TAB(55)        "  S  M  T  W  T  F  S"
190     FOR TR=1 TO 6
200       FOR TRR=1 TO 3
210 LOCATE ,(TRR-1)*26+2: PRINT " ";
220         FOR TT=1 TO 7
230 D=DA(T+TRR-1,TT,TR)
240 IF D=0 THEN D$="   ": GOTO 260
250 D$=RIGHT$(" "+STR$(D),3)
260 PRINT D$;
270         NEXT
280       NEXT:  PRINT
290     NEXT
300   NEXT
310 END
320 DATA 31,28,31,30,31,30,31,31,30,31,30,31,3,4,5,7,1,2,3,5,6,7,1,3,4,5,6,1,2,3,4,6,7,1,2,4,5,6,7,2," JANUARY ","FEBRUARY","  MARCH  ","  APRIL  ","  MAY  ", "  JUNE  ","  JULY  "," AUGUST ","SEPTEMBER","OCTOBER","NOVEMBER"
330 DATA "DECEMBER "