|********************************************************************
|**** *schnelle* ausgabe von zeichen im hintergrund  *****
|********************************************************************

	.globl _prn_byte
	.globl _anzahl
	.globl _ptr
	.globl _exstall
	.globl _old_vec
	.globl _shm_name


	.text
| **** programm durch signal gekillt!
_exstall:
	tstl _ptr
	ble no_print
	pea ex_print
	movew #38,a7@-
	trap #14
	addql #6,a7
	pea _shm_name 	| tempor„re datei wird z.zt. nicht gel”scht!
	movew #0x41,a7@-
	trap #1
	addql #6,a7
	pea killed
	movew #0x9,a7@-
	trap #1
	addql #6,a7
	clrw a7@-
	trap #1
	rts

ex_print:
	clrl _anzahl
	bclr #0,0xfa09:w		 | ausschalten
	bclr #0,0xfa15:w | maskieren
	movel _old_vec,0x100:w
	clrl _old_vec
	rts


| Idee aus ST-Computer 5/92, stark modifizert
_prn_byte:
	movel sp@(8),_anzahl | Anzahl Bytes
	ble no_print
	movel sp@(4),_ptr

	pea i_byte
	movew #38,a7@-
	trap #14
	addql #6,a7
no_print:
	rts

| Interruptroutine in MFP-Busy-Interrupt
i_byte: movel _ptr,a0
	moveb #14,0xffff8800:w | strobe aus
	moveb 0xffff8800:w,d0
	bset #5,d0
	moveb d0,0xffff8802:w
	movel 0x100:w,_old_vec
	movel #p_byte,0x100
	bclr #0,0xfa03:w
	bset #0,0xfa09:w | anschalten
	bset #0,0xfa15:w | demaskieren
	moveb #0xfe,0xfa11:w
	bsr out
	rts

	.ascii "XBRA"
	.ascii "DVIR"
_old_vec:  .long 0x00000000

p_byte: oriw #0x0700,sr
	subql #1,_anzahl
	ble ende
o_byte: moveml d0/a0,a7@-
	movel _ptr,a0
	bsr out
	moveml a7@+,d0/a0
	moveb #0xfe,0xfa11:w
	rte


ende: movel _old_vec,0x100:w
	bclr #0,0xfa09:w | ausschalten
	bclr #0,0xfa15:w | maskieren
	clrl _old_vec
	rte


out:	moveb #15,0xffff8800:w
	moveb a0@+,0xffff8802:w
	movel a0,_ptr

	movew wait1,d0 | damit das Timing der Norm entspricht, bzw
time1:	nop
	dbra d0,time1

	moveb #14,0xffff8800:w
	moveb 0xffff8800:w,d0
	bclr #5,d0
	moveb d0,0xffff8802:w
	bset #5,d0
	movew d0,a0

	movew wait2,d0 | ver„ndert werden kann
time2:	nop
	dbra d0,time2

	movew a0,d0
	moveb d0,0xffff8802:w
	rts

	.data
	.ascii "PATCH:"
wait1:	.word 0x0002
wait2:	.word 0x0020
killed: .byte 0x1b,0x48,0x20,7,0

	.data
	.comm _anzahl,4
	.comm _ptr,4