;
; AmigaTrainer Installations- Skript $VER:AmigaTrainer 2.0 (10.11.1995)
;
(if (= "deutsch" @language)
(
    (set default_lang 1)

    (set #startmsg "\nAmigaTrainer Installations-Skript.\n\nDieses Skript installiert AmigaTrainer auf Ihrer Festplatte oder Diskette.\n\nAmigaTrainer  1994-95 by Frank Weber\nAlle Rechte vorbehalten.")
    (set #choosedir "Bitte whlen Sie das Verzeichnis, in dem die AmigaTrainer-Schublade erstellt werden soll")
    (set #choosehelp (cat "\nIn dem Verzeichnis, das Sie hier auswhlen, wird eine Schublade mit dem Namen AmigaTrainer erstellt, in die das Hauptprogramm und die dazugehrigen Dateien kopiert werden."))
    (set #copybeispiel "\nMchten Sie die Zusatzdateien\n(Vokabeln/Sounds...) installieren ???\n\n(Sollten Sie installieren)")
    (set #copybeispiel-help "AmigaTrainer werden einige Dateien mitgeliefert,\nz.B. Vokabeldateien oder Sounddateien, die Sie spter in AmigaTrainer verwenden knnen.\n\nKlicken Sie auf 'Ja', wenn Sie diese Dateien installieren mchten.")
    (set #overwritemsg (cat"\nAmigaTrainer wurde bereits in dieses Verzeichnis installiert.\n\nAltes AmigaTrainer-Verzeichnis lschen ???"))
    (set #overwritehelp (cat"\nIn dem Verzeichnis, das Sie ausgewhlt haben, existiert bereits ein Verzeichnis mit dem Namen 'AmigaTrainer'.\n\nAntworten Sie 'Ja', wenn Sie das alte Verzeichnis komplett lschen mchten, bevor diese Version installiert wird."))
    (set #chooselang "\nWelche Sprachen sollen installiert werden ???")
    (set #chooselang-help "\nWenn Sie AmigaTrainer in verschiedenen Sprachen benutzen mchten, mssen Sie die Catalog-Dateien installieren. Whlen Sie aus, welche Cataloge Sie installieren wollen")
    (set #copylangs "\nMchten Sie die Sprachdateien (Cataloge) fr Deutsch und Englisch installieren ???")
    (set #copylangs-help "\nWenn Sie AmigaTrainer in verschiedenen Sprachen benutzen mchten, mssen Sie die Catalog-Dateien installieren.")
    (set #keyfiledir "\nWohin soll das Keyfile kopiert werden ??\n")
    (set #keyfiledir-help "\nUm AmigaTrainer als registrierter Anwender benutzen zu knnen, bentigen Sie das Keyfile. Damit knnen Sie auch neuere Demo-Versionen als Vollversionen benutzen.\nWhlen Sie aus, wohin es kopiert werden soll.")
    (set #sameasAT "gleiches Verzeichnis")
    (set #sdir "S: - Verzeichnis")
    (set #bdir "Vokabeln")
    (set #updir "Bitte whlen Sie die 'AmigaTrainer'-Schublade aus, in der das Update installiert werden soll")
    (set #updirhelp "Sie mssen sich hier das Verzeichnis\nauswhlen, IN dem sich das Hauptprogramm,\ndie Anleitung usw. befinden.\n\nWichtig: Ihre Vokabeln, die sich evtl.\nin diesem Verzeichnis befinden,\nwerden NICHT gelscht.")
    (set #uperr "Ich konnte das Hauptprogramm leider nicht in\ndiesem Verzeichnis finden.\n\nBitte beachten Sie, da Sie sich IM Verzeichnis,\nin dem Hauptprogramm, Anleitung etc. installiert\nsind befinden mssen, wenn Sie den Verzeichnisrequester besttigen.")
    (set #uperr2 "\n\nMchten Sie nochmal ein Verzeichnis auswhlen oder\nAmigaTrainer neu in dieses Verzeichnis installieren???")
    (set #uperrc1 "Nochmal")
    (set #uperrc2 "Neu installieren")
    (set #what "Was mchten Sie installieren")
    (set #new "AmigaTrainer neu installieren")
    (set #update "Update installieren")
    (set #keyfile "Keyfile installieren")
    (set #atfile "Bitte whlen Sie das 'AmigaTrainer'-Hauptprogramm aus")
    (set #atfilehelp "Sie mssen hier das Hauptprogramm 'AmigaTrainer' auswhlen, damit ich den KEYFILE-Tooltype richtig setzen kann.")
))
(if (= "english" @language)
(
    (set default_lang 2)
    (set #startmsg "\nAmigaTrainer Installation-Script.\n\nThis script will install AmigaTrainer to your harddisk or floppydisk.\n\nAmigaTrainer  1994-95 by Frank Weber\nAll rights reserved.")
    (set #choosedir "Please choose the directory where you want the 'AmigaTrainer'-directory to be created in")
    (set #choosehelp (cat "A new directory 'AmigaTrainer' will be created in the directory you select, where AmigaTrainer and all additional files will be copied into."))
    (set #copybeispiel "\n\nDo you want the additional files (words/sounds...) files to be installed ???\n\n(Installation recommended)")
    (set #copybeispiel-help "\nThis package includes some files that will be of use for you when using AmigaTrainer.\n\nSelect 'Yes' if you want them to be installed.")
    (set #overwritemsg (cat"\nAmigaTrainer has already been installed into this directory.\n\nDelete old directory"))
    (set #overwritehelp (cat"\nThere is already a directory called 'AmigaTrainer' in the directory chosen by you.\n\nSelect yes if you want the whole directory to be deleted before this version is installed."))
    (set #overwritemsg (cat"\nAmigaTrainer has already been installed into this drawer.\n\nDelete old AmigaTrainer-drawer ???"))
    (set #overwritehelp (cat"\nIn the drawer you have chosen there is already a directory called 'AmigaTrainer'.\n\nAnswer 'Yes' if you want the old AmigaTrainer-directory to be deleted."))
    (set #chooselang "\nWhich language do you want to have installed ???")
    (set #chooselang-help "\nIf you want to use AmigaTrainer in different languages, the catalog files must be installed. Please choose which catalogs you want to be installed.")
    (set #copylangs "\nDo want to have the language files (catalogs) to be installed ???")
    (set #copylangs-help "\nIf you want to use AmigaTrainer in different languages, the catalog files must be installed.")
    (set #keyfiledir "\nWhere do you want the Keyfile to be installed ??\n")
    (set #keyfiledir-help "\nTo use AmigaTrainer as a registered user, you need the keyfile. With this keyfile you will also be able to use newer demo-versions as regsitred versions.\nChoose where you want to have it installed.")
    (set #sameasAT "same directory")
    (set #sdir "S: - directory")
    (set #bdir "words")
    (set #updir "Please choose the 'AmigaTrainer'-drawer\nwhere you want this update to be installed")
    (set #updirhelp "Here you have to choose the drawer where the\nmain program, the documentation etc.\nare already installed\n\nNOTE: Your word files that might also be\nsomewhere within this drawer are not deleted.")
    (set #uperr "Couldn't locate the main program within this drawer.\nPlease note that you have to be WITHIN directory\nthat contains the main program, the documentation...\nwhen you confirm the directory requester.")
    (set #uperr2 "\n\nWould you like trying to choose the proper\ndirectory again?\n\nElse I could install AmigaTrainer completely new\nto this drawer.")
    (set #uperrc1 "Try again")
    (set #uperrc2 "Install new")
    (set #what "How would you like to have AmigaTrainer installed")
    (set #new "Install new")
    (set #update "Install update")
    (set #keyfile "Install keyfile")
    (set #atfile "Please choose the 'AmigaTrainer' main program")
    (set #atfilehelp "It is necessary for me to know where your main program is located, since I have to set the KEYFILE tooltype")
))


(if (exists "Work:" (NOREQ))
  (set default-dir "Work:")
  (set default-dir "Sys:")
)

(message #startmsg)

(set mode
        (askchoice
                (prompt #what)
                (help @askchoice-help)
                (choices #new #update #keyfile)
                (default 0)
        )
)

(complete 8)

(if (= mode 1)    ;Update
(
    (set @default-dest default-dir)

    (until (<> updatedir 0)
    (
        (if (> @user-level 0)
                (set @atdir
                        (askdir
                                (prompt #updir)
                                (help #updirhelp)
                                (default @default-dest)
                        )
                )
        )

        (if (= @atdir 0) (set @atdir @default-dest))

        (set updatedir 0)

        (if (exists (tackon @atdir "AmigaTrainer"))
        (
            (set size (getsize (tackon @atdir "AmigaTrainer")))
            (if (<> size 0)
                (
                  (set updatedir 1)
                  (set @default-dest @atdir)
                )
                (message #uperr)
            )
        )
        (if (= 0 (askbool (prompt (cat #uperr #uperr2)) (choices #uperrc1 #uperrc2) (help "")) )
           (set updatedir 2)
        )

        )
    ))

    (if (= updatedir 1)
    (
        (if (exists (tackon @atdir "AmigaTrainer") (noreq)) (delete (tackon @atdir "AmigaTrainer") (infos)))
        (if (exists (tackon @atdir "Anleitung.guide") (noreq)) (delete (tackon @atdir "Anleitung.guide") (infos)))
        (if (exists (tackon @atdir "AT.guide") (noreq)) (delete (tackon @atdir "AT.guide")(infos)))
        (if (exists (tackon @atdir "ReadMe_now") (noreq)) (delete (tackon @atdir "ReadMe_now")(infos)))
        (if (exists (tackon @atdir "LiesMich_jetzt") (noreq)) (delete (tackon @atdir "Liesmich_jetzt")(infos)))
        (if (exists (tackon @atdir "Hallo_Schler!!") (noreq)) (delete (tackon @atdir "Hallo_Schler!!")(infos)))
        (if (exists (tackon @atdir "RegiTool") (noreq)) (delete (tackon @atdir "RegiTool")(infos)))
        (if (exists (tackon @atdir "Installer-skript") (noreq)) (delete (tackon @atdir "Installer-Skript")(infos)))
        (if (exists (tackon @atdir "Install_Deutsch.info") (noreq)) (delete (tackon @atdir "Install_Deutsch.info")))
        (if (exists (tackon @atdir "Install_English.info") (noreq)) (delete (tackon @atdir "Install_English.info")))
        (if (exists "Locale:catalogs/deutsch/AT.catalog" (noreq)) (delete "Locale:catalogs/deutsch/AT.catalog"))
        (if (exists "Locale:catalogs/english/AT.catalog" (noreq)) (delete "Locale:catalogs/english/AT.catalog"))
   )
   (
        (if (= updatedir 2)
        (
            (makedir (tackon @atdir "AmigaTrainer") (infos))
            (set @atdir (tackon @atdir "AmigaTrainer/"))
            (set @default-dest @atdir)
        ))
   ))

))

(if (<> mode 2)
(

    (if (= mode 0)
    (
        (set @default-dest default-dir)
        (if (> @user-level 0)
                (set @user-dest
                        (askdir
                                (prompt #choosedir)
                                (help #choosehelp)
                                (default @default-dest)
                        )
                )
        )

        (if (= @user-dest 0) (set @user-dest @default-dest))

        (set @atdrawername (tackon @user-dest "AmigaTrainer"))
        (set @default-dest @atdrawername)

        (if (exists @atdrawername)
        (
          (if (> @user-level 1)
          (
            (set overwrite (askbool
                                   (prompt #overwritemsg)
                                   (help #overwritehelp)
                                   (default 0)
                           )
            )
            (if (= 1 overwrite)
              (run (cat "c:delete QUIET ALL " @atdrawername))
            )
          ))
        ))

        (makedir @atdrawername (infos))
    )
    (
        (set @atdrawername @atdir)
        (set @default-dir @atdrawername)
    )
    )

    (complete 20)

    (copyfiles
         (source "AmigaTrainer")
         (dest @atdrawername)
         (infos))

    (complete 30)

    (copyfiles
         (source "Anleitung.guide")
         (dest @atdrawername)
         (infos))

    (if (< (/ (getversion) 65536) 38)
        (tooltype (dest (tackon @atdrawername "Anleitung.guide"))
                  (setdefaulttool "sys:utilities/AmigaGuide")
        )

        (tooltype (dest (tackon @atdrawername "Anleitung.guide"))
                  (setdefaulttool "sys:utilities/Multiview")
        )

    )

    (complete 40)

    (copyfiles
         (source "LiesMich")
         (dest @atdrawername)
         (infos))

    (copyfiles
         (source "ReadMe")
         (dest @atdrawername)
         (infos))

    (complete 55)

    (if (OR (= mode 0) (= updatedir 2))
    (

      (if (= default_lang 1)

        (copyfiles  (source "AT.config_d")
                    (dest @atdrawername )
                    (newname "AT.config")
        )
        (copyfiles  (source "AT.config_e")
                    (dest @atdrawername)
                    (newname "AT.config")

        )
      )
      (tooltype (dest (tackon @atdrawername "AmigaTrainer"))
                (settooltype "OPTIONS" "AT.config")
      )

    )
    (
      (if (exists "S:AT.config")
        (tooltype (dest (tackon @atdrawername "AmigaTrainer"))
                  (settooltype "OPTIONS" "S:AT.config")
        )
        (if (exists (tackon @atdrawername "AT.config"))
          (tooltype (dest (tackon @atdrawername "AmigaTrainer"))
                    (settooltype "OPTIONS" "AT.config")
          )
        )
      )
    ))


    (tooltype (dest (tackon @atdrawername "AmigaTrainer"))
              (settooltype "DOC" "Anleitung.guide")
    )


    (complete 60)

    (if (> @user-level 1)
    (
        (if (askbool (prompt #copybeispiel)
                     (help #copybeispiel-help)
                     (default 0)
            )
            (set installbeispiel 1)
            (set installbeispiel 0)
        )
     )
     ((set installbeispiel 1)
     ))

    (if (= 1 installbeispiel)
    (
        (set @beispieldrawer (tackon @atdrawername #bdir))
        (makedir @beispieldrawer)

        (copyfiles
             (source (pathonly "Vokabeln/"))
             (dest @beispieldrawer)
             (Pattern "#?.AT"))

        (makedir (tackon @atdrawername "Sounds"))

        (copyfiles
            (source "Sounds/")
            (dest (tackon @atdrawername "Sounds"))
            (Pattern "#?")
        )

        (makedir (tackon @atdrawername "Workshop") (infos))

        (copyfiles
            (source "Workshop/")
            (dest (tackon @atdrawername "Workshop"))
            (Pattern "#?")
        )

    ))

    (complete 80)

    (set locale 0)
    (if (> @user-level 1)
      (set locale 2)
      (set locale 1)
    )
    (if (< @user-level 1)
        (set locale 0)
    )

    (if (= locale 2)
      (if (exists "SYS:Locale")
      (
        (if (exists "LOCALE:")
        (
          (set lang (askoptions (prompt #chooselang)
                                (help #chooselang-help)
                                (choices "Deutsch" "English")
                                (default default_lang)
                    )
          )
          (set n 0)
          (while (set language (select n
                                         "deutsch"
                                         "english"
                                         ""
                                )
                  )
          (
          (if (IN lang n)
          (
              (makedir (tackon "Locale:Catalogs/" language))
              (copyfiles
                 (source (tackon (tackon "Locale/Catalogs/" language) "AT.catalog"))
                 (dest (tackon "Locale:Catalogs/" language))
              )
          ))
          (set n (+ n 1))
          ))
        ))
      ))
    )

    (if (= locale 0) (set copylangs 1))

    (if (= locale 1)
        (set copylangs (askbool   (prompt #copylangs)
                                  (help #copylangs-help)
                                  (default 0)
                       )
        )
    )
    (if (= 1 copylangs)
    (
        (makedir  "Locale:Catalogs/deutsch")
        (makedir  "Locale:Catalogs/english")
        (copyfiles
           (source "Locale/Catalogs/deutsch/AT.catalog")
           (dest "Locale:Catalogs/deutsch")
        )
        (copyfiles
           (source "Locale/Catalogs/english/AT.catalog")
           (dest "Locale:Catalogs/english")
        )
    ))

))

(if (= mode 2)
  (complete 40)
  (complete 90)
)

(if (exists "AT_Key-File" (noreq))
(
    (set copykey 2)
    (if (= mode 2)
    (
        (set @atfile (askfile (prompt #atfile)
                              (help #atfilehelp)
                              (default "sys:")
        )            )
        (set @atdrawername (pathonly @atfile))
        (set @default-dest @atdrawername)
    ))

    (if (> @user-level 1)
        (set @keyfilepath (askdir (prompt #keyfiledir)
                                  (help #keyfiledir-help)
                                  (default @atdrawername)
                          )
        )
        (set copykey (askbool  (prompt #keyfiledir)
                               (help #keyfiledir-help)
                               (choices #sameasAT #sdir)
                               (default 1)
                     )
        )
     )
     (if (= copykey 1) (set @keyfilepath @atdrawername))
     (if (= copykey 0) (set @keyfilepath "S:"))

     (copyfiles  (source "AT_Key-File")
                 (dest @keyfilepath)
     )

     (tooltype (dest (tackon @atdrawername "AmigaTrainer"))
               (settooltype "KEYFILE" (tackon @keyfilepath "AT_Key-File"))
     )


     (complete 100)

)                   

(if (= mode 1)
(
    (if (exists (tackon @atdrawername "AT_Key-File"))
         (tooltype (dest (tackon @atdrawername "AmigaTrainer"))
                   (settooltype "KEYFILE" "AT_Key-File")
         )
         (if (exists "S:AT_Key-File")
             (tooltype (dest (tackon @atdrawername "AmigaTrainer"))
                       (settooltype "KEYFILE" "S:AT_Key-File")
             )
         )
    )
))

(complete 100)
)

(complete 100)
