
; $VER: Label Designer Install/Remove 1.0 (10.11.95)
;
; Copyright  1995 Markus Mader
; All rights reserved

;english

(set #yes "Yes")
(set #no "No")
(set #bad-kick "\n\nAmigaDOS 2.0 or higher is required for Label Designer1.0.\n\n")
(set #ask-user
(cat "\nLabel Designer 1.0  1995 Markus Mader\nAll rights reserved.\n\n"
   "This script installs or removes Label Designer on harddisk.\n"))
(set #choice0-user "Install Label Designer on harddisk")
(set #choice1-user "Remove Label Designer from harddisk")
(set #already-installed
(cat "\n\nLabel Designer 1.0 is already installed.\n\n"
     "Remove it before installing it again.\n"))
(set #no-help "\n Help not available.\n")
(set #install-prg "\nInstalling program files.\n")
(set #install-libs "\nInstalling Textfield Gadget.\n")
(set #magic "\n\nDo you want to install MagicWB-icons instead of normal icons?\n")
(set #install-icon "\nInstalling normal icons.\n")
(set #install-micon "\nInstalling MagicWB icons.\n")
(set #not-installed
(cat "\n\nLabel Designer 1.0 is not installed.\n\n"
     "Install it before removing it again.\n"))
(set #ask-really
(cat "\nDo you really want to remove Label Designer1.0 "
   "fromyoursystem?\n\n"))
(set #remove-prg "\nRemoving files.\n")
(set #remove-catalog "\nRemoving catalog file.\n")
(set #remove-help "\nRemoving online help.\n")
(set #ask-deltf "\nDo you want to delete the Textfield-Gadget?\n")
(set #installed-ld "Label Designer has been installed.\n")
(set #ask-dir
(cat "\nSelect the target directory. A drawer "
   "'LabelDesigner' will be created there.\n"))
(set #guide-name "LD_english.guide")
(set #make-dir "\nCreating drawer 'LabelDesigner'.\n")
(set #tf-help
(cat "The Textfield-Gadget is a multiline textentry "
   "field. Only delete it, if you are sure that you "
   "do not have any other programs that use it, too. "))
(set #remove-tf "\nRemoving Textfield-Gadget.\n")

;deutsch

(if (= @language "deutsch")
(
(set #yes "Ja")
(set #no "Nein")
(set #bad-kick "\n\nSie bentigen AmigaDOS 2.1 oder hher fr LabelDesigner1.0.\n\n")
(set #ask-user
(cat "\nLabel Designer 1.0  1995 Markus Mader\nAlle Rechte vorbehalten.\n\n"
   "Dieses Skript installiert oder entfernt Label Designer auf der Festplatte.\n"))
(set #choice0-user "Label Designer auf die Festplatte installieren")
(set #choice1-user "Label Designer von der Festplatte entfernen")
(set #already-installed
(cat "\n\nLabel Designer 1.0 ist schon installiert.\n\n"
   "Entfernen Sie es bevor Sie es wieder neu installieren.\n"))
(set #no-help "\n Keine Hilfe verfgbar.")
(set #install-prg "\nInstalliere Programm Dateien.\n")
(set #install-tf "\nInstalliere Textfield Gadget.")
(set #magic "\n\nWollen Sie Icons fr MagicWB anstelle normaler Iconsinstallieren?\n")
(set #install-icon "\nInstalliere normale Icons.\n")
(set #install-micon "\nInstalliere MagicWB Icons.\n")
(set #not-installed
(cat "\n\nLabel Designer 1.0 ist nicht installiert.\n\n"
   "Installieren Sie es bevor Sie es "
   "wieder lschen.\n"))
(set #ask-really "\nWollen Sie wirklich LabelDesigner1.0 lschen?\n\n")
(set #remove-prg "\nEntferne Dateien.\n")
(set #remove-catalog "\nLsche Katalog-Datei.\n")
(set #remove-help "\nLsche Online-Hilfe.\n")
(set #ask-deltf "\nWollen Sie das Textfield-Gadget lschen?\n")
(set #installed-ld "Label Designer wurde installiert.\n")
(set #ask-dir
(cat "\nWhlen Sie das Ziel-Verzeichnis. Eine "
   "Schublade 'LabelDesigner' wird dort angelegt.\n"))
(set #make-dir "\nErstelle Schublade 'LabelDesigner'.\n")
(set #tf-help
(cat "Das Textfield-Gadget ist ein mehrzeiliges "
   "Texteingabefeld. Lschen Sie es nur, wenn "
   "Sie sicher sind, da Sie keine anderen Programme "
   "haben, die es auch benutzen."))
(set #remove-tf "\nEntferne Textfield-Gadget.\n")

))

(complete 0)

(if (< (/ (getversion) 65536) 37)
    (abort #bad-kick))

(set CPU (database "cpu"))


(set action
   (askchoice
      (prompt #ask-user)
      (help @askchoice-help)
      (choices #choice0-user #choice1-user)
      (if (exists "ENV:LabelDesigner.path")
         (default 1)
         (default 0)
      )
   )
)

;install
(if (= action 0)
(
   (if (exists "ENV:LabelDesigner.path")
   (abort #already-installed))

   (set src-path (pathonly (pathonly @icon)))

   (set tf-path (tackon src-path "Libraries/Gadgets/textfield.gadget"))

   (set @default-dest
      (askdir
         (prompt #ask-dir)
         (help @askdir-help)
         (default @default-dest)
      )
   )

   (set dest-path (tackon @default-dest "LabelDesigner"))

   (run (cat "setenv LabelDesigner.path " dest-path))

   (run "copy ENV:LabelDesigner.path to ENVARC:")

   (complete 5)

   (makedir dest-path)

   (complete 10)

   (copyfiles
      (prompt #install-prg)
      (help @copyfiles-help)
      (source src-path)
      (choices
         "LabelDesigner"
         "Catalogs/LabelDesigner.ct"
         (tackon (tackon "Docs" @language) "LabelDesigner.guide")
         (tackon (tackon "Docs" @language) "RegForm")
      )
      (dest dest-path)
      (confirm "expert")
   )

   (complete 50)

   (if (<> @language "english")
      (copyfiles
         (prompt #install-prg)
         (help @copyfiles-help)
         (source src-path)
         (choices (tackon (tackon "Catalogs" @language) "LabelDesigner.catalog"))
         (dest (tackon "Locale:Catalogs/" @language))
         (confirm "expert")
      )
   )

   (complete 65)

   (copyfiles
      (prompt #install-prg)
      (help @copyfiles-help)
      (source src-path)
      (choices (tackon (tackon "Docs" @language) "LabelDesigner.guide"))
      (dest (tackon "HELP:" @language))
      (confirm "expert")
   )

   (complete 80)

   (if (< (/ (getversion) 65536) 39)
      (set gadget-path "SYS:Libs/Gadgets")
      (set gadget-path "SYS:Classes/Gadgets")
   )

   (copylib
      (prompt #install-tf)
      (help @copylib-help)
      (source tf-path)
      (dest gadget-path)
      (confirm "expert")
   )

   (complete 90)

   (set magic
      (exists "ENV:MagicWB")
   )

   (if (= 0 magic)
      (set magic
         (askbool
            (prompt #magic)
            (help #no-help)
            (choices #yes #no)
            (default 1)
         )
      )
   )

   (if (= 0 magic)
      (set icon-source-dir (tackon src-path "NormalIcons"))
      (
         (set icon-source-dir (tackon src-path "MagicWBIcons"))
         (set #install-icon #install-micon)
      )
   )

   (copyfiles
      (prompt #install-icon)
      (help @copyfiles-help)
      (source icon-source-dir)
      (choices "LabelDesigner.info" "LabelDesigner.guide.info" "RegForm.info")
      (dest dest-path)
      (confirm "expert")
   )
   (copyfiles
      (prompt #install-icon)
      (help @copyfiles-help)
      (source icon-source-dir)
      (choices "LabelDesigner_Drawer.info")
      (dest (pathonly dest-path))
      (confirm "expert")
   )

   (complete 95)

   (if (exists (tackon (pathonly dest-path) "LabelDesigner_Drawer.info"))
      (rename
         (tackon (pathonly dest-path) "LabelDesigner_Drawer.info")
         (tackon (pathonly dest-path) "LabelDesigner.info")
      )
   )

   (complete 97)

   (if (< (/ (getversion) 65536) 39)
      (set default-tool "SYS:Utilities/AmigaGuide")
      (set default-tool "SYS:Utilities/MultiView")
   )

   (tooltype
      (dest (tackon dest-path "LabelDesigner.guide"))
      (setdefaulttool default-tool)
   )

   (complete 100)
   (exit)
))

;remove
(if (= action 1)
(
   (if (NOT (exists "ENV:LabelDesigner.path"))
      (abort #not-installed))

   (set really
      (askbool
         (prompt #ask-really)
         (help #no-help)
         (choices #yes #no)
         (default 1)
      )
   )
   (complete 5)

   (if (= 0 really) (exit (quiet)))

   (set install-path (getenv "LabelDesigner.path"))

   (delete "ENVARC:LabelDesigner.path")
   (delete "ENV:LabelDesigner.path")

   (complete 10)

   (run
      (cat "Delete >NIL: " install-path "#? ALL FORCE")
      (prompt #remove-prg)
      (help #no-help)
      (confirm "average")
   )

   (complete 50)

   (if (exists (tackon (tackon "LOCALE:Catalogs" @language) "LabelDesigner.catalog"))
      (delete
         (tackon (tackon "LOCALE:Catalogs" @language) "LabelDesigner.catalog")
         (prompt #remove-catalog)
         (help #no-help)
         (confirm "average")
      )
   )

   (complete 65)

   (if (exists (tackon (tackon "HELP:" @language) "LabelDesigner.guide"))
      (delete
         (tackon (tackon "HELP:" @language) "LabelDesigner.guide")
         (prompt #remove-help)
         (help #no-help)
         (confirm "average")
      )
   )

   (complete 80)

   (if (set deltf
         (askbool
            (prompt #ask-deltf)
            (help #tf-help)
            (choices #yes #no)
            (default 1)
         )
      )
      (
         (if (< (/ (getversion) 65536) 39)
            (set gadget-path "SYS:Libs/Gadgets")
            (set gadget-path "SYS:Classes/Gadgets")
         )

         (delete
            (tackon gadget-path "textfield.gadget")
            (prompt #remove-tf)
            (help #tf-help)
         )
      )
   )

   (complete 100)
   (exit (quiet))
))
(welcome "")

