#!/bin/csh -f

# @(#)Collect mail in SOUP file with uqwk. V. 2.0 Sep 1994 josdb@xs4all.nl (Jos den Bekker)
# Thanks to H.Shrikumar shri@cs.umass.edu for the mail-lock function

set workdir=/tmp/uqwk.$$
set polldir=~/poll
set date=`date +%d%m`
set nonomatch

if ( -d $workdir ) then
  echo ""
  echo "          Error! Working-directory $workdir already exists."
  echo ""
  exit 1
else
  mkdir $workdir
  if ( $status != 0 ) then
    echo ""
    echo "          Error! Unable to create working-directory $workdir"
    echo ""
    exit 1
  else
    cd $workdir
  endif
endif

( echo 's1-$' $workdir/qwk$$ ; echo q ) | /usr/ucb/mail >/dev/null

if ( $status != 0 ) then
  echo ""
  echo "           WARNING! An error occurred while"
  echo "           locking your mail file."
  echo "           Mail cannot be collected"
  echo ""
  cd
  rm -rf $workdir
  exit 1
endif

uqwk +L -H$workdir -f$workdir/qwk$$ -B0 >/dev/null

if ( $status != 0 ) then
  echo ""
  echo "           WARNING! An error occurred while collecting mail."
  echo "           Mail box is moved to $workdir/qwk$$"
  echo ""
  exit 1
endif

zip -mbqj /tmp mail$date AREAS *.MSG

if ( $status != 0 ) then
  echo ""
  echo "          An error occured while zipping your files."
  echo "          Mail-output of uqwk in $workdir"
  echo ""
  exit 1
endif

if ( -e $polldir/mail*.zip.* ) rm $polldir/mail*.zip.*

if ( -e $polldir/mail$date.zip ) mv $polldir/mail$date.zip $polldir/mail$date.zip.$$

mv mail$date.zip $polldir

if ( $status != 0 ) then
  echo ""
  echo "        File mail$date.zip could not be moved to $polldir"
  echo "        File is in $workdir"
  echo ""
  exit 1
endif  

cd
rm -rf $workdir
