G4C - NetView

;by Kevin Anderson  andersok@mail.bogo.co.uk  {using Gui4Cli by D.Keletsekis}

WinBig 0 20 250 200 'NetView'
WinType 11110001
WinFont times.font 13 000

xOnLoad
UpDate NetView 1 $SfileVar
GuiOpen NetView
Extract NetView GUIPATH PathVar
Assign NetBar: $PathVar  

xIcon 4 3 :icons/open
ReqFile -1 -1 250 200 'Choose a file' LOAD SfileVar 'Sys:'
   UpDate NetView 1 $SfileVar

xIcon 28 3 :icons/new
GuiLoad :Pakit
GuiOpen Pakit

xIcon 221 3 :icons/help
CLI 'c:amigaguide NetBar:NetBar.guide'

BOX 0 0 250 26 IN RIDGE
BOX 0 28 250 105 IN RIDGE
BOX 0 133 250 26 IN RIDGE

xButton 4 30 120 20 '.arj file'
IfExists FILE c:unarj
  CD $.A.NetBar
       CLI 'unarj e $SfileVar'
Else
  EZreq 'Cannot find C:unarj see docs' OK NoFind
EndIf

xButton 4 50 120 20 'mime / base64'
IfExists FILE c:base64decode
  CLI 'c:Base64Decode $SfileVar autoname $.A.NetBar'
Else
  EZreq 'Cannot find C:Base64Decode see docs' OK NoFind
EndIf

xButton  4 70 120 20 '.tar.gz /.tgz /.gzip'
IfExists FILE c:untgz
  CLI 'c:untgz $SfileVar $.A.NetBar'
Else
  EZreq 'Cannot find C:Untgz see docs' OK NoFind
EndIf

xButton 4 90 120 20 'uuencoded'
IfExists FILE c:uuhx
  CD $.A.NetBar
  CLI 'c:uuhx x $SfileVar'
Else
  EZreq 'Cannot find C:uuhx see docs' OK NoFind
EndIf

xButton 4 110 120 20 '.zip file'
IfExists FILE c:unzip
  CLI 'c:unzip $SfileVar -d $.A.NetBar'
Else
  EZreq 'Cannot find C:Unzip see docs' OK NoFind
EndIf

XButton 4 136 120 20 'What the hell run it !'
  EZreq 'Are You Sure ???' GoForIt|NoWay RunVar
If $RunVar = 0
  ;Stop and run away
Else
  CLI '$SfileVar'
EndIf

xButton 124 30 120 20 'avi / mov / fli / flc'
IfExists FILE c:xanim
CLI 'c:Xanim.scr $SfileVar'
Else
  EZreq 'Cannot find C:xAnim see docs' OK NoFind
EndIf

xButton 124 50 120 20 'mpeg / mpg'
IfExists FILE c:mp
  CLI 'c:mp -dither gray8 $SfileVar'
Else
  EZreq 'Cannot find C:mp see docs' OK NoFind
EndIf

xButton 124 70 120 20 'Sound file .wav etc'
IfExists FILE c:play16
  CLI 'c:play16 $SfileVar' 
Else
  EZreq 'Cannot find c:play16 see docs' OK NoFind
EndIf

XButton 124 90 120 20 '.gif .jpg .anim etc'
IfExists FILE c:ppshow
  CLI 'c:ppshow $SfileVar'
Else
  EZreq 'Cannot find c:ppshow see docs' OK NoFind  
EndIf

xButton 124 110 120 20 'View Contents'
  GuiLoad    :ConView		; no problem if already loaded
  GuiOpen    ConView
  GuiWindow  ConView FRONT		; bring window to front
  GuiScreen  ConView FRONT		; bring screen to front

xButton 124 136 120 20 'MultiView (OS3.x)'
IfExists FILE sys:utilities/multiview
  CLI 'Sys:Utilities/MultiView $SfileVar' 
Else
  EZreq 'Cannot find Sys:Utilities/MultiView see docs' OK NoFind
EndIf

Text 10 160 120 15 'File to be operated on:' 30 NOBOX
GadFont times.font 13 010

Text 3 176 240 16 '' 80 BOX
GadID 1

xMenu File Open '' O
ReqFile -1 -1 250 200 'Choose a file' LOAD SfileVar 'Sys:'
   UpDate NetView 1 $SfileVar

xMenu File Quit '' Q
GuiClose NetView

xMenu Settings 'UnArc Path ' '' P
GuiLoad :DialEtc
GuiOpen DialEtc

xOnFail
EZreq 'FileType unknown/corrupted or wrong Helper \n Nobodys Perect' OK NoFind

xOnClose
DelVar SfileVar
GuiQuit Pakit
GuiQuit NetView
