;   -----------------------------
;       Install BancaBase
;   -----------------------------
;   Description:
;
;   Commodore Installer Script for BancaBase 1.3a
;   $VER: 1.02 (c) 1997 by Stefano Dardari

; some useful variables
	(set 
		newline 		"\n"
		#bbprogname 	"BancaBase13a.lha"
        #bb3-path       "BancaBase/"
        #catalogsname   "catalogs/"
        #docsname       "docs/"
        #examplename    "examples.lha"
		#patternsname 	"Patterns.lha"
        #soundsname     "Sounds.lha"
        #registername   "Register.lha"
        #bb3-dest       "SYS:"
        #bb3-key        "BBase.key"
        #bb3-prefs      "BancaBase.prefs"
        #bb3-readme     "ReadMe.doc"
        #bb3-readme-ita "Leggimi.doc"
        #bb3-icon-MWB   "Icons/MagicWB/"
        #bb3-icon-NI    "Icons/NewIcon/"
        #bb3-icon-STD   "Icons/Standard/"
        #STDTYPE        0
        #NITYPE         1
        #MWBTYPE        2
        #iconpattern    "#?.info"
        #bb3-lang-eng   "english"
        #bb3-lang-deu   "deutsch"
        #bb3-lang-ita   "italiano"
        #bb3-lang-fra   "français"
        #bb3-lang-rus   "russian"
        #ENG            0
        #DEU            1
        #ITA            2
        #FRA            3
        #RUS            4
	)

; some strings
(set #omp (cat "Un momento prego..." newline))

(set #installtext (cat "Benvenuti nello script di installazione di BancaBase.\n\nBancaBase3 V 1.3a (C) 1997 by Stefano Dardari\n\nAll rights reserved"))
(set #BB3dest-prompt "Prego selezionare la directory dove si desidera installare il cassetto BancaBase.\n(Vedere l'HELP per ulteriori dettagli)")
(set #BB3dest-help (cat "Selezionare la directory (o il disco) dove si desidera installare il programma. Verrà creata una directory con il nome di BancaBase."))
(set #BB3lang-prompt "Selezionare la lingua (tra quelle disponibili) che il programma dovrà utilizzare per i menù ed i gadgets.")
(set #BB3lang-help "Selezionando una delle lingue elencate, vengono copiati i relativi file catalogs che il programma caricherà in modo autonomo. Se si desidera lasciare il programma in INLGESE non è necessario alcun catalogo esterno in quanto costruito all'interno del programma stesso")
(set #BB3docs-prompt "Selezionare la lingua (tra quelle disponibili) dei file di documentazione che si desidera installare.")
(set #BB3docs-help "E' possibile selezionare la lingua (tra quelle elencate) di file documentazione del programma.")
(set #BB3patt-prompt "\n\n\nSi desidera installare alcuni sfondi da utilizzare con l'interfaccia grafica ?\n\nNOTA: Sono utilizzabili solo con WorkBench 3.0 o superiore.")
(set #BB3patt-help (cat "Gli sfondi (o backdrop patterns) vanno considerati come extra. Infatti non sono necessari per il corretto funzionamento di BancaBase, ma sono molto carini se utilizzati con l'interfaccia grafica.\n\nNota che il programma utilizza i Datatypes per gestire i pattern. Quindi se non si utilizza una versione V39 (o suberiore) del kickstart ... selezionare il gadget NO."))
(set #BB3end (cat "Installazione completata. Leggere il file readme prima di iniziare."))
(set #BB3icon-prompt "\nQuale tipo di ICONE si desidera installare tra quelle disponibili ?")
(set #BB3icon-help "Selezionare il tipo di Icona desiderata per il programma e tutti gli accessori forniti. Se ad esempio nel vostro WorkBench utilizzate normalmente le icone stile Magic WorkBench, selezionate MagicWB. Lo stesso vale per gli altri tipi di icona.")
(set #coping-icon-prompt "Attendere prego ... installo le icone selezionate.")

(welcome #installtext)

(procedure set_icon
   (set #def-icon
      (askchoice
         (prompt #BB3icon-prompt)
         (help   #bb3icon-help)
         (choices "Icone Standard" "Icone NewIcon" "Icone MagicWB")
         (default 0)
      )
   )
)

(procedure set_lang_catalogs
   (set #def-lang
      (askchoice
         (prompt #BB3lang-prompt)
         (help   #bb3lang-help)
         (choices "English (built in)" "Deutsch" "Italiano" "Français" "Russian")
         (default #ITA)
      )
   )
)

(procedure set_lang_docs
   (if (> #def-lang #ITA)
        (set #def-lang #ITA)
   )
   (set #def-lang
      (askchoice
         (prompt #BB3docs-prompt)
         (help   #bb3docs-help)
         (choices "English" "Deutsch" "Italiano")
         (default #def-lang)
      )
   )
)

(procedure set_dir
   (set #bb3-dest
      (askdir
         (prompt #BB3dest-prompt)
         (help #BB3dest-help)
         (default #bb3-dest)
         (newpath)
      )
   )
)

(set_dir)
(set #dest-path (tackon #bb3-dest #bb3-path))
(set @default-dest #dest-path)


(if (exists #dest-path (noreq))
   (
      (set #file-exist (cat "Spiacente ma la directory " #dest-path " esiste gia'.\nSelezionare una directory destinazione differente.\n"))
      (message #file-exist)
      (set_dir)
      (set #dest-path (tackon #bb3-dest #bb3-path))
      (set @default-dest #dest-path)
   )
)

(makedir #dest-path (infos))

(working #omp "Scompatto e copio il programma.")

(run "lha -x x "#bbprogname" "#dest-path )

(complete 20)
(if (exists #examplename (noreq))
       (
          (working #omp "Scompatto e copio i files di esempio.")
          (run "lha -x x "#examplename" "#dest-path )
       )
)


(complete 30)
(set_lang_catalogs)
(if (= #def-lang #ENG)
    (set #lang #bb3-lang-eng)
    )
(if (= #def-lang #DEU)
    (set #lang #bb3-lang-deu)
    )
(if (= #def-lang #ITA)
    (set #lang #bb3-lang-ita)
    )
(if (= #def-lang #FRA)
    (set #lang #bb3-lang-fra)
    )
(if (= #def-lang #RUS)
    (set #lang #bb3-lang-rus)
    )

(set #src-path (tackon "Catalogs" #lang))
(set #src-path (cat #src-path ".lha"))
(set #dst-path (tackon #dest-path #catalogsname))

(if (exists #src-path (noreq))
       (
          (makedir (cat #dest-path #catalogsname) (infos))
          (working #omp "Scompatto e copio i cataloghi.")
          (run "lha -x x "#src-path" "#dst-path )
          (if (exists (cat #catalogsname "BancaBase.cd"))
             (copyfiles
          		(source (cat #catalogsname "BancaBase.cd"))
    		    (dest #dst-path)
                (files)
              )
          )        
          (if (exists (cat #catalogsname "SDBase.cd"))
             (copyfiles
                (source (cat #catalogsname "SDBase.cd"))
    	        (dest #dst-path)
                (files)
             )
	      )

       )
)

(complete 40)

(set_lang_docs)
(if (= #def-lang #ENG)
    (set #lang #bb3-lang-eng)
    )
(if (= #def-lang #DEU)
    (set #lang #bb3-lang-deu)
    )
(if (= #def-lang #ITA)
    (set #lang #bb3-lang-ita)
    )

(set #src-path (tackon "Docs" #lang))
(set #src-path (cat #src-path ".lha"))
(set #dst-path (tackon #dest-path #docsname))

(if (exists #src-path (noreq))
       (
          (makedir (cat #dest-path #docsname) (infos))
          (working #omp "Scompatto e copio la documentazione.")
          (run "lha -x x "#src-path" "#dst-path )
       )
)


(complete 50)
(if (exists #registername (noreq))
       (
          (working #omp "Scompatto e copio i files documentazione per la registrazione.")
          (run "lha -x x "#registername" "#dest-path )
       )
)

(if (exists #bb3-readme (noreq))
	(copyfiles
        (prompt #omp "Copio i file di informazioni.")
		(source #bb3-readme)
		(dest #dest-path)
        (files)
	)
)

(if (exists #bb3-readme-ita (noreq))
	(copyfiles
        (prompt #omp "Copio i file di informazioni in italiano.")
		(source #bb3-readme-ita)
		(dest #dest-path)
        (files)
	)
)

(complete 60)
(if (exists #patternsname (noreq))
   (
      (if (askbool (prompt #BB3patt-prompt) (help #BB3patt-help) (default 1))
          (
             (working #omp "Scompatto e copio gli sfondi (patterns).")
             (run "lha -x x "#patternsname" "#dest-path )
          )
      )
   )
)


(complete 70)

(set_icon)
(if (= #def-icon #STDTYPE)
    (set #src-icon #bb3-icon-STD)
    )
(if (= #def-icon #NITYPE)
    (set #src-icon #bb3-icon-NI)
    )
(if (= #def-icon #MWBTYPE)
    (set #src-icon #bb3-icon-MWB)
    )

(copyfiles
   (prompt #coping-icon-prompt)
   (source #src-icon)
   (dest  #dest-path)
   (pattern #iconpattern)
   (noposition)
)

(set #src-path (tackon #src-icon "Docs"))
(set #dst-path (tackon #dest-path "Docs"))


(copyfiles
   (prompt #coping-icon-prompt)
   (source #src-path)
   (dest  #dst-path)
   (all)
   (noposition)
)

(set #src-path (tackon #src-icon "Register"))
(set #dst-path (tackon #dest-path "Register"))

(copyfiles
   (prompt #coping-icon-prompt)
   (source #src-path)
   (dest  #dst-path)
   (all)
   (noposition)
)

(complete 80)

(if (exists #soundsname (noreq))
       (
          (working #omp "Scompatto e copio i files sonori.")
          (run "lha -x x "#soundsname" "#dest-path )
       )
)


(complete 90)

(if (exists #bb3-prefs (noreq))
	(copyfiles
        (prompt #omp "Copio il file preferenze.")
		(source #bb3-prefs)
		(dest #dest-path)
        (files)
	)
)

(if (exists #bb3-key (noreq))
	(copyfiles
        (prompt #omp "Copio il KeyFile.")
		(source #bb3-key)
		(dest #dest-path)
        (files)
	)
)

(complete 100)

; The last message
	(set end_text (cat "\nSpero che BancaBase ti piaccia!\n"
                       "Non esitare a mandarmi commenti, suggerimenti e bugreports.\n\n"
                       "Le registrazioni sono BENVENUTE !!! :))"))

; the end
(set @default-dest #dest-path)
    (exit end_text)
;EOF