dnl Process this file with autoconf to produce a configure script.
AC_INIT(find/pred.c)
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_RANLIB
AC_AIX
AC_MINIX
AC_ISC_POSIX
AC_SCO_INTL
AC_MAJOR_HEADER
AC_DIR_HEADER
echo checking how to get filesystem type
# SVR4.
AC_TEST_CPP([#include <sys/statvfs.h>
#include <sys/fstyp.h>], AC_DEFINE(FSTYPE_STATVFS) fstype=1)
if test -z "$fstype"; then
# SVR3.
AC_TEST_CPP([#include <sys/statfs.h>
#include <sys/fstyp.h>], AC_DEFINE(FSTYPE_USG_STATFS) fstype=1)
fi
if test -z "$fstype"; then
# AIX.
AC_TEST_CPP([#include <sys/statfs.h>
#include <sys/vmount.h>], AC_DEFINE(FSTYPE_AIX_STATFS) fstype=1)
fi
if test -z "$fstype"; then  
# 4.3BSD.
AC_TEST_CPP([#include <mntent.h>], AC_DEFINE(FSTYPE_MNTENT) fstype=1)
fi
if test -z "$fstype"; then  
# 4.4BSD.  Also DEC OSF/1.
AC_HEADER_EGREP(f_type;, sys/mount.h, AC_DEFINE(FSTYPE_STATFS) fstype=1)
fi
if test -z "$fstype"; then  
# Ultrix.
AC_TEST_CPP([#include <sys/mount.h>
#include <sys/fs_types.h>], AC_DEFINE(FSTYPE_GETMNT) fstype=1)
fi

AC_UID_T
AC_CONST
AC_STDC_HEADERS
AC_UNISTD_H
AC_HAVE_HEADERS(string.h limits.h)
AC_REPLACE_FUNCS(memset stpcpy strdup strftime strspn strstr strtol)
AC_HAVE_FUNCS(strerror)
AC_VPRINTF
AC_ALLOCA
AC_ST_BLOCKS
AC_ST_RDEV
AC_STRUCT_TM
AC_TIMEZONE
AC_XENIX_DIR
AC_IRIX_SUN
AC_DYNIX_SEQ
AC_OUTPUT(Makefile lib/Makefile find/Makefile xargs/Makefile locate/Makefile man/Makefile)