%%HP: T(3);
@ BIO, a biorythm calculator, by Joe Horn.
@ 243 bytes, CRC = #795Ch.
@ The output from this program is guaranteed to be far more
@ accurate than your body's own chaotic cycles, and is thus
@ more useful for recreational purposes than anything practical.
DIR
  BIO @ birthdate -> biorythms
    \<< DUP "BD" \->TAG               @ Birthdate
SWAP DATE DDAYS                       @ Days old
DUP 23 BRY "Physical" \->TAG          @ Physical 23-day cycle
OVER 28 BRY "Emotional" \->TAG        @ Emotional 28-day cycle
ROT 33 BRY "Intellectual" \->TAG      @ Intellectual 33-day cycle
    \>>
  NXT @ -> tomorrow's biorythm
    \<< DROP2 DROP -1 DATE+ BIO       @ one more day old
    \>>
  BRY @ ddays & cycle length -> biorythm
    \<< / FP 0 ACOS 4 * * SIN         @ works in any angle mode
100 * 0 RND                           @ scale between -100 & +100
    \>>
END
