%%HP: T(3)A(D)F(.); 
  @ PARAL - Large Version L. Hoppis 3/14/91 DONE Rev 1.4
  @ 1842 Bytes #6E15h
DIR
  RPAR
    \<< DUP NXT \->BIN 0 RND DUP
      RCLF -49 CF -50 CF -40 CF
      PICT PURGE { #0d #0d } { #122d #63d } BOX
      PICT { #124d #4d } LOGO REPL PICT RCL 0 0 0
      \-> r x i f b t y z
      \<< { # 0d # 0d } PVIEW
        DO i \->VAL -3 RND DUP r OVER * SWAP r - / ABS \->BIN 0 RND
           \->VAL -3 RND
           IF DUP2 >
            THEN DROP2 PICT "- END OF LIST -" 1 \->GROB
              # 30d y # 7d * # 2d + 2 \->LIST SWAP GOR 9 'y'STO
            ELSE DUP2 \->PAR r %CH
            IF ABS DUP ACCU <
              THEN 2 RND DUP
              IF NOT
                THEN " " SWAP +
                ELSE \->STR
                IF DUP SIZE 3 <
                  THEN 0 +
                  END
                END " % - " + ROT DSP " || " +
                ROT DSP + + PICT SWAP 1 \->GROB # 13d y # 7d
                * # 2d + 2 \->LIST SWAP GOR 'y' INCR DROP
              ELSE 3 DROPN
              END 'i' INCR DROP 'z'INCR DROP
            END
          IF y 8 >
            THEN TONE 0 WAIT
              0 'y' STO
              IF DUP
                85.1 ==
                THEN
                  IF i t z + - DUP x \>=
                    THEN 'i' STO
                    ELSE DROP
                    END
                ELSE z 't' STO
                END
              PICT { # 0d # 0d } b REPL 0 'z' STO
            ELSE 0
            END
        UNTIL 55.1 ==
        END  f STOF r
      \>>
    \>>

  NXT
    \<< DUP \->BIN CEIL DUP \->VAL -3 RND ROT
        IF SAME
           THEN 1 + \->VAL -3 RND
           ELSE \->VAL -3 RND
           END
    \>>

  PRV
    \<< DUP \->BIN FLOOR DUP \->VAL -3 RND ROT
        IF SAME
           THEN 1 - \->VAL -3 RND
           ELSE \->VAL -3 RND
           END
    \>>

  \->PAR
    \<< DUP2 * ROT ROT + / \>>

  DSP
    \<< DUP MANT SWAP XPON
        CASE
          DUP 6 \>=
            THEN 6 - "M\GW"
            END
          DUP 3 \>=
            THEN 3 - "k\GW"
            END " \GW"
          END SWAP ALOG ROT * \->STR
        CASE
          DUP SIZE 2 <
            THEN ".00" +
            END
          DUP SIZE 3 <
            THEN ".0" +
            END
          DUP SIZE 4 <
            THEN
              IF DUP "." POS
                THEN "0" +
                END
            END
          END SWAP +
    \>>

  ACCU
    .2


  \->BIN
    \<< .976300098965 / LN 2.39852613838E-2 / \>>


  \->VAL
    \<< 2.39852613838E-2 * EXP .976300098965 * \>>

  LOGO
    GROB 7 49
    C140C140C10040404040C10040404040400042C2C3434200C140C140C100
    40404040C10000000000E314955454549514E3

  PPAR
    { (-6.5,-3.1) (6.5,3.2) X 0 (0,0) FUNCTION Y }

  TONE
    \<< 5000 .02 BEEP 3000 .01 BEEP\>>
END
