// COPY LIBRARY-P,NAME-VTOC01
*
* VTOC ANALYSIS REPORT
*
* ANALYZES DISK VTOC FOR FILES APPROCHING THEIR CURRENT RECORD ALLOCATION
*
* USAGE: VTOC <PERCENTAGE>
*        WHERE PERCENTAGE IS THE MINIMUM PERCENTAGE OF FILE AVAILABLE
*
* Copyright 1988,89 by David Gibbs, SysOp
*                   The Midrange System BBS
*                   312-439-9679
*
* This program many be freely distributed in any way shape or form as long
* as no fee is charged for the access or distribution.
*
*
// IF DATAF1-VTOC01   DELETE VTOC01,F1
*
// LOAD $LABEL
// RUN
// DISPLAY UNIT-F1,LABEL-ALL,SORT-NAME,OUTPUT-VTOC01
// END
*
// LOAD #GSORT
// FILE NAME-INPUT,LABEL-VTOC01
// FILE NAME-OUTPUT,LABEL-VTOC01,DISP-OLD
// RUN
     HSORTR     8A        3X 132       * SORT VTOC FILE
     I C      22EQCI                   * INCLUDE INDEXED FILES
     IAC      16EQC/
     IOC      22EQCS                   * AND SEQUENTIAL
     IAC      16EQC/
     FNC   1   8                       * SORT ON FILE NAME
     FDC   1 132                       * OUTPUT ENTIRE RECORD
// END
*
// EVALUATE P1,3=?1'025'?
// LOCAL OFFSET-100,DATA-'?1?'
*
// LOAD VTOC01
// FILE NAME-VTOC01,RETAIN-S
// RUN
*
// CEND
// COPY LIBRARY-S,NAME-VTOC01
0001 U                       P                                            VTOC01
0002 H    P064                      B       1                             VTOC01
0003 F*                       *   *  *****   ***     **    ***     *
0004 F*                       *   *    *    *   *   *  *  *   *   **
0005 F*                       *   *    *    *   *  *      *   *    *
0006 F*                       *   *    *    *   *  *      * 0 *    *
0007 F*                       *   *    *    *   *  *      *   *    *
0008 F*                        * *     *    *   *   *  *  *   *    *
0009 F*                         *      *     ***     **    ***   *****
0010 F*
0011 F*
0012 F*          AUTHORED BY DAVID GIBBS              DATE 10/05/88
0013 F*
0014 F*  PROGRAM DESCRIPTION -
0015 F*    ANALIZES DISK VTOC TO DETERMINE WHAT FILES ARE APPROCHING
0016 F*    SPECIFIED RECORD ALLOCATION
     F*
     F* This program many be freely distributed in any way shape or
     F* form as long as no fee is charged for the access or distribution.
     F*
     F* Copyright 1988 by David Gibbs, SysOp
     F*                   The Midrange System BBS
     F*                   312-439-9679
0017 F*
0018 F*
0019 F*  REVISION
0020 F*    DATE    BY   VERS   CHANGES
0021 F*
0022 F*
0023 F*
0024 F*
0025 F*
0026 F*
0027 F*
0028 F*
0029 F*  ********************** INDICATOR SUMMARY **********************
0030 F*
0031 F*  ID   F    C    EX   L    FUNCTION OF INDICATORS
0032 F*
0033 F*      01                   RECORD IDENTIFICATION INDICATOR FOR VTOC
0034 F*           10              CONDITIONS INCLUSION IN REPORT
0035 F*
0036 F*
0037 F*
0038 F*
0039 F*
0040 F*
0041 F*
0042 F*
0043 F*
0044 F*
0045 FVTOC01  IP    132 132            DISK
0046 FREPORT  O     132 132     OF     PRINTER
0047 IVTOC01  AA  01
0048 I                                        1   8 LABEL
0049 I                                       11  18 DATE
0050 I                                       22  22 TYPE
0051 I                                       50  570USED
0052 I                                       59  660AVAIL
0053 I                                       79  860ALLOC
0054 I*
0055 I           UDS
0056 I                                      100 1022PCENT
0057 C           ONCE      DO   *ZERO     ONCE    10       ONLY DO ONCE
0058 C* CALCULATE FACTOR BY WHICH TO INCREASE ALLOCATION
0059 C           PCENT     ADD  1         FACTOR  32
0060 C                     END
0061 C*
0062 C           ALLOC     IFNE *ZERO
0063 C           USED      DIV  ALLOC     FILLED  32
0064 C                     ELSE
0065 C                     Z-ADD*ZERO     FILLED
0066 C                     END
0067 C           1         SUB  FILLED    REMAIN  32
0068 C           REMAIN    COMP PCENT                  1010
0069 C           ALLOC     MULT FACTOR    NEWALO  80
0070 OREPORT  H                *AUTO
0071 O                                      'VTOC ANALYSIS REPORT'
0072 O        D        01 10   *AUTO
0073 O                         LABEL        'LABEL'
0074 O                         DATE         'DATE'
0075 O                         TYPE         'TYPE'
0076 O                         USED  Z      ''
0077 O                                C     'USED'
0078 O                         AVAIL Z      'RECORDS'
0079 O                                C     'AVAILABLE'
0080 O                         ALLOC Z      ''
0081 O                                C     'ALLOCATED'
0082 O                         REMAINZ      'PERCENTAGE'
0083 O                                C     'REMAINING'
0084 O                         NEWALOZ      'RECOMMENDED'
0085 O                                C     'ALLOCATION'
// CEND
                                                                                                                               