* AWARDPRNT VERSION 860510 THIS PROGRAM PRINTS A award file
*COPYRIGHT  (C) 1986    G3ZCZ
IF pf ='Y'
   SET PRINT ON
ENDIF

STORE 99 TO linecount
STORE  1 TO pagecount
STORE  0 TO qsled
STORE  0 TO worked

USE  &award INDEX &award

DO WHILE .NOT.EOF
   IF linecount > 60
      EJECT
      ? award,' PRINTOUT as of ',DATE (),' FOR ',callsign,' PAGE',pagecount
      IF choice = 'Q'
         ?? ' QSL STATUS'
      ENDIF
      STORE pagecount + 1 TO pagecount
      ?
      ? ' PX         CALL       DATE    TIME BND MODE '
      ?? 'STATUS'
      ? '--------------------------------------------'
      ?? '-------'
      STORE 5 TO linecount
   ENDIF

   IF dstate = ' ' .AND. choice <> 'P'
   ELSE
      IF dstate = 'W' .AND. choice = 'Q'
      ELSE
         ? pc,dcall,ddate,dtime,dband,dmode,dstate
         STORE linecount + 1 TO linecount
      ENDIF
   ENDIF
   IF dstate = 'R'
      STORE qsled + 1 TO qsled
      STORE worked + 1 TO worked
   ENDIF
   IF dstate = 'W'
      STORE worked + 1 TO worked
   ENDIF
   SKIP
ENDDO
?
?
? worked,' WORKED     ',qsled,'QSL-D'
?
EJECT
SET PRINT OFF

RELEASE choice,linecount,pagecount,worked,qsled
IF pf = 'Y'
ELSE
   WAIT
ENDIF
RETURN