;
; $VER: Script di Installazione di TurboProspEd v2.1 (06.07.00)
;

(set @default-dest "Work:")
(set #wrongOS   (cat "TurboProspEd necessita\n"
                     "dell'OS2.0 o superiore!\n"))
(set #TGest_dir (cat "Scegli il cassetto o la partizione\n"
                     "dove installare il cassetto TGest.\n"
                     "Se il cassetto esiste già, allora seleziona\n"
                     "il cassetto o la partizione che lo contiene."))
(set #done      (cat "TurboProspEd è stato installato\n"
                     "con successo nel cassetto.\n\n"))

(set OS_ver (getversion "exec.library" (resident)))
(if (< OS_ver (* 37 65536)) (abort #wrongOS))

(complete 0)
(set TGest_def_dir @default-dest)
(set TGest_dir
        (askdir
                (default TGest_def_dir)
                (prompt  #TGest_dir)
                (help    @askdir-help)
        )
)

(set TGest_dir (tackon TGest_dir "TGest"))
(set Doc_dir   (tackon TGest_dir "Doc"))
(set Pro_dir   (tackon TGest_dir "Prospetti"))

(if (NOT (exists TGest_dir)) (makedir TGest_dir (infos)))
(if (NOT (exists Doc_dir))   (makedir Doc_dir   (infos)))
(if (NOT (exists Pro_dir))   (makedir Pro_dir))

(complete 10)
(copyfiles (source "ProspEd")   (dest TGest_dir) (infos) (help @copyfiles-help))
(complete 70)
(copyfiles (source "TransPros") (dest TGest_dir) (infos) (help @copyfiles-help))
(complete 80)
(copyfiles (source "Prospetti/") (dest Pro_dir)  (all)   (help @copyfiles-help))
(complete 90)
(copyfiles (source "Doc/")       (dest Doc_dir)  (all)   (help @copyfiles-help))
(complete 100)

(message #done "\"" TGest_dir "\"")
(exit)