%%HP: T(3)A(D)F(.);
@ TYKO by K. M. Sinenmaa
DIR
 MAIN
\<< RCLF 'FL' STO DEG
-42 SF MISC
  IF 1 ==
  THEN
[ .606434 .374897 .259091 .827362 .779072 .993126 .700695 .485541
.566441 .505498 .140023 .292498 .987353 .053856 .849694 .089608
.056531 .814794 .133295 .882987 .821218 .870169 .400589 .664614
.846912 .725368 .480856 .663854 .04102 .357355 ]
[ .03660110129 .03629164709 .0367481952 .03386319198 .00273790931
.0027377785 .011367714 .01136759566 .01136762384 .00445046867
.00445036173 .00445040017 .00145575328 .00145561327 .00145569465
.00023080893 .00023080893 .00023080893 .00009294371 .00009294371
.00009294371 .00003269438 .00003269438 .00003265562 .00001672092
.00001672092 .00001663715 .00001115482 .00001104864 .00001104864 ]
C * + OBJ\-> DROP {
F9 G9 L9 F8 G8 L8
F7 G7 L7 F6 G6 L6
F5 G5 L5 F4 G4 L4
F2 G2 L2 F1 G1 L1
GS LS D FM GM LM }
'BZ' STO 1 30
    FOR j FP 360 *
BZ j GET STO
    NEXT CALS OBJ\->
DROP EVAL 'r' STO
EVAL 3600 / LS +
F36 '\GlS' STO 1400
.12 BEEP 1000 .2
BEEP { { "Merc"
    \<< CAL1 OBJ\->
DROP EVAL 'R' STO
EVAL '\Gb' STO EVAL
3600 / L1 + '\Gl' STO
2439 -.4 87 G1 * 1
CONT
    \>> } { "Venu"
    \<< CAL2 OBJ\->
DROP EVAL 'R' STO
EVAL '\Gb' STO EVAL
3600 / L2 + '\Gl' STO
6050 -4 224 G2 * 2
CONT
    \>> } { "Mars"
    \<< CAL4 OBJ\->
DROP EVAL 'R' STO
EVAL '\Gb' STO EVAL
3600 / L4 + '\Gl' STO
3397 -1.2 686 G4 *
3 CONT
    \>> } { "Jupit"
    \<< CAL5 OBJ\->
DROP EVAL 'R' STO
EVAL '\Gb' STO EVAL
3600 / L5 + '\Gl' STO
71398 -9.4 4360 G5
* 4 CONT
    \>> } { "Satur"
    \<< CAL6 OBJ\->
DROP EVAL 'R' STO
EVAL '\Gb' STO EVAL
3600 / L6 + '\Gl' STO
60000 -9.4 10740 G6
* 5 CONT
    \>> } { "Uran"
    \<< CAL7 OBJ\->
DROP EVAL 'R' STO
EVAL '\Gb' STO EVAL
3600 / L7 + '\Gl' STO
26320 -7.15 30690
G7 * 6 CONT
    \>> } { "Neptu"
    \<< CAL8 OBJ\->
DROP EVAL 'R' STO
EVAL '\Gb' STO EVAL
3600 / L8 + '\Gl' STO
24300 -6.83 60181
G8 * 7 CONT
    \>> } { "Pluto"
    \<< CAL9 OBJ\->
DROP EVAL 'R' STO
EVAL '\Gb' STO EVAL
3600 / L9 + '\Gl' STO
1500 -1 90480 G9 *
8 CONT
    \>> } { "Moon"
    \<< CALM OBJ\->
DROP EVAL SIN INV
DUP 'R' STO '\GD' STO
EVAL 3600 / DUP '\Gb'
STO 'b' STO EVAL
3600 / LM + F36 DUP
'\Gl' STO 'l' STO
1738 27 GM * 9 CONT
    \>> } { "Sun"
    \<< r DUP 'R' STO
'\GD' STO \GlS DUP '\Gl'
STO 'l' STO 0 '\Gb'
STO 0 'b' STO
696000 10 CONT
    \>> } } TMENU
"   Select  Object"
PROMPT 'n' STO
CLLCD
"WAIT ..again" 1
DISP
    IF n 10 <
    THEN LIST OBJ\->
7 DROPN SWAP 10000
* + 1000000 / +
SWAP 360 / NEG
DATE+ '\Gt' STO
    END
    IF n 9 <
    THEN \Gb 3600 /
'\Gb' STO \Gl F36 '\Gl'
STO GEOC 5 R \GD * 1
l \Gl - COS + .5 * \v/
/ LOG * + 'm' STO
    END
    IF n 9 ==
    THEN 2 * \GD 6378
* / R\->D \->HMS
    ELSE 2 * \GD
149597870 * / R\->D
\->HMS
    END 10000 *
    IF n 8 >
    THEN .6 *
    END 'Q' STO
  ELSE 1 'n' STO {
{ "STARS"
    \<< NEWS
    \>> } { "" } {
"ESC"
    \<< CONT
    \>> } } TMENU
"Browsing ..."
PROMPT 1.396971 t *
.0003086 t 2 ^ * +
.013056 t *
.0000092 t 2 ^ * -
5.12362 .241614 t *
.0001122 t 2 ^ * +
+ DATA n GET OBJ\->
DROP 'm' STO 'R'
STO OVER 4 PICK +
SIN 5 PICK * OVER +
DUP '\Gb' STO 'b' STO
TAN OVER 4 ROLL +
COS * ROT * NEG ROT
+ + DUP '\Gl' STO 'l'
STO n 10 + 'n' STO
  END CONV AAUT { Y
M LT \GlM \O/ TZ C T t
\Ge LM GM FM D \GWM LS
GS L1 G1 F1 L2 G2 F2
L4 G4 F4 L5 G5 F5
L6 G6 F6 L7 G7 F7
L8 G8 F8 L9 G9 F9 T
BZ \GlS h l b } PURGE
ERASE NM n GET 2
\->GROB PICT STO PICT
RCL { # 0d # 58d }
LIST K ZZ 6 FIX {
# 60d # 8d }
"GST 0UT= " UT \->HMS
ZZ { # 60d # 15d }
"LST= " ST \->HMS ZZ
{ # 0d # 10d }
"\Gl= " \Gl \->HMS ZZ {
# 0d # 16d } "\Gb= "
\Gb \->HMS ZZ { # 0d
# 24d } "r= " R ZZ
{ # 0d # 30d }
"\GD= " \GD ZZ { # 0d
# 38d } "\Gd= " \Gd
\->HMS ZZ { # 0d
# 44d } "\Ga= " \Ga 15
/ \->HMS ZZ { # 60d
# 23d } "AZ= " A
\->HMS ZZ { # 60d
# 29d } "a = " a
\->HMS ZZ { # 0d
# 51d } "\Gt= " \Gt ZZ
{ # 60d # 44d }
"LT\|^= " RI ZZ {
# 60d # 51d }
"LT\|v= " SE ZZ 2 FIX
{ # 57d # 37d }
"D= " Q ZZ { # 98d
# 37d } "m= " m ZZ
{ # 68d # 1d }
"JDAY= " JD ZZ PICT
STO 400 .2 BEEP 800
.2 BEEP 1600 .3
BEEP PICT RCL \->LCD
{ } PVIEW FL STOF {
n \GD \Gd \Ga \Gl \Gb r R FL
A a ST \Gt m Q UT JD
RI SE } PURGE 2
MENU
\>>
MISC
\<< POP STD { {
"DATE"
  \<<
"DATE-format DD.MMYYYY"
":DATE:" INPUT OBJ\->
DUP IP SWAP FP 100
* DUP IP SWAP FP
10000 * LIST { 1 3
} ROT PUT { 1 2 }
ROT PUT { 1 1 } ROT
PUT 'LIST' STO NEW
  \>> } { "TIME"
  \<<
"TIME-format HH.MMSS"
":TIME:"
INPUT OBJ\-> LIST { 3
1 } ROT PUT 'LIST'
STO NEW
  \>> } { "LONG"
  \<<
"Longitude in decimals"
"
west=neg
" +
":\Gl:" INPUT OBJ\->
LIST { 2 1 } ROT
PUT 'LIST' STO NEW
  \>> } { "LATIT"
  \<<
"Latitude in decimals"
":\O/:" INPUT OBJ\->
LIST { 2 2 } ROT
PUT 'LIST' STO NEW
  \>> } { "ZONE"
  \<<
"Integer -12 to 12"
":Time Zone:" INPUT
OBJ\-> LIST { 2 3 }
ROT PUT 'LIST' STO
NEW
  \>> } { "ESC"
  \<< { { "SUN.S"
    \<< 1 CONT
    \>> } { "" } {
"STARS"
    \<< 2 CONT
    \>> } } TMENU
  \>> } } TMENU NEW
HALT CLLCD
"WAIT ..." 1 DISP
LIST OBJ\-> 3 DROPN
'LT' STO 'TZ' STO
'\O/' STO '\GlM' STO
'Y' STO 'M' STO 367
Y * 7 Y M 9 + 12 /
IP + * 4 / IP - 3 Y
M 9 - 7 / IP + 100
/ IP 1 + * 4 / IP -
275 M * 9 / IP +
1721028.5 + + DUP
LT TZ - F24 HMS\-> 24
/ + 'JD' STO
2451545 - 36525 /
8640184.81287 *
24110.54841 + JD
2451545 - DUP 'C'
STO 36525 / 't' STO
.093104 t 2 ^ * +
.0000062 t 3 ^ * -
3600 / F24 DUP 'UT'
STO 1.00273790935
LT TZ - F24 HMS\-> *
+ \GlM 15 / + F24
'ST' STO t 1 + 'T'
STO .347343 C
.00014709391 * -
'\GWM' STO 84428 47 T
* - 9 \GWM COS * +
3600 / '\Ge' STO
\>>
CALM
\<< POP { '22640*SIN(
GM)-4586*SIN(GM-2*D
)+2370*SIN(2*D)+769
*SIN(2*GM)-668*SIN(
GS)-412*SIN(2*FM)-
212*SIN(2*GM-2*D)-
206*SIN(GM-2*D+GS)+
192*SIN(GM+2*D)+165
*SIN(2*D-GS)+148*
SIN(GM-GS)-125*SIN(
D)-110*SIN(G2+GS)-
55*SIN(2*FM-2*D)-45
*SIN(GM+2*FM)+40*
SIN(GM-2*FM)-38*SIN
(GM-4*D)+36*SIN(3*
GM)-31*SIN(2*GM-4*D
)+28*SIN(GM-2*D-GS)
-24*SIN(2*D+GS)+19*
SIN(GM-D)+18*SIN(D+
GS)+15*SIN(GM+2*D-
GS)+14*SIN(2*GM+2*D
)+14*SIN(4*D)-13*
SIN(3*GM-2*D)-11*
SIN(GM+16*LS-18*L2)
+10*SIN(2*GM-GS)+9*
SIN(GM-2*FM-2*D)+9*
COS(GM+16*LS-18*L2)
-9*SIN(2*GM-2*D+GS)
-8*SIN(GM+D)+8*SIN(
2*D-2*GS)-8*SIN(2*
GM+GS)-7*SIN(2*GS)-
7*SIN(GM-2*D+2*GS)+
7*SIN(\GWM)-6*SIN(GM-
2*FM+2*D)-6*SIN(2*
FM+2*D)-4*SIN(GM-4*
D+GS)+4*T*COS(GM+16
*LS-18*L2)-4*SIN(2*
GM+2*FM)+4*T*SIN(GM
+16*LS-18*L2)+3*SIN
(GM-3*D)-3*SIN(GM+2
*D+GS)-3*SIN(2*GM-4
*D+GS)+3*SIN(GM-2*
GS)+3*SIN(GM-2*D-2*
GS)-2*SIN(2*GM-2*D-
GS)-2*SIN(2*FM-2*D+
GS)+2*SIN(GM+4*D)+2
*SIN(4*GM)+2*SIN(4*
D-GS)+2*SIN(2*GM-D)
' '18461*SIN(FM)+
1010*SIN(GM+FM)+
1000*SIN(GM-FM)-624
*SIN(FM-2*D)-199*
SIN(GM-FM-2*D)-167*
SIN(GM+FM-2*D)+117*
SIN(FM+2*D)+62*SIN(
2*GM+FM)+33*SIN(GM-
FM+2*D)+32*SIN(2*GM
-FM)-30*SIN(FM-2*D+
GS)-16*SIN(2*GM+FM-
2*D)+15*SIN(GM+FM+2
*D)+12*SIN(FM-2*D-
GS)-9*SIN(GM-FM-2*D
+GS)-8*SIN(FM+\GWM)+8
*SIN(FM+2*D-GS)-7*
SIN(GM+FM-2*D+GS)+7
*SIN(GM+FM-GS)-7*
SIN(GM+FM-4*D)-6*
SIN(FM+GS)-6*SIN(3*
FM)+6*SIN(GM-FM-GS)
-5*SIN(FM+D)-5*SIN(
GM+FM+GS)-5*SIN(GM-
FM+GS)+5*SIN(FM-GS)
+5*SIN(FM-D)+4*SIN(
3*GM+FM)-4*SIN(FM-4
*D)-3*SIN(GM-FM-4*D
)+3*SIN(GM-3*FM)-2*
SIN(2*GM-FM-4*D)-2*
SIN(3*FM-2*D)+2*SIN
(2*GM-FM+2*D)+2*SIN
(GM-FM+2*D-GS)+2*
SIN(2*GM-FM-2*D)+2*
SIN(3*GM-FM)' '
.9508+.0518*COS(
134.9+447198.85*T)+
.0095*COS(259.2-
413335.38*T)+.0078*
COS(235.7+890534.23
*T)+.0028*COS(269.9
+954397.7*T)' }
\>>
CAL1
\<< POP { '84378*SIN(
G1)+10733*SIN(2*G1)
+1892*SIN(3*G1)-646
*SIN(2*F1)+381*SIN(
4*G1)-306*SIN(G1-2*
F1)-274*SIN(G1+2*F1
)-92*SIN(2*G1+2*F1)
+83*SIN(5*G1)-28*
SIN(3*G1+2*F1)+25*
SIN(2*G1-2*F1)+19*
SIN(6*G1)-9*SIN(4*
G1+2*F1)+8*T*SIN(G1
)+7*COS(2*G1-5*G2)' 
'24134*SIN(F1)+5180
*SIN(G1-F1)+4910*
SIN(G1+F1)+1124*SIN
(2*G1+F1)+271*SIN(3
*G1+F1)+132*SIN(2*
G1-F1)+67*SIN(4*G1+
F1)+18*SIN(3*G1-F1)
+17*SIN(5*G1+F1)-10
*SIN(3*F1)-9*SIN(G1
-3*F1)' '.39528-
.07834*COS(G1)-
.00795*COS(2*G1)-
.00121*COS(3*G1)-
.00022*COS(4*G1)' }
\>>
CAL2
\<< POP { '2814*SIN(
G2)-181*SIN(2*F2)-
20*T*SIN(G2)+12*SIN
(2*G2)-10*COS(2*GS-
2*G2)+7*COS(3*GS-3*
G2)' '12215*SIN(F2)
+83*SIN(G2+F2)+83*
SIN(G2-F2)' '.72335
-.00493*COS(G2)' }
\>>
CAL4
\<< POP { '38451*SIN(
G4)+2238*SIN(2*G4)+
181*SIN(3*G4)-52*
SIN(2*F4)+37*T*SIN(
G4)-22*COS(G4-2*G5)
-19*SIN(G4-G5)+17*
COS(G4-G5)+17*SIN(4
*G4)-16*COS(2*G4-2*
G5)+13*COS(GS-2*G4)
-10*SIN(G4-2*F4)-10
*SIN(G4+2*F4)+7*COS
(GS-G4)-7*COS(2*GS-
3*G4)-5*SIN(G2-3*G4
)-5*SIN(GS-G4)-5*
SIN(GS-2*G4)-4*COS(
2*GS-4*G4)+4*T*SIN(
2*G4)+4*COS(G5)+3*
COS(G2-3*G4)+3*SIN(
2*G4-2*G5)' '6603*
SIN(F4)+622*SIN(G4-
F4)+615*SIN(G4+F4)+
64*SIN(2*G4+F4)' '
1.53031-.1417*COS(
G4)-.0066*COS(2*G4)
-.00047*COS(3*G4)'
}
\>>
CAL5
\<< POP { '19934*SIN(
G5)+5023*T+2511+
1093*COS(2*G5-5*G6)
+601*SIN(2*G5)-479*
SIN(2*G5-5*G6)-185*
SIN(2*G5-2*G6)+137*
SIN(3*G5-5*G6)-131*
SIN(G5-2*G6)+79*COS
(G5-G6)-76*COS(2*G5
-2*G6)-74*T*COS(G5)
+68*T*SIN(G5)+66*
COS(2*G5-3*G6)+63*
COS(3*G5-5*G6)+53*
COS(G5-5*G6)+49*SIN
(2*G5-3*G6)-43*T*
SIN(2*G5-5*G6)-37*
COS(G5)+25*SIN(2*L5
)+25*SIN(3*G5)-23*
SIN(G5-5*G6)-19*T*
COS(2*G5-5*G6)+17*
COS(2*G5-4*G6)+17*
COS(3*G5-3*G6)-14*
SIN(G5-G6)-13*SIN(3
*G5-4*G6)-9*COS(2*
L5)+9*COS(G6)-9*SIN
(G6)-9*SIN(3*G5-2*
G6)+9*SIN(4*G5-5*G6
)+9*SIN(2*G5-6*G6+3
*G7)-8*COS(4*G5-10*
G6)+7*COS(3*G5-4*G6
)-7*COS(G5-3*G6)-7*
SIN(4*G5-10*G6)-7*
SIN(G5-3*G6)+6*COS(
4*G5-5*G6)-6*SIN(3*
G5-3*G6)+5*COS(2*G6
)-4*SIN(4*G5-4*G6)-
4*COS(3*G6)+4*COS(2
*G5-G6)-4*COS(3*G5-
2*G6)-4*T*COS(2*G5)
+3*T*SIN(2*G5)+3*
COS(5*G6)+3*COS(5*
G5-10*G6)+3*SIN(2*
G6)-2*SIN(2*L5-G5)+
2*SIN(2*L5+G5)-2*T*
SIN(3*G5-5*G6)-2*T*
SIN(G5-5*G6)' '
-4692*COS(G5)+259*
SIN(G5)+227-227*COS
(2*G5)+30*T*SIN(G5)
+21*T*COS(G5)+16*
SIN(3*G5-5*G6)-13*
SIN(G5-5*G6)-12*COS
(3*G5)+12*SIN(2*G5)
+7*COS(3*G5-5*G6)-5
*COS(G5-5*G6)' '
5.20883-.25122*COS(
G5)-.00604*COS(2*G5
)+.0026*COS(2*G5-2*
G6)-.0017*COS(3*G5-
5*G6)-.00106*SIN(2*
G5-2*G6)-.00091*T*
SIN(G5)-.00084*T*
COS(G5)+.00069*SIN(
2*G5-3*G6)-.00067*
SIN(G5-5*G6)+.00066
*SIN(3*G5-5*G6)+
.00063*SIN(G5-G6)-
.00051*COS(2*G5-3*
G6)-.00046*SIN(G5)-
.00029*COS(G5-5*G6)
+.00027*COS(G5-2*G6
)-.00022*COS(3*G5)-
.00021*SIN(2*G5-5*
G6)' }
\>>
CAL6
\<< POP { '23045*SIN(
G6)+5014*T-2689*COS
(2*G5-5*G6)+2507+
1177*SIN(2*G5-5*G6)
-826*COS(2*G5-4*G6)
+802*SIN(2*G6)+425*
SIN(G5-2*G6)-229*T*
COS(G6)-153*COS(2*
G5-6*G6)-142*T*SIN(
G6)-114*COS(G6)+101
*T*SIN(2*G5-5*G6)-
70*COS(2*L6)+67*SIN
(2*L6)+66*SIN(2*G5-
6*G6)+60*T*COS(2*G5
-5*G6)+41*SIN(G5-3*
G6)+39*SIN(3*G6)+31
*SIN(G5-G6)+31*SIN(
2*G5-2*G6)-29*COS(2
*G5-3*G6)-28*SIN(2*
G5-6*G6+3*G7)+28*
COS(G5-3*G6)+22*T*
SIN(2*G5-4*G6)-22*
SIN(G6-3*G7)+20*SIN
(2*G5-3*G6)+20*COS(
4*G5-10*G6)+19*COS(
2*G6-3*G7)+19*SIN(4
*G5-10*G6)-17*T*COS
(2*G6)-16*COS(G6-3*
G7)-12*SIN(2*G5-4*
G6)+12*COS(G5)-12*
SIN(2*G6-2*G7)-11*T
*SIN(2*G6)-11*COS(2
*G5-7*G6)+10*SIN(2*
G6-3*G7)+10*COS(2*
G5-2*G6)+9*SIN(4*G5
-9*G6)-8*SIN(G6-2*
G7)-8*COS(2*L6+G6)+
8*COS(2*L6-G6)+8*
COS(G6-G7)-8*SIN(2*
L6-G6)+7*SIN(2*L6+
G6)-7*COS(G5-2*G6)-
7*COS(2*G6)-6*T*SIN
(4*G5-10*G6)+6*T*
COS(4*G5-10*G6)+6*T
*SIN(2*G5-6*G7)-5*
SIN(3*G5-7*G6)-5*
COS(3*G5-3*G6)-5*
COS(2*G6-2*G7)+5*
SIN(3*G5-4*G6)+5*
SIN(2*G5-7*G6)+4*
SIN(3*G5-3*G6)+4*
SIN(3*G5-5*G6)+4*T*
COS(G5-2*G6)+3*T*
COS(2*G5-4*G6)+3*
COS(2*G5-6*G6+3*G7)
-3*T*SIN(2*L6)+3*T*
COS(2*G5-6*G6)-3*T*
COS(2*L6)+3*COS(3*
G5-7*G6)+3*COS(4*G5
-9*G6)+3*SIN(3*G5-6
*G6)+3*SIN(2*G5-G6)
+3*SIN(G5-4*G6)+2*
COS(3*G6-3*G7)+2*T*
SIN(G5-2*G6)+2*SIN(
4*G6)-2*COS(3*G5-4*
G6)-2*COS(2*G5-G6)-
2*SIN(2*G5-7*G6)+2*
COS(G5-4*G6)+2*COS(
4*G5-11*G6)-2*SIN(
G6-G7)' '8297*SIN(
G6)-3346*COS(G6)+
462*SIN(2*G6)-189*
COS(2*G6)+185+79*T*
COS(G6)-71*COS(2*G5
-4*G6)+46*SIN(2*G5-
6*G6)-45*COS(2*G5-6
*G6)+29*SIN(3*G6)-
20*COS(2*G5-3*G6)+
18*T*SIN(G6)-14*COS
(2*G5-5*G6)-11*COS(
3*G6)-10*T+9*SIN(G5
-3*G6)+8*SIN(G5-G6)
-6*SIN(2*G5-3*G6)+5
*SIN(2*G5-7*G6)-5*
COS(2*G5-7*G6)+4*
SIN(2*G5-5*G6)-4*T*
SIN(2*G6)-3*COS(G5-
G6)+3*COS(G5-3*G6)+
3*T*SIN(2*G5-4*G6)+
3*SIN(G5-2*G6)+2*
SIN(4*G6)-2*COS(2*
G5-2*G6)' '9.55774-
.53252*COS(G6)-
.01878*SIN(2*G5-4*
G6)-.01482*COS(2*G6
)+.00817*SIN(G5-G6)
-.00539*COS(G5-2*G6
)-.00524*T*SIN(G6)+
.00349*SIN(2*G5-5*
G6)+.00347*SIN(2*G5
-6*G6)+.00328*T*COS
(G6)-.00225*SIN(G6)
+.00149*COS(2*G5-6*
G6)-.00126*COS(2*G5
-2*G6)+.00104*COS(
G5-G6)+.00101*COS(2
*G5-5*G6)+.00098*
COS(G5-3*G6)-.00073
*COS(2*G5-3*G6)-
.00062*COS(3*G6)+
.00042*SIN(2*G6-3*
G7)+.00041*SIN(2*G5
-2*G6)-.0004*SIN(G5
-3*G6)+.0004*COS(2*
G5-4*G6)-.00028*T-
.00023*SIN(G5)+
.0002*SIN(2*G5-7*G6
)' }
\>>
CAL7
\<< POP { '19397*SIN(
G7)+570*SIN(2*G7)-
536*T*COS(G7)+143*
SIN(G6-2*G7)+110*T*
SIN(G7)+102*SIN(G6-
3*G7)+76*COS(G6-3*
G7)-49*SIN(G5-G7)+
64*T-30*T*COS(2*G7)
+29*SIN(2*G5-6*G6+3
*G7)+29*COS(2*G7-2*
G8)-28*COS(G7-G8)+
23*SIN(3*G7)-21*COS
(G5-G7)+20*SIN(G7-
G8)+20*COS(G6-2*G7)
-19*COS(G6-G7)+17*
SIN(2*G7-3*G8)+14*
SIN(3*G7-3*G8)+13*
SIN(G6-G7)-24*T*COS
(G7)-12*COS(G7)+10*
SIN(2*G7-2*G8)-9*
SIN(2*F7)-18*SIN(G7
)+9*COS(2*G7-3*G8)+
8*T*COS(G6-2*G7)+7*
T*COS(G6-3*G7)-7*T*
SIN(G6-3*G7)+7*T*
SIN(2*G7)+6*SIN(2*
G5-6*G6+2*G7)+6*COS
(2*G5-6*G6+2*G7)+5*
SIN(G6-4*G7)-4*SIN(
3*G7-4*G8)+4*COS(3*
G7-3*G8)-3*COS(G8)-
2*SIN(G8)' '2775*
SIN(F7)+131*SIN(G7-
F7)+130*SIN(G7+F7)' 
'19.21216-.90154*
COS(G7)-.02488*T*
SIN(G7)-.02121*COS(
2*G7)-.00585*COS(G6
-2*G7)-.00508*T*COS
(G7)-.00451*COS(G5-
G7)+.00336*SIN(G6-
G7)+.00198*SIN(G5-
G7)+.00118*COS(G6-3
*G7)+.00107*SIN(G6-
2*G7)-.00103*T*SIN(
2*G7)-.00081*COS(3*
G7-3*G8)' }
\>>
CAL8
\<< POP { '3523*SIN(
G8)-50*SIN(2*F8)-43
*T*COS(G8)+29*SIN(
G5-G8)+19*SIN(2*G8)
-18*COS(G5-G8)+13*
COS(G6-G8)+13*SIN(
G6-G8)-9*SIN(2*G7-3
*G8)+9*COS(2*G7-2*
G8)-5*COS(2*G7-3*G8
)-4*T*SIN(G8)+4*COS
(G7-2*G8)+8*T*SIN(
G8)' '6404*SIN(F8)+
55*SIN(G8+F8)+55*
SIN(G8-F8)-33*T*SIN
(F8)' '30.07175-
.25701*COS(G8)-
.00787*COS(2*L7-G7-
2*L8)+.00409*COS(G5
-G8)-.00314*T*SIN(
G8)+.0025*SIN(G5-G8
)-.00194*SIN(G6-G8)
+.00185*COS(G6-G8)'
}
\>>
CAL9
\<< POP { '101577*SIN
(G9)+15517*SIN(2*G9
)-3593*SIN(2*F9)+
3414*SIN(3*G9)-2201
*SIN(G9-2*F9)-1871*
SIN(G9+2*F9)+839*
SIN(4*G9)-757*SIN(2
*G9+2*F9)-285*SIN(3
*G9+2*F9)+454*T*SIN
(G9)+218*SIN(2*G9-2
*F9)+200*T*SIN(G9)' 
'57726*SIN(F9)+
15257*SIN(G9-F9)+
14102*SIN(G9+F9)+
3870*SIN(2*G9+F9)+
1138*SIN(3*G9+F9)+
472*SIN(2*G9-F9)+
353*SIN(4*G9+F9)-
144*SIN(G9-3*F9)-
119*SIN(3*F9)-111*
SIN(G9+3*F9)' '
40.74638-9.58235*
COS(G9)-1.16703*COS
(2*G9)-.22649*COS(3
*G9)-.04996*COS(4*
G9)' }
\>>
CALS
\<< POP { '6910*SIN(
GS)+72*SIN(2*GS)-17
*T*SIN(GS)-7*COS(GS
-G5)+6*SIN(LM-LS)+5
*SIN(4*GS-8*G4+3*G5
)-5*COS(2*GS-2*G2)-
4*SIN(GS-G2)+4*COS(
4*GS-8*G4+3*G5)+3*
SIN(2*GS-2*G2)-3*
SIN(G5)-3*SIN(2*GS-
2*G5)' '1.00014-
.01675*COS(GS)-
.00014*COS(2*GS)' }
\>>
AAUT
\<< POP -16 CF ST 15
* \Ga - 'h' STO h COS
\Gd COS \O/ COS * * \Gd
SIN \O/ SIN * + ASIN
'a' STO h COS \Gd COS
\O/ SIN * * \Gd SIN \O/
COS * - h SIN \Gd COS
* \->V2 -16 SF V\-> F36
'A' STO DROP \Gd TAN
\O/ TAN * DUP
  IF ABS 1 >
  THEN DROP
    IF a 0 >
    THEN
"Continuous"
    ELSE "    No"
    END
"phenomenon"
  ELSE NEG ACOS \Ga
OVER - 15 / UT -
SWAP \Ga + 15 / UT -
    IF n 9 \=/
    THEN \Gd ABS
      IF \O/ 0 >
      THEN \O/ + 9.4
/ SIN DUP ROT + ROT
ROT -
      ELSE \O/ NEG +
9.3 / SIN DUP ROT +
ROT ROT -
      END
    ELSE \Gd \O/ ABS +
SIN 2 / DUP ROT +
ROT ROT +
    END TZ 15 * \GlM
- 15 / DUP ROT +
F24 \->HMS SWAP ROT +
F24 \->HMS
  END 'SE' STO 'RI'
STO
\>>
CONV
\<< POP -16 CF l COS
l SIN \Ge COS * b TAN
\Ge SIN * - \->V2 -16
SF V\-> F36 '\Ga' STO
DROP b SIN \Ge COS *
b COS \Ge SIN l SIN *
* + ASIN '\Gd' STO
\>>
DATA
{ { 69.78901342
-5.46743986 21 .85
} { 301.75502956
29.30364784 5.1 .77
} { 249.7616937
-4.56997796 130 .96
} { 204.2332694
30.7362084 11 -.04
} { 88.838405
-16.0275303 200 .01
} { 81.85774154
22.86434254 14 .08
} { 335.3285854
59.90627092 560
1.25 } {
115.78545193
-16.019622324 3.5
.38 } {
149.82870578
.46469195 26 1.35 }
{ 76.82923859
-31.12276919 280
.12 } { 104.081575
-39.6052516 2.7
-1.46 } }
GEOC
\<< POP -16 CF R 2 ^
r 2 ^ + 2 R r \GlS \Gl
- 180 + COS * * * -
\v/ '\GD' STO R \Gb SIN *
\GD / ASIN 'b' STO \Gb
COS \Gl COS R * * r
\GlS COS * + R \Gb COS
\Gl SIN * * r \GlS SIN
* + \->V2 -16 SF V\->
F36 'l' STO DROP
\>>
NEW
\<<
"      Changeable
"
"
" + LIST \->STR +
"
" +
"
    ESC to continue
"
+ CLLCD 1 DISP 3
FREEZE
\>>
NEWS
\<< " Number ?"
":No:" INPUT OBJ\->
'n' STO
  IF n 11 >
  THEN CLLCD
"Not computationable"
1 DISP 3 FREEZE
  ELSE CLLCD NM n
10 + GET 1 DISP 3
FREEZE
  END
\>>
NM
{ "Mercury" "Venus"
"Mars" "Jupiter"
"Saturn" "Uranus"
"Neptune" "Pluto"
"Moon" "Sun"
"Aldebaran"
"Altair" "Antares"
"Arcturus"
"Betelgeuse"
"Capella" "Deneb"
"Procyon" "Regulus"
"Rigel" "Sirius" }
LIST
[[ 10 12 1991 ]
 [ 24.954 60.162 2 ]
 [ 2 0 0 ]]
POP
\<<
  IF 'FL' VTYPE 0 <
  THEN
"Something lost ?"
DOERR
  END
\>>
ZZ
\<< \->STR + 1 \->GROB
GOR
\>>
F36
\<< DUP 360 / IP
360 * -
  IF DUP 0 <
  THEN 360 +
  END
\>>
F24
\<< DUP 24 / IP 24 *
-
  IF DUP 0 <
  THEN 24 +
  END
\>>
