/*
** PhotoCD
**
** $VER: ADPro PhotoCD Loader 1.0 (6.6.96)
** Loader for Photo-CD-Pictures in ADPro together with PCD2IFF24.
** Copyright  1996 Allenbrand Brice
** Based on PHCD V2.1  1994-1995 Erik Simonson
** 
*/

OPTIONS RESULTS
SIGNAL ON BREAK_C
SIGNAL ON BREAK_D
SIGNAL ON HALT
SIGNAL ON SYNTAX

ConvProg      = "c:PCD2IFF24"
PhotoPath     = "tmp:"
TempFile      = "TMP:TempFile"

ADPro         = '"ADPro PhotoCD-Loader"'
NL            = '0a'x

ADDRESS "ADPro"
DISPLAYMESSAGE ADPro

FileReq   = '"Select PCD File to Load"'
FileMess  = '"No picture selected, do you want to quit?"'
FileChoi  = "Select|Yes"
ResReq    = '"In which resolution do you want\nto have the converted picture ?"'
ResRequ   = '"Do you which to do something more ?"'
ConvMess  = '"Converting picture..."'

CALL FilePath("File",FileReq,PhotoPath,,FileMess,FileChoi)
PhotoFile = String

OKAYN ADPro ResReq "3072x2048|1536x1024|768x512|384x256|192x128|Cancel"
SELECT
  WHEN RC = 1 THEN ConvArgs = 'Size 5'
  WHEN RC = 2 THEN ConvArgs = 'Size 4'
  WHEN RC = 3 THEN ConvArgs = 'Size 3'
  WHEN RC = 4 THEN ConvArgs = 'Size 2'
  WHEN RC = 5 THEN ConvArgs = 'Size 1'
  WHEN RC = 0 THEN CALL Quit
END

OKAYN ADPro ResRequ "None|Black&White|ColorEnhancer|Cancel"
SELECT
  WHEN RC = 3 THEN ConvArgs2 = 'BW'
  WHEN RC = 2 THEN ConvArgs2 = 'OVSKP'
  WHEN RC = 1 THEN ConvArgs2 = ' '
  WHEN RC = 0 THEN CALL Quit
END

DISPLAYMESSAGE ConvMess
ADDRESS COMMAND ConvProg ">NIL:" ConvArgs ConvArgs2 PhotoFile TempFile

ADDRESS "ADPro"
DISPLAYMESSAGE ADPro
LOADER "IFF" TempFile
CALL Quit


FilePath:
  PARSE ARG Type,Title,DefaultDir,DefaultFile,Mess,Choices
  ADDRESS "ADPro"
  Resultat = 1
  DO WHILE Resultat ~= 0
    IF Type = "File" THEN DO
      GETFILE Title DefaultDir DefaultFile
      Resultat = RC
      IF Resultat ~= 0  THEN DO
          OKAYN ADPro Mess Choices
          IF RC = 0 THEN CALL Quit
      END
      String = ADPRO_RESULT
    END
    ELSE
    IF Type = "Dir" THEN DO
      GETDIR Title DefaultDir
      Resultat = RC
      IF Resultat ~= 0 THEN DO
        OKAYN ADPro Mess Choices
        IF RC = 0 THEN CALL Quit
      END
      String = ADPRO_RESULT
    END
  END
RETURN String


Quit:
  PARSE ARG String
  ADDRESS "ADPro"
  IF String ~= "" THEN OKAY1 String
  DISPLAYMESSAGE
  ADDRESS COMMAND "Delete >NIL:" TempFile
  EXIT 0
