; $VER: Install HPAsm 1.0 (02.04.94)
; Ernest TAGADA  1994

(welcome)
(complete 0)


; rpertoire destination

(set DIR
	(tackon
		(askdir
			(prompt "Select or create the drawer where the directory HPAsm "
			"will be created (will contain HP Assembler's distribution) :")
			(help @askdir-help)
			(default (if ((= (exists "hd1:" (noreq)) 2)) ("hd1:") ("sys:")))
			(disk)
		)
		"HPAsm"
	)
)
(if (= (exists DIR (noreq)) 2) 
	(message "Directory '" DIR "' already exists...")
	(makedir DIR)
	)
(set @default-dest DIR)
(complete 10)


; type d'icnes

(set RES
	(askchoice
		(prompt "What kind of icons do you want to be installed ?")
		(help @askchoice-help)
		(choices "For med-res workbench (ratio 1x2)" "For high-res workbench (ratio 1x1)")
		(default 0)
	)
)
(if (= RES 1) (
	(set HPICON "icons/hpasm_highres.info")
	(set DOCICON "icons/doc_highres.info")
	(set SRCICON "icons/source_highres.info")
	(set CODEICON "icons/code_highres.info")
	)
	(
	(set HPICON "icons/hpasm_medres.info")
	(set DOCICON "icons/doc_medres.info")
	(set SRCICON "icons/source_medres.info")
	(set CODEICON "icons/code_medres.info")
	)
)
(complete 20)


; copie fichiers

(copyfiles
	(source "HPAsm")
	(dest DIR)
)
(copyfiles
	(source HPICON)
	(dest DIR)
	(newname "HPAsm.info")
)
(tooltype (dest (tackon DIR "HPAsm")) (noposition))
(complete 30)
(copyfiles
	(source "HPAsm.doc")
	(dest DIR)
)
(copyfiles
	(source DOCICON)
	(dest DIR)
	(newname "HPAsm.doc.info")
)
(tooltype (dest (tackon DIR "HPAsm.doc")) (noposition))
(complete 40)
(copyfiles
	(source SRCICON)
	(dest "ENV:HPAsm")
	(newname "source.info")
)
(copyfiles
	(source CODEICON)
	(dest "ENV:HPAsm")
	(newname "code.info")
)
(complete 50)
(copyfiles
	(source SRCICON)
	(dest "ENVARC:HPAsm")
	(newname "source.info")
)
(copyfiles
	(source CODEICON)
	(dest "ENVARC:HPAsm")
	(newname "code.info")
)
(complete 60)


; installation des fontes

(set OKFONT
	(askbool
		(prompt "Two fonts are provided, in order to have an HP look (HPTopaz and More). Do you want to install these fonts (in FONTS:) ?")
		(help @askbool-help)
		(default 1)
	)
)
(if (= OKFONT 1)
	(copyfiles
		(source "fonts/")
		(dest "FONTS:")
		(all)
	)
)
(complete 80)


; installation des fichiers exemples

(set OKEXAM
	(askbool
		(prompt "Do you want example files (programs in HPSaturn assembler) ?")
		(help @askbool-help)
		(default 1)
	)
)
(if (= OKEXAM 1)
	(
		(copyfiles
			(source "examples/")
			(dest DIR)
			(all)
		)
		(foreach "examples/" "~(#?.info)"
			(
				(copyfiles
					(source SRCICON)
					(dest DIR)
					(newname (cat (fileonly @each-name) ".info"))
				)
				(tooltype
					(dest (tackon DIR (fileonly @each-name)))
					(noposition)
				)
			)
		)
	)
)
(complete 100)


; fin

(exit)
