/************************************************************************
*	設定情報の変更処理						*
*************************************************************************/
/*	ファイルからユーザー設定情報を読み込む	*/
%LOADset{
	var	newfile	[64];
	SNDMSG({erande_f.snd});
	footnote({ユーザー設定情報を読み込むファイルを指定して下さい});
	newfile:=@filesel({USR});
	case	(newfile<>{},
		{Yes},
		{
		%newdir	@getcdir;
		newfile:=@dir2(newdir)|newfile;
		case	(@filechk(newfile),
			{Yes},
			{
			%ExcPilot {#}|newfile;
			ExcPilot;
			init;
			SETFILE1:=@tail(newfile,{\});
			}
			);
		}
		);
	setcdir(CDIR);
	};

/*	ファイルからＮＩＦＴＹ設定情報を読み込む	*/
%LOADnif{
	var	newfile	[64];
	SNDMSG({erande_f.snd});
	footnote({ＮＩＦＴＹでの処理の設定を読み込むファイルを指定して下さい});
	newfile:=@filesel({NIF});
	case	(newfile<>{},
		{Yes},
		{
		%newdir	@getcdir;
		newfile:=@dir2(newdir)|newfile;
		case	(@filechk(newfile),
			{Yes},
			{
			%ExcPilot {#}|newfile;
			ExcPilot;
			setcdir(CDIR);
			SETFILE2:=@tail(newfile,{\});
			}
			);
		}
		);
	setcdir(CDIR);
	};

/*	ファイルからユーザー設定情報とＮＩＦＴＹ設定情報を読み込む	*/
%LOADall{
	var	newfile1[64];
	var	newfile2[64];
	SNDMSG({erande_f.snd});
	footnote({設定を読み込むファイル名を指定して下さい});
	newfile1:=@filesel({USR});
	case	(newfile1<>{},
		{Yes},
		{
		%newdir	@getcdir;
		newfile1:=@dir2(newdir)|newfile1;
		newfile2:=@body(newfile1,,{.})|{.NIF};
		case	(@filechk(newfile1) && @filechk(newfile2),
			{Yes},
			{
			%ExcPilot {#}|newfile1|{;#}|newfile2;
			ExcPilot;
			init;
			setcdir(CDIR);
			SETFILE1:=@tail(newfile1,{\});
			SETFILE2:=@tail(newfile2,{\});
			},
			{No},
			{
			SNDMSG({okasi_f.snd});
			display({ﾕｰｻﾞｰ設定ﾌｧｲﾙ(*.USR)とNIFTY設定ﾌｧｲﾙ(*.NIF)}|
				{の両方が同一ﾃﾞｨﾚｸﾄﾘに必要です\n});
			wait(2);
			}
			);
		}
		);
	setcdir(CDIR);
	};

/*	設定を元に戻す	*/
%CANCEL	{
	setcdir(CDIR);
	#FAPXSET.SET;
	#FAPXNIF.SET;
	init;
	setcdir(CDIR);
	SETFILE1:={標準設定};
	SETFILE2:={標準設定};
	};

%SETCHNG{
	loop	({
		SNDMSG({erande_f.snd});
		footnote({現在のﾕｰｻﾞｰ設定ﾌｧｲﾙ=}|SETFILE1|
				{  NIFTY設定ﾌｧｲﾙ=}|SETFILE2);
		select	({どの設定情報をファイルから読み込みますか？},
			Wtime4,{im({No})},
			{      ユーザー設定情報      },{LOADset;im({Yes})},
			{ ＮＩＦＴＹでの処理設定情報 },{LOADnif;im({Yes})},
			{         両方の設定         },{LOADall;im({Yes})},
			{    両方の設定を元に戻す    },{CANCEL;im({Yes})},
			{         終      了         },{im({No})}
			);
		});
	display({\n現在のﾕｰｻﾞｰ設定ﾌｧｲﾙ=}|SETFILE1|
		{  NIFTY設定ﾌｧｲﾙ=}|SETFILE2|{ \n});
	};

SETCHNG;