; $VER: print 6.3  (28.07.98); installer script 1998 Dietmar Eilert

(delopts "oknodelete" "force" "askuser")

(complete 0)

(onerror

    (if (> @ioerr 0)

        (
            (delete "env:INSTALLOPTIONS")

            (message "An error has occurred. Please inform our support (Dietmar.Eilert@post.rwth-aachen.de)")
        )
    )
)

; initialize return code

(textfile (dest "env:COMPONENTINSTALL") (append "INCOMPLETE"))

; initialize strings

(if (= @installer-version 0)

    (set #print_esc "")
    (set #print_esc "[2p")
)

(if (= @language "deutsch")

    (
        (set #print_uninstalling "Die Drucker-Erweiterung wird entfernt ...")

        (set #print_badversion   "Diese Software bentigt GoldED 6 !")

        (set #print_welcome      "Willkommen beim Setup fr die Drucker-Erweiterung !")

        (set #print_install      "Installieren")

        (set #print_uninstall    "Entfernen")

        (set #print_golded       "Bitte installieren Sie GoldED, bevor Sie diese Installation ausfhren !")

        (set #print_registry     "Registry wird aktualisiert...")

        (set #print_language     "Sprache fr die Symbolleiste whlen:")
    )

    (
        (set #print_uninstalling "Uninstalling printer add-on ...")

        (set #print_badversion   "This software requires GoldED 6 !")

        (set #print_welcome      "Welcome to the setup for the printer add-on !")

        (set #print_install      "Install")

        (set #print_uninstall    "Uninstall")

        (set #print_golded       "Please install GoldED before you install this add-on !")

        (set #print_registry     "Updating registry ...")

        (set #print_language     "Choose language for toolbar:")
    )
)

(if (exists "golded:" (NOREQ))

    (
        (set vernum (getversion "golded:golded"))

        (set ver (/ vernum 65536))
        (set rev (- vernum (* ver 65536)))

        (set version (+ (* 10 ver) rev))

        (if (< version 60)

            (
                (message #print_badversion)
            )
        )

        ; read command passed in to our script in the env variable INSTALLOPTIONS

        (if (exists "env:INSTALLOPTIONS" (noreq))

            ; (getenv) may not be used without checking if var exists (installer bug)

            (
                (set print_installmode (getenv "INSTALLOPTIONS"))

                (if (= print_installmode "UNINSTALL")

                    (working #print_uninstalling)

                    (message #print_welcome)
                )
            )

            (set print_installmode "ASK")
        )

        (if (= print_installmode "ASK")

            (if

                (askbool

                    (prompt #print_welcome)

                    (choices

                        #print_install
                        #print_uninstall
                    )

                    (help @askbool_help)
                )

                (set print_installmode "INSTALL")

                (set print_installmode "UNINSTALL")
            )
        )

        (delete "env:INSTALLOPTIONS")

        ; verify directory structure

        (makedir "golded:etc")

        (makedir "golded:etc/api")

        (makedir "golded:etc/syntax")

        (makedir "golded:etc/images")

        (makedir "golded:etc/images/toolbar")

        (makedir "golded:add-ons")

        (makedir "golded:etc/uninstall")

        ; install registry editor (if not yet installed)

        (if (exists "golded:add-ons/regedit")

            (
                (set oldver (getversion "golded:add-ons/regedit/regedit"))

                (set newver (getversion "regedit/regedit"))

                (if (> newver oldver)

                    (copyfiles

                        (source "regedit")

                        (dest "golded:add-ons/regedit")

                        (all)

                        (nogauge)
                    )
                )
            )

            (copyfiles

                (source "regedit")

                (dest "golded:add-ons/regedit")

                (all)

                (nogauge)
            )
        )

        (if (= print_installmode "UNINSTALL")

            ; uninstall

            (
                ; update registry

                (working #print_registry)

                (if (exists ("golded:etc/uninstall/envCPP.bat"))

                    (
                        (run "golded:add-ons/regedit/regedit script=golded:etc/uninstall/envCPP.bat label=uninstall")

                        (delete "golded:etc/uninstall/envCPP.bat")
                    )

                    (run "golded:add-ons/regedit/regedit script=install.bat label=uninstall")
                )


                (exit (quiet))
            )

            ; install

            (
                (if (= bat_installmode "ASK")

                    (welcome)
                )

                ; install basic files

                (makedir "golded:add-ons/print")

                (copyfiles

                    (source "print")

                    (dest "golded:add-ons/print")

                    (all)
                )

                ; install toolbar images

                (copyfiles

                    (source "toolbar")

                    (dest "golded:etc/images/toolbar")

                    (all)
                )

                (if (= @language "deutsch")

                    (set language 1)
                    (set language 0)
                )

                (set language

                    (askchoice

                        (prompt #print_language)

                        (help @askchoice-help)

                        (choices

                            (cat #print_esc "English")
                            (cat #print_esc "Deutsch")
                        )

                        (default language)
                    )
                )

                ; update registry

                (working #print_registry)

                (if (= language 0)

                    (run "golded:add-ons/regedit/regedit script=install.bat presets/e/standard.gadgets")
                    (run "golded:add-ons/regedit/regedit script=install.bat presets/d/standard.gadgets")
                )

                ; prepare uninstallation

                (copyfiles

                   (source  "install.bat")
                   (dest    "golded:etc/uninstall")
                   (newname "envPRT.bat")
                )

                ; installation completed

                (textfile (dest "env:COMPONENTINSTALL") (append "OK"))

                (complete 100)

                (set @default-dest "golded:add-ons/print")

                (if (= print_installmode "INSTALL")

                    (exit)
                    (exit (quiet))
                )
            )
        )
    )

    (message #print_golded)
)

(exit (quiet))
