/* Beispiel 2: */
/* Gibt die Datei S:user-startup über das Desk-Modul in ein */
/* Fax aus und betrachtet hinterher das erstellte Fax.      */

/* Vor jeder Befehlszeile steht die Beschreibung der Zeile. */

	/* Es folgen DOS-Befehle. */
address command
call open out,"RAM:TMP",write
call writeln out,'Stack 20000'
call writeln out,'MultiFax:Desk'
call close out
	/* Start des Desk-Moduls über die temporäre Datei, */
	/* da eine Erhöhung des Stapelspeichers notwendig war.. */
'Run Execute RAM:TMP'
	/* Start des MultiFax-ARexx-Moduls. */
'Run MultiFax:MFRexx'
	/* 10 Sekunden warten. */
'Wait' "10 secs"
	/* Es folgen MultiFax-Befehle. */
address 'MultiFaxRexx'
	/* Wir möchten gerne Ergebnisse erhalten. */
options results
	/* Welche Version des MultiFax betreiben wir? */
'version'
	/* Ausgabe der Versionszeichenkette. */
say result
	/* Erst einmal die Liste löschen. */
clearlist
	/* Die Datei 'S:user-startup' in die Liste aufnehmen. */
addfile "S:user-startup"
	/* Telefaxeintrag des Empfängers setzen. */
setphone "@Beispielfax@Vorname@Zusatz@Faxnummer@Strasse@PLZ/Ort@Anwender1@Anwender2@"
	/* Das Fax soll als Faxdatei erstellt werden. */
phonemode 0
	/* Das Fax dem Versand übergeben. */
sendfax
	/* Welche Datei wurde gerade erstellt? */
lastfaxfile
	/* Merken des Namens. */
lastresult = result
	/* Ausgabe des Dateinamens. */
say lastresult
	/* Es folgen DOS-Befehle. */
address command
	/* Anzeige des gerade erstellten Faxes. */
'MultiFax:View >NIL: ' lastresult
	/* Es folgen DOS-Befehle. */
address command
	/* 10 Sekunden warten. */
'Wait' "10 secs"
	/* Es folgen MultiFax-Befehle. */
address 'MultiFaxRexx'
	/* Alle MultiFax-Module einschließlich des MFRexx-Moduls beenden. */
exitall
	/* Es folgen DOS-Befehle. */
address command
	/* Löschen der temporären Datei. */
'Delete RAM:TMP'
	/* Löschen des temporären Faxes, da es nur für diese */
	/* Demonstration erstellt wurde. */
'Delete' lastresult