;$VER: Oscar Install 1.2 (13.01.96)
;
;Install-Script & HD-Loader
;1996 Thomas Kessler (kessler@fen.baynet.de)
;All rights reserved.
;
;Feel free to contact me via email if you have any questions
;or if you want to use parts of this installer-script.
;
;Oscar 1993-96 Flair Software(tm)
;All rights reserved.

(set #patch-version "1.2")
(set old-level @user-level)

; --- english by Thomas Kessler ---
(set #msg_welcome (cat
	"\n\nOscar HD-Installer "#patch-version"\n\n"
	"for the Oscar AGA disk-version\n"
	"1993-97 Flair Software\nAll rights reserved.\n\n"
	"Install-Script & HD-Loader\n1996-97 Thomas Kessler\nAll rights reserved."))
(set #msg_choosedir (cat
	"Choose a destination-directory on your harddisk.\n"
	"A new drawer for Oscar will be created there."))
(set #msg_space1 "\nApproximately 2010K of harddisk space\nis needed on your volume ")
(set #msg_space2 "\n\nFree space: ")
(set #msg_space3 "\n\nDelete or transfer some files and try again.")
(set #msg_askdisk1 "\nPlease insert the disk \"")
(set #msg_askdisk2 "\"!")
(set #msg_reading1 "Reading files from \"")
(set #msg_reading2 "\" ...")
(set #msg_reading " ")
(set #msg_exit1 (cat
	"\nNote: OscarHD needs about 1.8M continous memory\n"
	"and does not return to Workbench.\n\n"))
(set #msg_exit2 (cat
	"Note: Oscar was designed for a 'normal' A1200,\n"
	"but it should also work on an A4000/030 (or\n"
	"better) with the new HD-loader.\n"))
(set #na "\n Sorry, no help available.")

; --- deutsch by Thomas Kessler ---
(if (= @language "deutsch")
(
(set #msg_welcome (cat
	"\n\nOscar HD-Installation "#patch-version"\n\n"
	"fr die Oscar AGA Disketten-Version\n"
	"1993-97 Flair Software\nAlle Rechte vorbehalten.\n\n"
	"Installations-Skript & HD-Ladeprogramm\n1996-97 Thomas Kessler\nAlle Rechte vorbehalten."))
(set #msg_choosedir (cat
	"Whlen Sie ein Verzeichnis auf der Festplatte aus.\n"
	"Dort wird eine neue Schublade fr Oscar angelegt."))
(set #msg_space1 "\nEtwa 2010K Speicherplatz wird auf\nder Festplatte ")
(set #msg_space2 " bentigt.\n\nFreier Platz: ")
(set #msg_space3 "\n\nLschen oder verschieben Sie einige Dateien\nund versuchen Sie es dann erneut.")
(set #msg_askdisk1 "\nBitte legen Sie die Diskette \"")
(set #msg_askdisk2 "\" ein!")
(set #msg_reading1 "Lese Dateien von \"")
(set #msg_reading2 "\" ...")
(set #msg_reading " ")
(set #msg_exit1 (cat
	"\nWichtig: OscarHD braucht etwa 1.8M fortlaufenden\n"
	"Speicher und kommt nicht auf die Workbench zurck.\n\n"))
(set #msg_exit2 (cat
	"Wichtig: Oscar wurde fr einen 'normalen' A1200\n"
	"entwickelt, aber mit dem neuen HD-Ladeprogramm\n"
	"sollte es auch auf einem A4000/030 (oder besser)\n"
	"laufen.\n"))
(set #na "\n Sorry, keine Hilfe verfuegbar.")
))

; --- franais ---
;(if (= @language "franais")
;(
;
;))
; ------------------

; --- italiano by Luca Longone ---
(if (= @language "italiano")
(
(set #msg_welcome (cat
   "\n\nOscar HD-Installer "#patch-version"\n\n"
   "per Oscar AGA in versione dischetto\n"
   "1993-97 Flair Software\nTutti i diritti riservati.\n\n"
   "Script di installazione & caricamento da HD\n1996-97 Thomas Kessler\nTutti i diritti riservati."))
(set #msg_choosedir (cat
   "Scegli un cassetto di destinazione sul tuo harddisk.\n"
   "Un nuovo cassetto per Oscar sar creato l."))
(set #msg_space1 "\nSono necessari approssimativamente\n2010K di spazio sul tuo harddisk ")
(set #msg_space2 "\n\nSpazio libero: ")
(set #msg_space3 "\n\nCancella o sposta alcuni file e riprova.")
(set #msg_askdisk1 "\nPrego inserisci il disco \"")
(set #msg_askdisk2 "\"!")
(set #msg_reading1 "Sto leggendo i file da \"")
(set #msg_reading2 "\" ...")
(set #msg_reading " ")
(set #msg_exit1 (cat
   "\nNota: OscarHD ha bisogno di circa 1.8M di memoria\ncontinua "
   "e non ritorna al Workbench.\n\n"))
(set #msg_exit2 (cat
   "Nota: Oscar  realizzato per un 'normale' A1200,\n"
   "ma dovrebbe funzionare anche su un A4000/030\n"
   "(o superiore) con il nuovo caricamento da HD.\n"))
(set #na "\n Spiacente, aiuto non disponibile.")
))

; ------------------

(complete 0)
(user 2)

(message #msg_welcome)
(complete 1)

(set #oscardir
	(askdir (prompt #msg_choosedir) (help @askdir-help) (default "Work:")))
(set @default-dest (tackon #oscardir "OscarHD"))
(complete 7)

(if (<> (getdevice #oscardir) "RAM")
	(if (< (getdiskspace #oscardir) 2010000)
		(abort (cat #msg_space1 (getdevice #oscardir)":" #msg_space2 (/ (getdiskspace #oscardir) 1024)"K" #msg_space3))
	)
)
(complete 9)

(makedir (tackon #oscardir "OscarHD") (prompt "Creating dir") (help @makedir-help) (infos) (safe))
(complete 10)

(askdisk (dest "Oscar1") (prompt (cat #msg_askdisk1 "Oscar1" #msg_askdisk2)) (help @askdisk-help))
(working (cat #msg_reading1 "Oscar1" #msg_reading2))
(copyfiles
	(prompt "Copy files")
	(help #na)
	(source "Oscar1:10")
	(dest (tackon #oscardir "OscarHD"))
   (newname "main")
   (optional force) (safe) (nogauge) 
)
(complete 15)
(copyfiles
	(prompt "Copy files")
	(help #na)
	(source "Oscar1:")
	(choices "01" "02" "03" "04" "05" "06" "07" "08" "09" "0A" "0B" "0C" "0D" "0E" "0F")
	(dest (tackon #oscardir "OscarHD"))
   (optional force) (safe) (nogauge) 
)
(complete 40)
(askdisk (dest "Oscar2") (prompt (cat #msg_askdisk1 "Oscar2" #msg_askdisk2)) (help @askdisk-help))
(working (cat #msg_reading1 "Oscar2" #msg_reading2))
(copyfiles
	(prompt "Copy files")
	(help #na)
	(source "Oscar2:")
	(choices "10" "11" "12" "13" "14" "15" "16" "17" "18" "19" "1A" "1B" "1C" "1D" "1E" "1F" "20" "21" "22" "23" "24" "25" "26" "27" "28" "29")
	(dest (tackon #oscardir "OscarHD"))
   (optional force) (safe) (nogauge) 
)
(complete 65)
(askdisk (dest "Oscar3") (prompt (cat #msg_askdisk1 "Oscar3" #msg_askdisk2)) (help @askdisk-help))
(working (cat #msg_reading1 "Oscar3" #msg_reading2))
(copyfiles
	(prompt "Copy files")
	(help #na)
	(source "Oscar3:")
	(choices "2A" "2B" "2C" "2D" "2E" "2F" "30" "31" "32" "33" "34" "35" "36" "37" "38" "39" "3A" "3B" "3C" "3d")
	(dest (tackon #oscardir "OscarHD"))
   (optional force) (safe) (nogauge) 
)
(complete 90)
(working #msg_reading)
(copyfiles
	(prompt "Copy files")
	(help #na)
	(source "Data/OscarHD")
	(dest (tackon #oscardir "OscarHD"))
	(infos)
	(optional force) (safe) (nogauge)
)
(complete 95)
(working #msg_reading)
(copyfiles
	(prompt "Copy files")
	(help #na)
	(source "Data/OscarHD_drawer.info")
	(dest #oscardir)
	(newname "OscarHD.info")
   (optional force) (safe) (nogauge)
)
(complete 100)

(exit (cat #msg_exit1 (if (<> (database "cpu") "68020") #msg_exit2)))
(user old-level)
(welcome "")
