; $VER: Install script for AStart21 2.7 (27.10.97)
; LANGUAGES

(procedure polish (
	(set language0 "Polski")
	(set MSG_WELCOME "\nWitaj w AStart V2.1\n\nostatecznym programie do\n\nbootowania \"alternatywnego\"\n\nAStart © 1997 Wojiech Kocjan\n\nAStart jest mailware\n\n(nowy uûytkownik/czka)")
	(set MSG_WELCOMEU "\nWitaj w AStart V2.1\n\nostatecznym programie do\n\nbootowania \"alternatywnego\"\n\nAStart © 1997 Wojiech Kocjan\n\nAStart jest mailware\n\n(upgrade ze starszej wersji)")
	(set MSG_ASKPREFDIR "Podaj ôcieûkë docelowâ dla programu konfiguracji")
	(set MSG_COPYCMD "Kopiowanie komendy uruchamiajâcej AStart")
	(set MSG_COPYASTARTUP "Kopiowanie skryptu alternate-startup")
	(set MSG_ASK_YES "Tak")
	(set MSG_ASK_NO "Nie")
	(set MSG_ASKMODIFY "Czy mam modyfikowaê plik s:startup-sequence?\n(jest to konieczne, jeûeli nie zainstalowaîeô(aô)\njeszcze poprzednich wersji AStart,\nJeûeli tak, to nie jest to zalecane)")
	(set MSG_ASKMODIFY_YES "Modyfikuj")
	(set MSG_ASKMODIFY_NO "Nie modyfikuj")
	(set MSG_ASKBACKUP "Czy mam zrobiê kopië oryginalnego pliku s:startup-sequence?")
	(set MSG_ASKBACKUP_YES "Zrób kopië")
	(set MSG_ASKBACKUP_NO "Nie rób kopii")
	(set MSG_MODIFYSTARTUP0 "Modyfikowanie pliku startup-sequence")
	(set MSG_COPYSTARTUP "Kopiowanie zmodyfikowanego pliku startup-sequence")
	(set MSG_RUNPREF "Czy mam uruchomiê program ustawieï? (wymaga MUI 3.1)")
	(set MSG_ASK_COPYDOC "Czy mam skopiowaê plik pomocy?")
	(set MSG_COPYDOC "Kopiujë plik pomocy...")
	(set MSG_ASKDOCSDIR "Gdzie mam umieôciê plik pomocy?")
	(set MSG_COPYENVARC "Kopiujë podstawowe ustawienia...")
))

(procedure english (
	(set language0 "English")
	(set MSG_WELCOME "\nWelcome to AStart V2.1\n\nthe ultimate alternate bootup maker\n\nAStart © 1997 Wojciech Kocjan\n\nAStart is mailware\n\n(you are a new AStart user)")
	(set MSG_WELCOMEU "\nWelcome to AStart V2.1\n\nthe ultimate alternate bootup maker\n\nAStart © 1997 Wojciech Kocjan\n\nAStart is mailware\n\n(you are upgrading from older versions of AStart)")
	(set MSG_ASKPREFDIR "Enter path for preferences")
	(set MSG_COPYCMD "Copying AStart running command")
	(set MSG_COPYASTARTUP "Copying alternate-startup script")
	(set MSG_ASK_YES "Yes")
	(set MSG_ASK_NO "No")
	(set MSG_ASKMODIFY "Should I modify s:startup-sequence?\n(it's neccessary if you haven't installed\nAStart yet, if you already have, then it's not reccommended)")
	(set MSG_ASKMODIFY_YES "Modify")
	(set MSG_ASKMODIFY_NO "Don't modify")
	(set MSG_ASKBACKUP "Should I backup the original s:startup-sequence?")
	(set MSG_ASKBACKUP_YES "Backup")
	(set MSG_ASKBACKUP_NO "Don't backup")
	(set MSG_MODIFYSTARTUP0 "Modyfying s:startup-sequence")
	(set MSG_COPYSTARTUP "Copying modified startup-sequence")
	(set MSG_RUNPREF "Shall I run the preferences program? (requires MUI 3.1)")
	(set MSG_ASK_COPYDOC "Shall I copy the docs?")
	(set MSG_COPYDOC "Copying the docs...")
	(set MSG_ASKDOCSDIR "Where shall I copy the docs?")
	(set MSG_COPYENVARC "Copying default settings...")
))

(set language0 "")

(if (= @language "english")  (english))
(if (= @language "polski")  (polish))
(if (= language0 "") (english))

(procedure modifystartup (
	(textfile (dest "T:startup-sequence")
	(append ("; This part was added by AStart\n; AStart © 1997 Wojciech Kocjan\n\nC:AStart S:alternate-startup\nIF WARN\n  EndCLI >NIL:\nEndIF\n\n" firstline)) (include "s:startup-sequence"))
	(copyfiles
		(prompt MSG_COPYSTARTUP)
		(help @copyfiles-help)
		(source "T:startup-sequence")
		(dest "S:")
		(files)
		(confirm)
	)	
))

(welcome)

(run "setenv ASTART_WASINSTALLED `c/MatchLine s:startup-sequence 1 \"(;?This part?was?added?by?AStart|#?AStart#?alternate-startup)\"`" (safe))
(set upgrading (getenv "ASTART_WASINSTALLED"))
(delete "ENV:ASTART_WASINSTALLED" (prompt "") (help "") (optional force) (safe))

(if (= upgrading 0)
	(message MSG_WELCOME)
	(message MSG_WELCOMEU)
)

(complete 0)

(set dest_dir "C:")
(set @default-dest "SYS:")

(set pref_dest_dir
   (askdir (prompt MSG_ASKPREFDIR)
           (help @askdir-help)
           (default "SYS:Prefs"))
)

(if (= upgrading 0)
	(
		(set backup
			(askbool 
				(prompt MSG_ASKBACKUP)
				(help @askbool-help)
				(default 1)
				(choices MSG_ASKBACKUP_YES MSG_ASKBACKUP_NO))
		)
		
		(set modify
			(askbool 
				(prompt MSG_ASKMODIFY)
				(help @askbool-help)
				(default 1)
				(choices MSG_ASKMODIFY_YES MSG_ASKMODIFY_NO))
		)
	)
	(
		(set backup 0)
		(set modify 0)
	)
)
		
(complete 10)

(set copydocs
	(askbool
		(prompt MSG_ASK_COPYDOC)
		(help @askbool-help)
		(default 1)
		(choices MSG_ASK_YES MSG_ASK_NO))
)

(if (= copydocs 1)
	(set docs_dest_dir
	   (askdir (prompt MSG_ASKDOCSDIR)
	           (help @askdir-help)
	           (default "HELP:"))
	)
)

(complete 20)

(copyfiles
	(prompt MSG_COPYCMD)
	(help @copyfiles-help)
	(source "C")
	(dest dest_dir)
	(choices "AStart" "Beep" "ConvertX" "GetF")
	(confirm)
	(files)
)

(complete 30)

(if (= copydocs 1)
	(copyfiles
		(prompt MSG_COPYASTARTUP)
		(help @copyfiles-help)
		(source "S/alternate-startup")
		(dest "S:")
		(confirm)
		(files))
)

(complete 40)

(if (= copydocs 1)
	(
	(copyfiles
		(prompt MSG_COPYDOC)
		(help @copyfiles-help)
		(source "astart.guide")
		(dest docs_dest_dir)
		(infos)
		)
	)
)

(complete 50)

(if backup
	(copyfiles
		(prompt MSG_COPYCMD)
		(help @copyfiles-help)
		(source "S:startup-sequence")
		(dest "Sys:Storage")
		(newname "startup-sequence.bak")
	)
)

(complete 60)

(if modify 
	(modifystartup)
)

(complete 70)

(copyfiles
	(prompt MSG_COPYENVARC)
	(help @copyfiles-help)
	(source "ENVArc")
	(dest "ENVArc:")
	(choices "AStart_CIA" "AStart_Debug" "AStart_DOSDrivers" "AStart_ENVArc" "AStart_Monitors" "AStart_UserStartup" "AStart_DT" "AStart_T")
	(confirm)
	(files)
)
(complete 80)

(copyfiles
	(prompt MSG_COPYCMD)
	(help @copyfiles-help)
	(source "Prefs")
	(dest pref_dest_dir)
	(choices "AStart")
	(confirm)
	(infos)
	(files)
)

(complete 90)

(if
	(askbool 
		(prompt MSG_RUNPREF)
		(help @askbool-help)
		(default 1)
		(choices MSG_ASK_YES MSG_ASK_NO))
	(run "Prefs/AStart")
)

(complete 100)

(exit)