10  'HENKAN.BAS  ｢Ｄ.Ｔ.Ｆ.｣  LZW圧縮←→非圧縮変換プログラム
20  ON ERROR GOTO *ERRSUB
30  SCREEN 0:SCREEN@ 0:CLS
40  '
50  'INDR$ ="F:\FRICO\"
60      '入力元のパスを指定して下さい｡
70      '最後には\が付くようにしてください｡
80  '
90  'OUTDR$="F:\FRICO\"
100      '出力先のパスを指定して下さい｡
110      '最後には\が付くようにしてください｡
120      '出力先に既に同じファイル名がある場合は､勝手に上書きします｡
130      '入力元と出力先を同じにすることもできます｡(上書きになります)
140  '
150  HENKAN=0
160      '0 か 1 を指定して下さい｡
170      '   HENKAN=0 なら､   →「非圧縮 」に変換して出力
180      '   HENKAN=1 なら､   →「LZW圧縮」に変換して出力
190  '
200  '以上で指定箇所は終わりです｡プログラムを実行して下さい｡
210  '実行には､ある程度時間がかります｡
220  '
230  B$="SAGG.TIF"  :X=319:Y=239:PALT=0      :GOSUB *LKS
240  B$="SAMM.TIF"  :X=319:Y=239:PALT=0      :GOSUB *LKS
250  B$="SASUB1.TIF":X=639:Y=479:PALT=1      :GOSUB *LKS
260  B$="SASUB2.TIF":X=639:Y=479:PALT=1      :GOSUB *LKS
270  A$="SBH"       :X=639:Y=479:PALT=0      :GOSUB *SUB1
280  A$="SBOO"      :X=639:Y=191:PALT=0:M=27 :GOSUB *SUB2
290  A$="SCOO"      :X=319:Y=191:PALT=0:M=4  :GOSUB *SUB2
300  A$="SDOO"      :X=639:Y=159:PALT=0:M=6  :GOSUB *SUB2
310  A$="SYOO"      :X=287:Y=239:PALT=0:M=2  :GOSUB *SUB2
320  A$="SZOO"      :X=639:Y=239:PALT=0:M=2  :GOSUB *SUB2
330  END
340  '
350 *SUB1
360  FOR I=0 TO 3
370   B$=A$ + RIGHT$(STR$(1000+I),1) + ".TIF":GOSUB *LKS
380  NEXT
390  RETURN
400  '
410 *SUB2
420  FOR I=1 TO M
430   B$=A$ + RIGHT$(STR$(1000+I),3) + ".TIF":GOSUB *LKS
440  NEXT
450  RETURN
460  '
470 *LKS
480  LOADF=1
490  LOAD@ INDR$  + B$
500  LOADF=0
510  KILLF=1
520  KILL  OUTDR$ + B$
530  KILLF=0
540  SAVEF=1
550  SAVE@ OUTDR$ + B$ , (0,0)-(X,Y),PALT,HENKAN
560  SAVEF=0
570  RETURN
580  '
590 *ERRSUB
600  S$= "エラーです｡  ERR=" + STR$(ERR) + " :     ERL=" + STR$(ERL)
610  IF ERR=63 AND KILLF=1 THEN RESUME NEXT
620  IF ERR=63 AND LOADF=1 THEN S$=INDR$ + B$ + "が見つかりません"
630  IF ERR=63 AND SAVEF=1 THEN S$=OUTDR$ + ":出力先をチェックして下さい"
640  CLS:PRINT S$
650  RESUME 330