.K ""

; Ishid-o-matic 1.0
; batchfile for installing game on disk and creating autobooting gamedisk
; written by R.B. at 16-Mar-92

failat 21

resident >NIL: sys:c/copy        ; make it faster (if it's in ROM, don't care)
resident >NIL: sys:c/echo
resident >NIL: sys:c/makedir
resident >NIL: sys:c/if

echo "*N[1mCreating bootable gamedisk for Ishid-o-matic:[0m*N"
echo "Please insert a disk in drive DF0: and press RETURN"
ask >NIL: ""
echo "This disk will be formated, all data will be lost"
ask  "Shall I continue, and format the disk ? (Y/N)"
if not warn
        echo "**** Installation canceled"
        skip end
endif
sys:system/format DRIVE df0: NAME Ishid-o-matic NOICONS
if warn
        echo "**** Format failed! - Installation canceled"
        echo "Make sure that a write-enabled disk is in drive DF0: and try again."
        skip end
endif

install df0:
if warn
        echo "**** Couldn't install bootblock! - Installation canceled"
        skip end
endif

echo "Now creating directories ..."

makedir Ishid-o-matic:l
makedir Ishid-o-matic:libs
makedir Ishid-o-matic:s
makedir Ishid-o-matic:c
makedir Ishid-o-matic:devs
makedir Ishid-o-matic:devs/keymaps
makedir Ishid-o-matic:fonts
makedir Ishid-o-matic:fonts/narrowpenguin

echo "Now copying required files to Ishid-o-matic: ..."

;--- first we copy some files from your workbench: ---

if exists libs:diskfont.library
        copy libs:diskfont.library to Ishid-o-matic:libs
else
        echo "**** diskfont.library not found! - Installation canceled"
        skip end
endif

if exists l:disk-validator
        copy l:disk-validator to Ishid-o-matic:l
endif

if exists c:loadwb
         copy sys:c/loadwb to Ishid-o-matic:c
endif

if exists c:endcli
        copy c:endcli to Ishid-o-matic:c
endif

if exists devs:keymaps/d
        copy devs:keymaps/d Ishid-o-matic:devs/keymaps
endif

if exists c:assign
        copy c:assign to Ishid-o-matic:c
endif

if exists devs:keymaps/usa1
        copy sys:devs/keymaps/usa1 Ishid-o-matic:devs/keymaps
endif
if exists sys:system/setmap
        copy sys:system/setmap Ishid-o-matic:c
endif

if exists libs:icon.libray
        copy libs:icon.library to Ishid-o-matic:libs
endif

if exists devs:system-configuration
        copy devs:system-configuration to Ishid-o-matic:devs
endif


;--- creating startup-sequence ---

copy :Ishid-o-matic/startup-sequence_A to Ishid-o-matic:s/startup-sequence
if exists Ishid-o-matic:devs/keymaps/d            ; install german keyboard
	if exists Ishid-o-matic:c/setmap
	        echo >>Ishid-o-matic:s/startup-sequence "setmap d"
	endif
endif
type >>Ishid-o-matic:s/startup-sequence :Ishid-o-matic/startup-sequence_B

;--- now we copy the files of the program ---

copy :c/muchmore to Ishid-o-matic:c
copy :Ishid-o-matic/Ishid-o-matic#? to Ishid-o-matic:
copy :Ishid-o-matic/Gfx to Ishid-o-matic:
copy :Ishid-o-matic/iom_highscores to Ishid-o-matic:
copy :Ishid-o-matic/iom_tournament to Ishid-o-matic:
copy :Ishid-o-matic/mod.praeludium to Ishid-o-matic:
copy :Ishid-o-matic/stoneclick.dump to Ishid-o-matic:
copy :Ishid-o-matic/iom.doc#? to Ishid-o-matic:
copy :Ishid-o-matic/iom.dok#? to Ishid-o-matic:
copy :Ishid-o-matic/medplayer.library to Ishid-o-matic:libs
copy :Ishid-o-matic/narrowpenguin.font Ishid-o-matic:fonts
copy :Ishid-o-matic/narrowpenguin/8 to Ishid-o-matic:fonts/narrowpenguin/8

echo "Installation complete."
echo "*N[1mPlease compare the contents of your game-disk to the file ref_dir,[0m"
echo "[1mand make sure, that all files are on your game-disk.[0m"
lab end
echo "*N*NClick close gadget to get rid of window"
endcli


