;	$VER: Install international 2.1 (8.5.92)

.BRA {
.KET }

Set Default "Work:term"

Lab Start

Echo "Please select the drawer to install the"
Echo "`term' main program in."
Echo "Drawer (<Return> = $Default) ? " NoLine

UnSet Drawer

Set >NIL: Drawer ?

If "$Drawer" EQ "*$Drawer"
	Set Drawer $Default
EndIf

Set StartPath $Drawer

FailAt 21

Assign >NIL: ${Drawer} Exists

If FAIL
	FailAt 10

	If NOT EXISTS $Drawer
		FailAt 21

		MakeDir "$Drawer"

		If FAIL
			Echo "*NCould not create drawer $Drawer!"

			FailAt 10

			Skip Back Start
		EndIf
	EndIf

	:C/UpdateIcon "$Drawer" Add

	Set Temp "$Drawer/"

	Set Drawer $Temp

	UnSet Temp
EndIf

Copy term(.info|%) "$Drawer" Quiet

:C/UpdateIcon ${Drawer}term Update

Echo "*NDo you wish to have the program documentation"
Echo "files installed" NoLine

Ask " (y / n)?"

If WARN
	Copy #?.doc#? ${Drawer} Quiet
	:C/UpdateIcon ${Drawer}#?.doc Update Replace :c/MuchMore DefaultTool MuchMore
	Copy :C/MuchMore ${Drawer}
EndIf

Echo "*NDo you wish to have the special fonts required"
Echo "by `term' installed" NoLine

Ask " (y / n)?"

If WARN
	Copy Fonts Fonts: All Quiet
EndIf

Echo "*NDo you wish to have the XPR-libraries required for"
Echo "data transfer installed" NoLine

Ask " (y / n)?"

If WARN
	Copy XPR_Libs/#?.library Libs: Quiet
EndIf

Echo "*NDo you wish to have the documentation files associated"
Echo "with the XPR-libraries installed" NoLine

Ask " (y / n)?"

If WARN
	Copy XPR_Libs/#?.do#? ${Drawer} Quiet
	:C/UpdateIcon ${Drawer}#?.do? Update Replace :c/MuchMore DefaultTool MuchMore
	Copy :C/MuchMore ${Drawer}
EndIf

Echo "*N`term' supports external terminal emulation"
Echo "libraries which can be used instead of the"
Echo "builtin terminal emulation routines. Although"
Echo "not necessarily required they are a useful"
Echo "enhancement. Do you wish to have the libraries"
Echo "installed" NoLine

Ask " (y / n)?"

If WARN
	Copy XEM_Libs/#?.library Libs: Quiet
	Copy XEM_Libs/Env Env: All Quiet
	Copy XEM_Libs/Env EnvArc: All Quiet
EndIf

Echo "*NIf installed, `term' will use a special library"
Echo "which helps to share the serial device driver"
Echo "between concurrent applications. Do you wish to"
Echo "have it installed" NoLine

Ask " (y / n)?"

If WARN
	Copy Extra_Libs/OwnDevUnit.library Libs:
EndIf

Echo "*NInstallation finished. `term' can now be found"
Echo "in the *"$StartPath*" drawer. Select the close"
Echo "gadget in the top left window corner to continue."
