%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%                                                             %
%                      PAUSEN                                 %
%                                                             %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%




%%%%%%%%%
%% "dp" %
%%%%%%%%%

beginchar(58,1/2nhw#, 3nhh#, 0);
         clear;
         penpos1(nhh,90);
         penpos2(nhh,90);
         y1r = y2r = h;
         x1r =  0; x2r = w;
         currentpen:= pencircle;
         penstroke z1e--z2e;
labels(1,2);
endchar;

%%%%%%%%%%
%% "ddp" %
%%%%%%%%%%

beginchar(59,1/2nhw#, 3nhh#, 0);
         clear;
         penpos1(2nhh,90);
         penpos2(2nhh,90);
         y1r = y2r = h;
         x1r =  0; x2r = w;
         currentpen:= pencircle;
         penstroke z1e--z2e;
labels(1,2);
endchar;

%%%%%%%%%%%%%%%%%%
%% "ganze Pause" %
%%%%%%%%%%%%%%%%%%

beginchar(60, nhw#, 3nhh#, 0);
         clear;
         penpos1(nhh/2,90);
         penpos2(nhh/2,90);
         y1r = y2r = h;
         x1r =  0; x2r = w;
         currentpen:= pencircle;
         penstroke z1e--z2e;
endchar;
%charwd:=4.5; chardx:=charwd*pt; chardp:=0; charht:=4;

%%%%%%%%%%%%%%%%%%
%% "halbe Pause" %
%%%%%%%%%%%%%%%%%%

beginchar(61, nhw#, 2.5nhh#, 0);
         clear;
         penpos1(nhh/2,90);
         penpos2(nhh/2,90);
         y1r = y2r = h;
         x1r =  0; x2r = w;
         currentpen:= pencircle;
         penstroke z1e--z2e;
endchar;

%%%%%%%%%%%%%%%%%%%%
%% "viertel Pause" %
%%%%%%%%%%%%%%%%%%%%

beginchar(62, nhw#, 4nhh#, 0);                               % .1
         clear;                                            %         .2
         thin := 5 thinwidth; thick := 1/2 nhh;            %    8..3
         alpha_a = -50; alpha_b = -50;                     %   .4
         penpos1 (  thin,   (alpha_a+90));                 %        .5
         penpos5 (  thin,   (alpha_b));                    %   .6
         penpos2 ( thick,    alpha_a   );                  %
         penpos4 ( thick,    alpha_b   );                  %        .7
         penpos3 ( thick, 1/2(alpha_a+alpha_b));
         x3r:=9/10[x3,x3r];
         penpos8 ( thick, 1/2(alpha_a+alpha_b));
         x8l:=9/10[x8,x8l];
         penpos6 ( 1/2thick, (alpha_b+10));
         penpos7 ( 1/4thick,-20);
         y1l = h - 2s;
         x1l =  2s;
         z2r =  z1 +(nhh* right) rotated alpha_a;
         z5 =  z4l+(nhh* right) rotated alpha_b;
         z3  = 1/3[z2,z4];
         z8  = 2/3[z2,z4];
%        z3  = 1/2[z2r,z4];
         z4  = (w,h) scaled .5;
         y6r = 1.5nhh;
         x6l = x4l;
         x7 = w/2; y7r= nhh;
         currentpen:= pencircle scaled thin;
         draw z1--z2r; draw z5--z4l;
         penstroke z2e..z3e..z8e..z4e;
         penstroke z5e{nw}..z6e{z7-z6}..z7e;
endchar;
%%title "viertelpause";                                    %
%beginchar(62, nhw#, 4nhh#, 0);                               % .1
%         clear;                                            %         .2
%         thin := 5 thinwidth; thick := 1/2 nhh;            %    8..3
%         alpha_a = -50; alpha_b = -50;                     %   .4
%%         penpos4(thick,-45);
%         z1 = (s,h-s);
%         z3 = (w,nhh);
%         z2-z3=(h/2-s)*up;
%         z1-z6=(h/2-2s)*up;
%         z4r = 1/3z1;
%         z4l = (w/2,nhh);% z2 = (w-s,h-nhh-s);
% %        1[z2,z4r]=1/3(w,h);
%         z5 = 1/2(w,nhh);
%         currentpen:= pencircle scaled thin;%4
%         draw z1--z2; draw z6--z3;
%         filldraw z1--z2..control1/3[-z2,z4r]
%         %-(w/2,h/2))}
%         ..z3--z6..control1/4[-z6,z2]
%         %(w/2,h-nhh))}
%         ..z1--cycle;
%         filldraw z3...z4r...z5--z5..z4l..z3..cycle;
%penlabels(1,2,3,4,5,6);
%endchar;
%end;

%%%%%%%%%%%%%%%%%%%
%% "achtel Pause" %
%%%%%%%%%%%%%%%%%%%

beginchar(63, 2nhh#, 3nhh#, 0)
clear;
          %punkte f"ur achtelpause, 16. und 32. Pause
          x1=y1= nhh; x2=x6=7/4nhh; y2=11/4nhh;
          x3=x4=x5=1/2nhh; y3=10/4nhh;
          y4=3nhh; y5=0; y6=15/4nhh;
          currentpen := pencircle scaled 2thinwidth;
          draw z1..z2;
          currentpen := pensquare rotated45 scaled(sqrt2*thinwidth);
          draw z2..z3{up+left};
          fill z3..z4..z3..cycle;
endchar;

%%%%%%%%%%%%%%%%%%%%%%%%
%% "sechzehntel Pause" %
%%%%%%%%%%%%%%%%%%%%%%%%

beginchar(64,2nhh#, 3nhh#, 0)
          clear;
          %punkte f"ur achtelpause, 16. und 32. Pause
          x1=y1= nhh; x2=x6=7/4nhh; y2=11/4nhh;
          x3=x4=x5=1/2nhh; y3=10/4nhh;
          y4=3nhh; y5=0; y6=15/4nhh;
          currentpen := pencircle scaled 2thinwidth;
          draw z5..z2;
          currentpen := pensquare rotated45 scaled(sqrt2*thinwidth);
          draw z2..z3{up+left};
          draw z2..z3{up+left} shifted(-1/2nhh,-nhh);
          fill z3..z4..z3..cycle;
          fill z3..z4..z3..cycle shifted (-1/2nhh,-nhh);
endchar;

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% "zweiunddreissigstel Pause" %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

beginchar(65,2nhh#, 4nhh#, 0)
          clear;
          %punkte f"ur achtelpause, 16. und 32. Pause
          x1=y1= nhh; x2=x6=7/4nhh;
          y2=11/4nhh; x3=x4=x5=1/2nhh; y3=10/4nhh;
          y4=3nhh; y5=0; y6=15/4nhh;
          currentpen := pencircle scaled 2thinwidth;
          draw z5..z6;
          currentpen := pensquare rotated45 scaled(sqrt2*thinwidth);
          draw z2..z3{up+left} shifted(      0,nhh);
          draw z2..z3{up+left} shifted(-1/4nhh,  0);
          draw z2..z3{up+left} shifted(-2/3nhh,-nhh);
          fill z3..z4..z3..cycle shifted (      0, nhh);
          fill z3..z4..z3..cycle shifted (-1/4nhh,   0);
          fill z3..z4..z3..cycle shifted (-2/3nhh,-nhh);
endchar;