;$VER: QCInstall v1.2 (16.5.93)
;By Bo Lincoln, Calle Englund 1993
;This script uses the installer program to install Quadra Composer to
;your hard drive.

(complete 0)
(welcome)

;Check kickver
(if (< (/ (getversion) 65536) 37)
	(abort ("You must have kickstart 2.0x to use this installation "
		"utility...")
	)
)

(message
	("\nThis program lets you install Quadra Composer to your hard ")
	("disk drive. If you dont own one, abort installation immediately. ")
)

(set sdir (pathonly @icon))
;Get dir for drawer
(set tdir (askdir (prompt ("Where do you want to install Quadra Composer?"))
		(help ("Select a drive where you want to install the ")
		("Quadra Composer. A drawer called Quadra Composer ")
		("will be made...\n")
		)
		(default ("dh0:"))
	)
)
;Make Quadra Composer dir
(makedir (tackon tdir "QuadraComposer"))
(run (cat "copy /QuadraComposer.info " tdir))
(working ("Copying Quadra Composer"))
;Copy main program
(copyfiles
	(source (tackon sdir "QuadraComposer"))
	(dest (tackon tdir "QuadraComposer/"))
	(infos)
)
;50%
(complete 50)
(message
	"\nNow, the manual will be installed. Is is just a simple ASCII "
	"text file, which can be read in e.g 'muchmore'."
)
(set md (askdir
		(prompt "Where do you want to place the manual?")
		(help @askdir-help)
		(default (tackon tdir "QuadraComposer/"))
	)
)
;Copy the manual
(copyfiles
	(source (tackon sdir "QCManual.txt"))
	(dest md)
	(infos)
)
(complete 75)
(message
	"\nIf you're a programmer, it can be a good idea to install the "
	"replay routines. They are assembler sources which play your music."
)
;Copy replay...
(copyfiles
	(prompt "Select replay routines to copy:")
	(source sdir)
	(dest (tackon tdir "QuadraComposer/"))
	(help @copyfiles-help)
	(choices
		"QCReplay.s"
		"QCFastreplay.s"
	)
	(confirm)
)
(complete 95)
(message
	"\nThis is the last part of this installation. 'reqtools.library' will"
	" be copied to your libs: drawer, if you don't "
	"already have a later version installed."
)
(copylib
	(prompt "Copying reqtools...")
	(help @copylib-help)
	(source (":libs/reqtools.library"))
	(dest "libs:")
	(confirm)
)
(complete 100)
(set @default-dest (tackon tdir "QuadraComposer/"))
(exit ("Have fun!"))
