; Creates month-dependent Filename for Bootpics

; Language: BlitzBASIC 2.1
; Requires: "Blitzlibs:Amigalibs.res" in Compiler-Options
;

DEFTYPE.l                                               ; All Vars LONG-Integer
*dattim.DateTime=AllocVec_(76,#MEMF_CLEAR|#MEMF_PUBLIC) ; Allocate Memory
If *dattim<>0                                           ; Check Memory
  rda_results=*dattim+64                                ; Memory for Arguments
  rd_args=ReadArgs_(?template,rda_results,0)            ; Read Arguments
  If rd_args
    *dattim\dat_Format=3                                ; Set Date-Format
    *dattim\dat_StrDate=*dattim+32                      ; Set Pointer to Date-String
    dummy.l=DateStamp_(*dattim)                         ; Get Systemdate
    dummy.l=DateToStr_(*dattim)                         ; Convert SystemDate to String
    Poke.b *dattim\dat_StrDate+5,0                      ; Terminate Day in DateString
    fh1.l=Open_(?env,#MODE_NEWFILE)                     ; Open ENV for output
    If fh1<>0
      FPuts_ fh1,?af                                    ; Write '"'
      FPuts_ fh1,Peek.l(rda_results)                    ; Write Pathname
      FPuts_ fh1,*dattim\dat_StrDate+3                  ; Write DayString
      FPuts_ fh1,?af                                    ; Write '"'
      Close_ fh1                                        ; Close ENV-File
    EndIf
    FreeArgs_ rd_args                                   ; Freeing Args-Structure
  EndIf
  FreeVec_ *dattim                                      ; deallocate Memory
EndIf
End
; -------------------------------------------------------------------------
copyright:
  Dc.b "$VER: BootpicName 1.2 (17.06.1999) by J.Reinert",0
af:
  Dc.b 34,0
env:
  Dc.b "ENV:BOOTPIC",0
template:
  Dc.b "BASENAME",0
  Even