;======================================================================
;
; Adom Install Script $VER: Install 1.0 (26.1.97)
;
; Copyright  1997 Jochen Terstiege
;
;======================================================================

(set #hello "\nWelcome to the Adom Installation\n\n\Version 0.94 Gamma 4b")
(set #select_destination "Where should i create the Adom directory?")
(set #destination_help (cat "Choose a destination partition or directory. "
									"A directory called 'Adom' will be created there."))
(set #install_to1 "\nInstall Adom to \"")
(set #install_to2 "\" ?")
(set #have_fun "Have fun with Adom...")

;======================================================================
; variables
;======================================================================

(set adom_source (pathonly @icon))	; from where we were started
(set adom_drawer "Adom")				; destination drawer name
(set adom_dest	"Work:")					; default destination

;======================================================================
; welcome
;======================================================================

(message #hello)

;======================================================================
; select destination
;======================================================================

(set adom_dest
	(askdir
		(prompt #select_destination)
		(default "Work:")
		(help #destination_help)
	)
)
(set adom_dest (tackon adom_dest adom_drawer))
(set @default-dest adom_dest)

;======================================================================
; make directory
;======================================================================

(if (not (exists adom_dest))
	(
		(message (cat #install_to1 adom_dest #install_to2))
		(makedir adom_dest (infos))
	)
)

;======================================================================
; copy files
;======================================================================

(complete 0)

(copyfiles (source (tackon adom_source "Adom")) (dest adom_dest) (all))

(complete 100)

(exit #have_fun)
