failat 21
resident rtEZReq pure
resident rtGetString pure
set DD 1
set rtgstext `rtGetString TITLE="Enter Any text" DEF="" ALLOWEMPTY`
set ezreq1 `rtEZReq "You entered: *"$rtgstext*"*NIs that correct?" "_Yes|_No"`
if "$ezreq1" EQ "1"
   rtEZReq >NIL: "See how simple is that" "_I see"
   skip show_makeid
EndIf

Lab repeatit1
set ezreq1 `rtEZReq "Think again!!!*NYou entered: *"$rtgstext*"*NIs that correct?" "_Yes|_No"`
If "$ezreq1" NOT EQ "1"
   Skip repeatit1 BACK
EndIf

Lab show_makeid
set rtgstext `rtGetString TITLE="Enter the four letter ID" DEF="MkID"`
set makeid `MakeID $rtgstext`
IF "$rtgstext" EQ ""
   Skip show_makeid BACK
EndIf
rtEZReq >NIL: "You entered *"$rtgstext*"*NIts ID is 0x$makeid" "_Oh, thank you"
rtEZReq >NIL: "You're welcome*N*N(press any key)" VKEY INACTIVE

Lab show_idcmp
set ezreq2 `rtEZReq "Please remove a disk or press Okay" "_Okay" DISKREMOVED`
if "$ezreq2" NOT EQ "-1"
   set ezreq3 `rtEZReq "What, don't you have a floppy drive" "_Yes, I have!|_No, I do NOT"`
   If "$ezreq3" EQ "1"
      Skip show_idcmp BACK
   EndIf
   set DD 0
   rtEZReq >NIL: "I am so sorry!" "_I know"
EndIf

If "$DD" EQ "1"
   rtEZReq >NIL: "Please reinsert the diskette*N(or any other diskette)" DISKINSERTED
EndIf
rtEZReq >NIL: "That's all folks!*NPress any key" VKEY

Lab Cleanup ; koniec
resident rtEZReq REMOVE
resident rtGetString REMOVE
unset DD
unset ezreq1
unset ezreq2
unset ezreq3
unset makeid
unset RTGSTEXT