# ライフゲーム　　By JOUJI
# Usage:jgawk -f life.awk life.dat [-{fmr|towns|98}]

# d[y]:回りの生の数を表す文字列
# s[y]:今の状態を表す文字列

BEGIN {
	con="/dev/stdin"
	err="/dev/stderr"
	for(i=1; i<ARGC; i++)
		if(ARGV[i]~/^-/) {
			if(ARGV[i]~/^-[FTft]/) {
				csroff="\x1b[1v"
				csron="\x1b[0v"
			} else if(ARGV[i]~/^-9/) {
				csroff="\x1b[>5h"
				csron="\x1b[>5l"
			}
			ARGV[i]=""
		}
	printf("\x1b[2J%s",csroff) >err
	printf("%12s    世代 000\n",ARGV[1])
}

{
	print
	l=jlength($0)
	if(l>xm) xm=l
	s[++j]=$0
}

END {
	xm++
	ym=j+1
	d0=sprintf("%0" xm+1 "d",0)
	for(y=1;y<ym;y++) d[y]=d0
	for(g=1;;g++) {
		printf("世代増分('Q'で終了) >\x1b[0K") >err
		if(g<gm) print "" >err
		else {
			printf("%s",csron) >err
			getline <con
			if(/[Qq]/) exit
			printf("%s",csroff) >err
			if($0>0) gm=g+$0
		}
		for(y=1;y<ym;y++) {
			while( x=jindex(s[y],"●") ) {
				sub("●","◎",s[y])
				for(j=y-1;j<y+2;j++)
					d[j]=substr(d[j],1,x-1) \
						add1(substr(d[j],x,3)) substr(d[j],x+3)
			}
			gsub("◎","●",s[y])
		}
		for(y=1;y<ym;y++) {
			p=substr(d[y],2,xm-1)
			gsub(/3/,"●",p)
			gsub(/[0-25-9]/,"　",p)
			while( x=match(p,/4/) ) {
				sub(/4/, substr(s[y],x,2), p)
			}
			s[y]=p
			d[y]=d0
		}
		printf("\x1b[%dA",ym+1) >err
		printf("%12s    世代 %03d\n",ARGV[1],g)
		for(y=1;y<ym;y++) print s[y]
	}
}

function add1(s) {
	gsub(/8/,"9",s)
	gsub(/7/,"8",s)
	gsub(/6/,"7",s)
	gsub(/5/,"6",s)
	gsub(/4/,"5",s)
	gsub(/3/,"4",s)
	gsub(/2/,"3",s)
	gsub(/1/,"2",s)
	gsub(/0/,"1",s)
	return s
}