%%HP: T(3)A(D)F(.);
@ BOOTMESS
@ by Kevin Jessup
DIR

  GREET
    \<< "GOOD " { "MORNING" "AFTERNOON" "EVENING" } TIME DUP
      IF 12 <
      THEN DROP 1
      ELSE
        IF 18 <
        THEN 2
        ELSE 3
        END
      END GET +
    \>>

  BOOTTIME { # 1D41D7D4EC60Eh "12/25/90 03:21" }

  PRESERVE
    \<< RCLF \-> f
      \<< EVAL f STOF
      \>>
    \>>

  SIGNOFF
    \<< CLLCD OFF UPTIME
    \>>

  SYSUP
    \<< TICKS DATE TIME TSTR 5 18 SUB 2 \->LIST 'BOOTTIME' STO
    \>>

  UPTIME
    \<< CLLCD 2 FREEZE
      \<< GREET 4 DISP BOOTTIME OBJ\-> DROP "Booted: " SWAP + 5 DISP TICKS
       SWAP - B\->R 29491200 / DUP 24 / IP 0 FIX \->STR SWAP 24 MOD \->HMS
       4 FIX \->STR + "Online: " SWAP + 6 DISP "kBytes: " MEM 1024 / 1 FIX
       \->STR + 7 DISP
      \>> PRESERVE
    \>>
END
