%%HP: T(3)A(R)F(.);
@ by Craig Finseth
DIR
  MPHASE
    \<< RCLF -31 SF DEG ERASE { # 0h # 0h } PVIEW { # 40h # 1Ch } # 1Ah
        0 360 ARC 26 28 MFRAC MPLOT FLIP 7 FREEZE STOF
    \>>
  MTIME
    \<< MFRAC \-> X
      \<<
        CASE X .25 <
          THEN "NM+"
          END X .5 <
          THEN "FQ+"
          END X .75 <
          THEN "FM+"
          END "LQ+"
        END X
      \>> .25 MOD 42532 * SWAP OVER 1440 / IP \->STR + "d " + SWAP 1440
          MOD SWAP OVER 60 / IP \->STR + "h " + SWAP 60 MOD SWAP
          OVER IP \->STR + "m " + SWAP FP 60 * IP \->STR + "s" +
    \>>
  MFRAC
    \<< 1.121975 DATE DDAYS TIME 4.21 HMS- HMS\-> 24 / + 1440 * 42532 / FP
    \>>
  FLIP
    \<< PICT PICT RCL NEG { # 0h # 0h } SWAP REPL
    \>>
  MPLOT
    \<< \-> RA MI F
      \<<
        IF F .5 <
        THEN F 360 * COS RA * RA
        ELSE RA NEG F .5 - 360 * COS RA *
        END \-> L R
        \<< 1 0
          FOR x x ACOS SIN DUP MI x RA * + L R MLINE MI x RA * - L R MLINE
            RA INV NEG
          STEP
        \>>
      \>>
    \>>
  MLINE
    \<< \-> SC LI L R
      \<< SC L * 64 + R\->B LI R\->B 2 \->LIST SC R * 64 + R\->B LI
          R\->B 2 \->LIST LINE
      \>>
    \>>
  PPAR { (-6.5,-3.1) (6.5,3.2) X 0 (0,0) FUNCTION Y }
END
