;$VER: Spidersoft_Utilities Installation Script
(welcome)

(set inst
    (askchoice
        (prompt "Install which program...")
        (help @askchoice-help)
        (choices "Garden Designer" "Property Protector")
    )
)

(set @app-name
    ("Garden Designer")
)

(set otherapp
    ("Property Protector")
)

(if (= inst 1)(
    (set @app-name
        ("Property Protector")
    )
    (set otherapp
        ("Garden Designer")
    )
))

(set @default-dest
    (askdir
        (prompt "Please select a place to install " @app-name)
        (help @askdir-help)
        (default "Work:SSoftUtils")
    )
)

(if (= inst 0)
    (
        (copyfiles
            (source "Spidersoft_Utilities:")
            (choices "DND" "HowDoI?")
            (dest @default-dest)
            (help @copyfiles-help)
        )

        (copyfiles
            (source "Spidersoft_Utilities:")
            (dest @default-dest)
            (pattern "Garden#?")
            (help @copyfiles-help)
        )

        (if (exists "Spidersoft_Utilities:Reg")
            (copyfiles
                (source "Spidersoft_Utilities:reg")
                (dest @default-dest)
                (help @copyfiles-help)
            )
        )
    )
)

(if (= inst 1)
    (
        (copyfiles
            (source "Spidersoft_Utilities:Property_Protector")
            (dest @default-dest)
            (infos)
        )

        (makedir (tackon @default-dest "PP_Data"))
        (set ppdata (tackon @default-dest "PP_Data"))

        (copyfiles
            (source "Spidersoft_Utilities:PP_Data")
            (dest ppdata)
            (all)
        )
    )
)

(set other
    (askchoice
        (prompt "Have you installed " otherapp " on your hard drive?")
        (help @askchoice-help)
        (choices "Yes" "No")
        (default 1)
    )
)

(if (= other 1)
(
    (set save
        (askdir
            (prompt "Please select a place for your saved files")
            (help @askdir-help)
            (default "Work:SSoftSaves")
        )
    )

    (startup @app-name
        (prompt "A few commands need to be added to your user-startup...")
        (help @startup-help)
        (command "assign Spidersoft_Utilities: " @default-dest
                 "\nassign Saved: " save)
    )
))

(if (= other 0)
    (
        (startup @app-name
            (prompt "A few commands need to be added to your"
                    "user-startup...")
            (help @startup-help)
            (command "assign Spidersoft_Utilities: " @default-dest " add")
        )
    )
)

(exit)