%%HP: T(3)A(D)F(.);
@ TRAIN, by Jeremy Smith
\<< # BFh # 40h BLANK { # 3Ch # 0h } LCD\-> REPL
    PICT STO { # 3Ch # 0h } PVIEW DEPTH 190 \-> depth x
  \<<
    WHILE x
    REPEAT PICT x R\->B # 7h 2 \->LIST
    @ ensure the next GROB line hex numbers are on one line with no spaces!
    GROB 60 7 00E3000000000000E163000000000000CC6100CFFF8FFF30CFF5F7CA
              AA8AAA20EFF7F7DFFBAFFF20FFFFFFFFFFFFFF70CCC1630303060C00
    REPL
      IF RAND 9 * 5 - R\->B B\->R
      THEN
        IF DEPTH depth - DUP
        THEN RAND * ROLL PIXOFF
        ELSE DROP
        END
      END 'x' DECR DROP
      IF 1 FS?C
      THEN x 4 + R\->B # 7h 2 \->LIST PIXON
        x 6 + R\->B # 5h 2 \->LIST DUP PIXON
        x 7 + R\->B # 5h 2 \->LIST DUP PIXON
      END
      IF RAND 10 * 9.45 - R\->B B\->R
      THEN 2112 DUP .28 BEEP .2 WAIT .4 BEEP
      END
      IF RAND 9 * 7.7 - R\->B B\->R
      THEN 1 SF x 4 + R\->B # 7h 2 \->LIST PIXON 
        x 4 + R\->B # 6h 2 \->LIST DUP PIXON
        x 5 + R\->B # 6h 2 \->LIST DUP PIXON
      END
    END DEPTH depth - DROPN 1 CF
  \>>
\>>
