; $VER: MicroDot mode 2.3  (29.03.98); installer script 1998 Dietmar Eilert

(delopts "oknodelete" "force" "askuser")

(complete 0)

(onerror

    (if (> @ioerr 0)

        (
            (delete "env:INSTALLOPTIONS")

            (message "An error has occurred. Please inform our support (Dietmar.Eilert@post.rwth-aachen.de)")
        )
    )
)

; initialize return code

(textfile (dest "env:COMPONENTINSTALL") (append "INCOMPLETE"))

; initialize strings

(if (= @installer-version 0)

    (set #mdt_esc "")
    (set #mdt_esc "[2p")
)

(if (= @language "deutsch")

    (
        (set #mdt_uninstalling "Die Microdot-Erweiterung wird entfernt ...")

        (set #mdt_badversion   "Diese Software bentigt GoldED 6 !")

        (set #mdt_welcome      "Willkommen beim Setup fr die Microdot-Erweiterung !")

        (set #mdt_install      "Installieren")

        (set #mdt_uninstall    "Entfernen")

        (set #mdt_golded       "Bitte installieren Sie GoldED, bevor Sie diese Installation ausfhren !")

        (set #mdt_language     "Sprache fr Kontext-Menu whlen:")

        (set #mdt_registry     "Registry wird aktualisiert...")

        (set #mdt_configure    "Bitte konfigurieren Sie MicroDot so, da der\nfolgende Befehl zum Start des Editors verwendet\nwird (Einstellungen fr externe Programme):\n\ned %s STICKY FILETYPE=\"MICRODOT\"")
    )

    (
        (set #mdt_uninstalling "Uninstalling Microdot add-on ...")

        (set #mdt_badversion   "This software requires GoldED 6 !")

        (set #mdt_welcome      "Welcome to the setup for the Microdot add-on !")

        (set #mdt_install      "Install")

        (set #mdt_uninstall    "Uninstall")

        (set #mdt_golded       "Please install GoldED before you install this add-on !")

        (set #mdt_language     "Select context menu language:")

        (set #mdt_registry     "Updating registry ...")

        (set #mdt_configure    "Please configure MicroDot to use the following\ncommand to run the editor (configuration of\nexternal programs):\n\ned %s STICKY FILETYPE=\"MICRODOT\"")
    )
)

(if (exists "golded:" (NOREQ))

    (
        (set vernum (getversion "golded:golded"))

        (set ver (/ vernum 65536))
        (set rev (- vernum (* ver 65536)))

        (set version (+ (* 10 ver) rev))

        (if (< version 60)

            (
                (message #mdt_badversion)
            )
        )

        ; read command passed in to our script in the env variable INSTALLOPTIONS

        (if (exists "env:INSTALLOPTIONS" (noreq))

            ; (getenv) may not be used without checking if var exists (installer bug)

            (
                (set mdt_installmode (getenv "INSTALLOPTIONS"))

                (if (= mdt_installmode "UNINSTALL")

                    (working #mdt_uninstalling)

                    (message #mdt_welcome)
                )
            )

            (set mdt_installmode "ASK")
        )

        (if (= mdt_installmode "ASK")

            (if

                (askbool

                    (prompt #mdt_welcome)

                    (choices

                        #mdt_install
                        #mdt_uninstall
                    )

                    (help @askbool_help)
                )

                (set mdt_installmode "INSTALL")

                (set mdt_installmode "UNINSTALL")
            )
        )

        (delete "env:INSTALLOPTIONS")

        ; verify directory structure

        (makedir "golded:etc")

        (makedir "golded:etc/api")

        (makedir "golded:etc/syntax")

        (makedir "golded:etc/images")

        (makedir "golded:etc/images/toolbar")

        (makedir "golded:add-ons")

        (makedir "golded:etc/uninstall")

        ; install registry editor (if not yet installed)

        (if (exists "golded:add-ons/regedit")

            (
                (set oldver (getversion "golded:add-ons/regedit/regedit"))

                (set newver (getversion "regedit/regedit"))

                (if (> newver oldver)

                    (copyfiles

                        (source "regedit")

                        (dest "golded:add-ons/regedit")

                        (all)

                        (nogauge)
                    )
                )
            )

            (copyfiles

                (source "regedit")

                (dest "golded:add-ons/regedit")

                (all)

                (nogauge)
            )
        )

        (if (= mdt_installmode "UNINSTALL")

            ; uninstall

            (
                ; update registry

                (working #mdt_registry)

                (if (exists ("golded:etc/uninstall/envMDT.bat"))

                    (
                        (run "golded:add-ons/regedit/regedit script=golded:etc/uninstall/envMDT.bat label=uninstall")

                        (delete "golded:etc/uninstall/envMDT.bat")
                    )

                    (run "golded:add-ons/regedit/regedit script=install.bat label=uninstall")
                )

                (exit (quiet))
            )

            ; install

            (
                (if (= mdt_installmode "ASK")

                    (welcome)
                )

                (if (= @language "deutsch")

                    (set language 1)
                    (set language 0)
                )

                (set language

                    (askchoice

                        (prompt #mdt_language)

                        (help @askchoice-help)

                        (choices

                            (cat #mdt_esc "English")
                            (cat #mdt_esc "Deutsch")
                        )

                        (default language)
                    )
                )

                ; install basic files

                (makedir "golded:add-ons/microdot")

                (copyfiles

                    (source "microdot")

                    (dest "golded:add-ons/microdot")

                    (all)
                )

                ; update registry

                (working #mdt_registry)

                (if (= language 0)

                    (run "golded:add-ons/regedit/regedit script=install.bat presets/e/email.mouse")
                    (run "golded:add-ons/regedit/regedit script=install.bat presets/d/email.mouse")
                )

                ; prepare uninstallation

                (copyfiles

                   (source "install.bat")

                   (dest "golded:etc/uninstall")

                   (newname "envMDT.bat")
                )

                ; installation completed

                (message #mdt_configure)

                (textfile (dest "env:COMPONENTINSTALL") (append "OK"))

                (complete 100)

                (set @default-dest "golded:")

                (if (= mdt_installmode "INSTALL")

                    (exit)
                    (exit (quiet))
                )
            )
        )
    )

    (message #mdt_golded)
)

(exit (quiet))
