The following macro will convert a user-specified range into a 
comma delimited format for any DOS or Windows based version 
of 123.

The customer would then have to print the converted range to 
a text file via the /Print File command.
 

                A        B        C        D        E        F        
 1    \C     {INDICATE Specify the Range to Convert to Commma Delimited}
 2           /RNCinput~{?}~
 3           {INDICATE Please Wait Converting Data}
 4           {LET temp,0}{CALC}
 5           {GOTO}input~
 6           {WINDOWSOFF}{FRAMEOFF}
 7    \R     {FOR column,1,@ROWS(input),1,\E}
 8           {LET temp,temp+1}
 9           {IF temp<@COLS(input)}{UP}{END}{UP}{RIGHT}{BRANCH \I}
10           {BRANCH end}
11
12    \I     /WIC~,~/C~{LEFT}{END}{DOWN}{RIGHT}.{END}{UP}~
13           {LET temp,temp+1}
14           /WCS1~{RIGHT}{BRANCH \R}
15
16
17    \E     {IF @CELLPOINTER("TYPE")="V"}{BRANCH \D}
18           {IF @CELLPOINTER("type")="l"}{EDIT}"{HOME}{RIGHT}"~{BRANCH \D}
19           {IF @CELLPOINTER("type")="b"}'""~{BRANCH \D}
20           {EDIT}"{HOME}'"~
21    \D     {DOWN}
22
23
24    END    {GOTO}input~
25           {WINDOWSON}{FRAMEON}
26           {INDICATE}


Steps to recreate the macro:
1.  Type in the above macro
2.  Create the following range names:
     \C   A1..A1
     \R   A7..A7
     \I  A12..A12
     \E  A17..A17
     \D  A21..A21
    END  A24..A24
3.  Activate macro "\C" to start the macro to convert the 
    user-specified range into a comma delimited format.


A Breakdown of the Macro Subroutines:
  \C  Promts the user to input the range to be converted 
      and assigns this range to the range name called "INPUT".
  \R  A FOR loop designed to step down the column, cell by cell.
  \I  Inserts a column of commas between the users data columns.
  \E  Determines the type of the cell:
      If a Label:  the macro puts it in quotes
           Blank:            enters a apostrophe and then two 
                             empty quotation marks
           Number:           converts it to a left justified 
                             label (by entering an apostrophe) 
                             and then puts it in quotation marks
  \D  Move the cursor down to the next cell in the column.
 END  Goto INPUT and end the macro.
           


