; $VER: Rexx 1.0  (8.10.99); installer script 1999 Dietmar Eilert

(delopts "oknodelete" "force" "askuser")

(complete 0)

(onerror

    (if (> @ioerr 0)

        (
            (delete "env:INSTALLOPTIONS")

            (message "An error has occurred. Please inform our support (Dietmar.Eilert@post.rwth-aachen.de)")
        )
    )
)

; initialize return code

(textfile (dest "env:COMPONENTINSTALL") (append "INCOMPLETE"))

; initialize strings

(if (= @installer-version 0)

    (set #rexx_esc "")
    (set #rexx_esc "[2p")
)

(if (= @language "deutsch")

    (
        (set #rexx_uninstalling "Die Rexx-Erweiterung wird entfernt ...")

        (set #rexx_badversion   "Diese Software bentigt GoldED 6.2.3+ !")

        (set #rexx_welcome      "Willkommen beim Setup fr die Rexx-Erweiterung !")

        (set #rexx_install      "Installieren")

        (set #rexx_uninstall    "Entfernen")

        (set #rexx_golded       "Bitte installieren Sie GoldED, bevor Sie diese Installation ausfhren !")

        (set #rexx_registry     "Registry wird aktualisiert...")

        (set #rexx_menu         "Sprache fr Menu whlen:")

        (set #rexx_rexxfiles    "Warnung: Die Rexx-Installation auf diesem Rechner ist unvollstndig !")
    )

    (
        (set #rexx_uninstalling "Uninstalling Rexx add-on ...")

        (set #rexx_badversion   "This software requires GoldED 6.2.3+ !")

        (set #rexx_welcome      "Welcome to the setup for the Rexx add-on !")

        (set #rexx_install      "Install")

        (set #rexx_uninstall    "Uninstall")

        (set #rexx_golded       "Please install GoldED before you install this add-on !")

        (set #rexx_registry     "Updating registry ...")

        (set #rexx_menu         "Choose language for menu:")

        (set #rexx_rexxfiles    "Warning: Rexx installation on this computer is incomplete !")
    )
)

(if (exists "golded:" (NOREQ))

    (
        (set vernum (getversion "golded:golded"))

        (set ver (/ vernum 65536))
        (set rev (- vernum (* ver 65536)))

        (set version (+ (* 10 ver) rev))

        (if (< version 62)

            (
                (message #rexx_badversion)
            )
        )

        ; read command passed in to our script in the env variable INSTALLOPTIONS

        (if (exists "env:INSTALLOPTIONS" (noreq))

            ; (getenv) may not be used without checking if var exists (installer bug)

            (
                (set rexx_installmode (getenv "INSTALLOPTIONS"))

                (if (= rexx_installmode "UNINSTALL")

                    (working #rexx_uninstalling)

                    (message #rexx_welcome)
                )
            )

            (set rexx_installmode "ASK")
        )

        (if (= rexx_installmode "ASK")

            (if

                (askbool

                    (prompt #rexx_welcome)

                    (choices

                        #rexx_install
                        #rexx_uninstall
                    )

                    (help @askbool_help)
                )

                (set rexx_installmode "INSTALL")

                (set rexx_installmode "UNINSTALL")
            )
        )

        (delete "env:INSTALLOPTIONS")

        ; verify directory structure

        (makedir "golded:etc")

        (makedir "golded:etc/api")

        (makedir "golded:etc/syntax")

        (makedir "golded:etc/images")

        (makedir "golded:etc/images/toolbar")

        (makedir "golded:add-ons")

        (makedir "golded:etc/uninstall")

        ; install registry editor (if not yet installed)

        (if (exists "golded:add-ons/regedit")

            (
                (set oldver (getversion "golded:add-ons/regedit/regedit"))

                (set newver (getversion "regedit/regedit"))

                (if (> newver oldver)

                    (copyfiles

                        (source "regedit")

                        (dest "golded:add-ons/regedit")

                        (all)

                        (nogauge)
                    )
                )
            )

            (copyfiles

                (source "regedit")

                (dest "golded:add-ons/regedit")

                (all)

                (nogauge)
            )
        )

        (if (= rexx_installmode "UNINSTALL")

            ; uninstall

            (
                ; update registry

                (working #rexx_registry)

                (if (exists ("golded:etc/uninstall/envREX.bat"))

                    (
                        (run "golded:add-ons/regedit/regedit script=golded:etc/uninstall/envREX.bat label=uninstall")

                        (delete "golded:etc/uninstall/envREX.bat")
                    )

                    (run "golded:add-ons/regedit/regedit script=install.bat label=uninstall")
                )

                (exit (quiet))
            )

            ; install

            (
                (if (= rexx_installmode "ASK")

                    (welcome)
                )

                (if (= @language "deutsch")

                    (set language 1)
                    (set language 0)
                )

                (set language

                    (askchoice

                        (prompt #rexx_menu)

                        (choices

                            (cat #rexx_esc "English")
                            (cat #rexx_esc "Deutsch")
                        )

                        (default language)

                        (help @askchoice-help)
                    )
                )

                ; install basic files

                (makedir "golded:add-ons/rexx")

                (copyfiles

                    (source "rexx")

                    (dest "golded:add-ons/rexx")

                    (all)
                )

                ; locate rexx-related programs

                (makedir "golded:add-ons/rexx/programs")

                (if (exists "sys:rexxc")

                    (copyfiles

                        (source "sys:rexxc")

                        (dest "golded:add-ons/rexx/programs")

                        (pattern "(hi|tcc|tco|te|ts)")
                    )

                    ; else

                    (if (exists "sys:rexx")

                        (copyfiles

                            (source "sys:rexx")

                            (dest "golded:add-ons/rexx/programs")

                            (pattern "(hi|tcc|tco|te|ts)")
                        )

                        ; else

                        (copyfiles

                            (source "c:")

                            (dest "golded:add-ons/rexx/programs")

                            (pattern "(hi|tcc|tco|te|ts)")
                        )
                    )
                )

                (if (not (and (exists "golded:add-ons/rexx/programs/hi") (exists "golded:add-ons/rexx/programs/tcc") (exists "golded:add-ons/rexx/programs/tco") (exists "golded:add-ons/rexx/programs/te") (exists "golded:add-ons/rexx/programs/ts")))

                    (message #rexx_rexxfiles)
                )

                ; install toolbar images

                (copyfiles

                    (source "toolbar")

                    (dest "golded:etc/images/toolbar")

                    (all)
                )

                ; update registry

                (working #rexx_registry)

                (if (= language 0)

                    (run "golded:add-ons/regedit/regedit script=install.bat presets/e/rexx.gadgets")

                    (run "golded:add-ons/regedit/regedit script=install.bat presets/d/rexx.gadgets")
                )

                ; prepare uninstallation

                (copyfiles

                   (source "install.bat")

                   (dest "golded:etc/uninstall")

                   (newname "envREX.bat")
                )

                ; installation completed

                (textfile (dest "env:COMPONENTINSTALL") (append "OK"))

                (complete 100)

                (set @default-dest "golded:add-ons/rexx")

                (if (= rexx_installmode "INSTALL")

                    (exit)
                    (exit (quiet))
                )
            )
        )
    )

    (message #rexx_golded)
)

(exit (quiet))
