/* emxinst.cmd */

call RxFuncAdd "SysLoadFuncs", "RexxUtil", "SysLoadFuncs"
call SysLoadFuncs

version = '0.8h'

say 'emxinst' version '-- Copyright (c) 1993 by Eberhard Mattes'

parse arg arg1 rest

if arg1 \== '' then do
  say 'Usage: emxinst'
  exit 1
end

location = '<EM_emx_'||version||'_FOLDER>'

call make_folder
call make_book 'emxbook', 'Programming Manual', ''
call make_book 'libref', 'Library Reference', ' [Topic]'
call make_book 'emxrt', 'Run-Time Guide', ''

say 'emx' version 'folder successfully created.'

exit

make_folder: procedure expose location version
  if \SysCreateObject('WPFolder', 'emx '||version, '<WP_DESKTOP>', ,
                      'OBJECTID='||location, 'update') then do
    say 'Cannot create folder.'
    exit 1
  end
  return

make_book: procedure expose location
  parse arg name, title, parm
  if \SysCreateObject('WPProgram', title, location, ,
                      'PROGTYPE=PM;EXENAME=VIEW.EXE;PARAMETERS='||name||parm, ,
                      'update') then do
    say 'Cannot create book object.'
    exit 1
  end
  return