1i\
# Makefile generated by "gcc-emx.cmd"\
default: all.emx
/^target=/c\
target=emx
/^xmake_file=/c\
.SUFFIXES: .o\
all.emx: cccp xgcc $(LANGUAGES)
/^tmake_file=/d
/^version=/c\
VERSION
s/CC = cc/CC = gcc/
s/:\$/: \$/g
s/^	\.\//	.\\/
s/^	\$(srcdir)\/move-if-change/	updt/
s/ \$(srcdir)\/move-if-change$//
/^USE_HOST_OBSTACK=/c\
USE_HOST_OBSTACK=obstack.o
s/^SHELL=/# SHELL=/
s/^USE_/# USE_/
s/`echo \$(srcdir)\///g
s/ | sed 's,\^\\\.\/,,'`//g
s/^	cd \$(srcdir)[	 ]*;[	 ]*/	/
/^[	 ]*\\$/d
/^enquire[ 	]*:/ s/\$(GCC_PARTS)//g
/^enquire.o[ 	]*:/ s/\$(GCC_PASSES)//g
s///
s/^C c:/C c :/
s/${\([^}]*\)}/$(\1)/g
/-DGCC_INCLUDE_DIR=.*\\/d
/-DGPLUSPLUS_INCLUDE_DIR=.*\\/d
/-DLOCAL_INCLUDE_DIR=.*\\/d
/-DCROSS_INCLUDE_DIR=.*\\/d
/-DSTANDARD_STARTFILE_PREFIX=.*\\/d
/-DSTANDARD_EXEC_PREFIX=.*\\/d
/-DDEFAULT_TARGET_MACHINE=.*\\/d
/^GCC_FOR_TARGET =/c\
GCC_FOR_TARGET = gcc
s/\(gen[a-z*]*\)\([^.*a-z]\)/\1.exe\2/g
s/\(gen[a-z*]*\)$/\1.exe/
s/generate\([a-z*]*\).exe/generate\1/g
s/\(bi-[a-z*]*\)\([^.*a-z]\)/\1.exe\2/g
s/\(bi-[a-z*]*\)$/\1.exe/
/if cmp -s \$(PREMADE_ATTRTAB_MD) md/,/fi/c\
	.\\genattrtab.exe md > tmp-attrtab.c
/^Makefile:/,/sh/s/^/# /
s/^	-rm -f /	del /
s/^	mv -f /	ren /
s/ ;$//
/# Go via `gccnew'/a\
	-del gcc
/^LANGUAGES =/c\
LANGUAGES = c c++ objective-c
/^objc-runtime: libobjc\.a$/c\
objc-runtime:
s/ ; @true$//