;
; Installations-Skript fr das komplette Rechnungsprogramm.
;


; Die Routine im Fehlerfall

(onerror
	(makeassign "MUI-Rechnung" (safe))
)

(complete 0)

; Falls die Installation erneut gestartet wird

(makeassign "MUI-Rechnung" (safe))	; neu starten ohne Assigns

;
; 1. Teil
;
; Installation von 'Rechnung' mit allen dazugehrigen Dateien
;

(set Rechnung_dest			; Variable fr den Pfad
	(tackon
		(askdir
			(prompt "In welchem Verzeichnis soll ein Verzeichnis \"MUI-Rechnung\" "
			        "angelegt werden und das Programm MUI-Rechnung installiert "
                 "werden?")
			(help @askdir-help)
			(default @default-dest)
		)
		"MUI-Rechnung"
	)
)

(makedir Rechnung_dest (infos))

; fr den Installer noch das endgltige Verzeichnis mitteilen

(set @default-dest Rechnung_dest)

; Teste nach, ob es sich um OS2.x oder OS3.x handelt

(set vernum (getversion "exec.library" (resident)))
(set ver (/ vernum 65536))

(if (>= ver 39)
	(set This_dest (tackon "libs:" "Gadgets"))
	(set This_dest (tackon Rechnung_dest "Gadgets"))
)

; Kopiere das Gadget

(copylib
	(prompt "Kopiere das Textfield.gadget.")
	(help @copylib-help)
	(source "Gadgets/textfield.gadget")
	(dest This_dest)
	(infos)
	(confirm)
)


; Kopiere die Files...

(copylib
	(prompt "Kopiere das Programm \"MUI-Rechnung\".")
	(help @copylib-help)
	(source "MUI-Rechnung")
	(dest Rechnung_dest)
	(infos)
	(confirm)
)

;
; zustzlich fr ACC Briefe
;

(copylib
	(prompt "Kopiere das Startprogramm \"Briefe\".")
	(help @copylib-help)
	(source "Briefe")
	(dest Rechnung_dest)
	(infos)
	(confirm)
)


(complete 15)

(copylib
	(prompt "Kopiere die Online-Hilfe fr \"MUI-Rechnung\".")
	(help @copylib-help)
	(source "MUI-Rechnung.guide")
	(dest Rechnung_dest)
	(infos)
	(confirm)
)

(complete 25)

(if (= (exists (tackon Rechnung_dest "Konfiguration.dat") ) 0)
	(copyfiles
		(prompt "Kopiere Default-Konfiguration.")
		(help @copyfiles-help)
		(source "Konfiguration.dat")
		(dest Rechnung_dest)
		(confirm)
	)
)

(if (= (exists (tackon Rechnung_dest "Kundenkategorien.dat") ) 0)
	(copyfiles
		(prompt "Kopiere Kundenkategorien.")
		(help @copyfiles-help)
		(source "Kundenkategorien.dat")
		(dest Rechnung_dest)
		(confirm)
	)
)

(if (= (exists (tackon Rechnung_dest "Artikelkategorien.dat") ) 0)
	(copyfiles
		(prompt "Kopiere Artikelkategorien.")
		(help @copyfiles-help)
		(source "Artikelkategorien.dat")
		(dest Rechnung_dest)
		(confirm)
	)
)

(if (= (exists (tackon "" "MUI-Rechnung.user") ) 1)
	(copyfiles
		(prompt "Kopiere Konfigurationsdatei.")
		(help @copyfiles-help)
		(source "MUI-Rechnung.user")
		(dest Rechnung_dest)
		(confirm)
	)
)

(complete 30)


(set This_dest
	(tackon
		Rechnung_dest
		"TeXwork"
	)
)
(if (= (exists (tackon This_dest "invoice.tex") ) 1)
	(delete (tackon This_dest "invoice.tex")
		(prompt "Lsche altes TeX-Format.")
		(help @delete-help)
		(optional "force")
	)
)

(copyfiles
	(prompt "Kopiere TeX-Files.")
	(help @copyfiles-help)
	(source "TeXwork")
	(choices "invoicepatch.tex" "ecma94.tex" "german.sty" "checkprt.dvi" "invoicemacro.tex" "listmacro.tex" "labelmacro.tex" "ShowDVI.rexx")
	(dest This_dest)
	(confirm)
)

(complete 35)

;
; 2. Teil
;
; Installation von TeX
;

(set is_TeX_update 0)
(set TeX_dest (getassign "TeX" "a"))

; Wenn es ein Update ist, dann wahrscheinlich im alten Pfad installieren

(if TeX_dest
	(if (askbool
			(prompt "Ihre aktuelle Version von TeX befindet sich vermutlich im Verzeichnis \""
					TeX_dest
					"\". Wollen Sie TeX in dieses Verzeichnis installieren (siehe hierzu unbedingt 'Help...'!) ?")
			(help
				"Das Installationsprogramm hat erkannt, da Sie evtl. bereits eine "
				"Version von TeX auf Ihrem System installiert haben.\n\n"
				"Falls Sie TeX nur in Verbindung mit der MUI-Rechnung verwenden, whlen Sie "
				"JA, um die Installation im bisherigen Verzeichnis fortzufhren.\n\n"
				"Falls Sie TeX auch anderweitig verwenden ist es nicht ratsam, die Installation in "
				"das gleiche Verzeichnis durchfhren zu lassen. Whlen Sie zuerst NEIN und "
				"geben Sie ein anderes Verzeichnis an, um vorbergehend das mitgelieferte "
				"TeX zu verwenden.\n\n"
				"Wenn Sie TeX auch anderweitig verwenden, knnen Sie die Installation auch "
				"an dieser Stelle abbrechen.\n\n"
				"Bei Problemen mit TeX hilft Ihnen der Autor von MUI-Rechnung gerne weiter."
			)
			(default 1)
		)

		(set is_TeX_update 1)
	)
)

; Falls es kein Update ist, den gewnschten Pfad erfragen.

(if (NOT is_TeX_update)
	(set TeX_dest
		(tackon
			(askdir
				(prompt "In welchem Verzeichnis soll ein Verzeichnis \"TeX\" angelegt "
				        "und TeX installiert werden?")
				(help @askdir-help)
				(default @default-dest)
			)
			"TeX"
		)
	)
)

; Erzeuge Schublade mit Icon, falls sie noch nicht vorhanden ist.

(if (NOT is_TeX_update)
	(makedir TeX_dest (infos))
)

;
; altes File evtl. loeschen
;

(if is_TeX_update
	;
	; altes Formatfile loeschen
	;
	(if (= (exists (tackon TeX_dest "formats/invoice.fmt") ) 1)
		(delete (tackon TeX_dest "formats/invoice.fmt")
			(prompt "Lsche altes TeX-Format.")
			(help @delete-help)
			(optional "force")
		)
	)

	;
	; alte TeX-Files loeschen
	;
	(if (= (exists (tackon TeX_dest "invoice.tex") ) 1)
		(delete (tackon TeX_dest "invoice.tex")
			(prompt "Lsche altes TeX-Format.")
			(help @delete-help)
			(optional "force")
		)
	)
	(if (= (exists (tackon TeX_dest "invoicepatch.tex") ) 1)
		(delete (tackon TeX_dest "invoicepatch.tex")
			(prompt "Lsche altes TeX-Format.")
			(help @delete-help)
			(optional "force")
		)
	)
	(if (= (exists (tackon TeX_dest "checkprt.dvi") ) 1)
		(delete (tackon TeX_dest "checkprt.dvi")
			(prompt "Lsche altes TeX-Format.")
			(help @delete-help)
			(optional "force")
		)
	)
)

(makeassign "TeX" TeX_dest)

; Bin-Dateien sind noch auf der ersten Diskette

(set This_dest
	(tackon
		TeX_dest
		"bin"
	)
)
(copyfiles
	(prompt "Kopiere ausfhrbare Programme fr TeX.")
	(help @copyfiles-help)
	(source "TeX/bin")
	(dest This_dest)
	(confirm)
	(all)
)

(complete 50)

;
; Formatfile fuer TeX
;

(set This_dest
	(tackon
		TeX_dest
		"formats"
	)
)

;
; altes File evtl. loeschen
;

(if (= (exists (tackon This_dest "invoice.fmt") ) 1)
	(delete (tackon This_dest "invoice.fmt")
		(prompt "Lsche altes TeX-Format.")
		(help @delete-help)
		(optional "force")
	)
)

;
; nur noch das Plain.fmt kopieren
;

(copyfiles
	(prompt "Kopiere Formatdatei fr TeX.")
	(help @copyfiles-help)
	(source "TeX/formats")
	(dest This_dest)
	(all)
)

(complete 75)

(set This_dest
	(tackon
		TeX_dest
		"config"
	)
)
(copyfiles
	(prompt "Kopiere Konfiguration fr TeX.")
	(help @copyfiles-help)
	(source "TeX/config")
	(dest This_dest)
	(all)
)

(complete 78)

(set This_dest
	(tackon
		TeX_dest
		"rexx"
	)
)
(copyfiles
	(prompt "Kopiere ARexx Dateien fr TeX.")
	(help @copyfiles-help)
	(source "TeX/rexx")
	(dest This_dest)
	(all)
)

(complete 80)

(set This_dest
	(tackon
		TeX_dest
		"fonts"
	)
)
(copyfiles
	(prompt "Kopiere Fonts fr TeX.")
	(help @copyfiles-help)
	(source "TeX/fonts")
	(dest This_dest)
	(all)
)

(complete 85)

(set This_dest
	(tackon
		TeX_dest
		"pk"
	)
)
(copyfiles
	(prompt "Kopiere Fonts fr TeX.")
	(help @copyfiles-help)
	(source "TeX/pk")
	(dest This_dest)
	(optional "nofail")
	(all)
)

(complete 90)

(set This_dest
	(tackon
		TeX_dest
		"pool"
	)
)
(copyfiles
	(prompt "Kopiere Pool fr TeX.")
	(help @copyfiles-help)
	(source "TeX/pool")
	(dest This_dest)
	(all)
)

(complete 95)

; ndere die S:User-Startup

(startup "TeX"
	(prompt
		"Es mu noch ein Befehl in die \"S:user-startup\" eingefgt "
		"werden, damit Ihr System fr TeX korrekt konfiguriert ist.")
	(help "Diese nderung MUSS vorgenommen werden, oder TeX wird "
	      "nicht funktionieren!")
   (command
		"ASSIGN TeX: \"" TeX_dest "\"\n"
	)
)

; Alle Assigns wieder initialisieren

(if (not @pretend)
	(makeassign "TeX" TeX_dest)
)

(complete 100)

	; cleanup

(message
   "Bitte stellen Sie nach der Installation die Grundeinstellungen im Programm \"MUI-Rechnung\" nach "
   "Ihren Bedrfnissen ein. Danach kann mit \"MUI-Rechnung\" gearbeitet werden. "
   "Mit dem Programm \"MUI\" knnen Sie die Oberflche der MUI-Rechnung nach Ihren "
   "Wnschen einstellen (eigener Screen, Fonts, MagicWB-look, ...)."
)

(makeassign "MUI-Rechnung" (safe))

	; this is not strictly necessary, but doesn't hurt -- there is always
	; a default (exit) at the end of any script
(exit)
